Mục lục
Các biến số (chẳng hạn như giá hàng hóa, cổ phiếu, lãi suất, v.v.) phụ thuộc vào ngày tháng khiến mọi người thường hoang mang vì giá của chúng phụ thuộc vào ngày tháng. INDEX MATCH nhiều phạm vi ngày tiêu chí có thể trích xuất giá từ một phạm vi ngày nhất định.
Giả sử chúng tôi có một số sản phẩm nhất định với giá của chúng ổn định trong một khoảng thời gian nhất định. Và chúng tôi muốn INDEX MATCH giá cho các tiêu chí nhất định.
Trong bài viết này, chúng tôi sử dụng nhiều hàm để INDEX MATCH phạm vi ngày nhiều tiêu chí.
Tải xuống Sổ làm việc Excel
Phạm vi ngày nhiều tiêu chí.xlsx
3 cách dễ dàng để sử dụng hàm INDEX MATCH cho nhiều tiêu chí của phạm vi ngày
Phương pháp 1: Sử dụng hàm INDEX MATCH cho nhiều tiêu chí của phạm vi ngày
Chúng tôi muốn để trích xuất giá cho một sản phẩm nhất định vào một ngày cụ thể. Giả sử chúng ta muốn xem giá của Kem vào ngày 02-10-22 ( tháng-ngày-năm ). Nếu ngày đã cho nằm trong khoảng thời gian được cung cấp, chúng tôi sẽ trích xuất giá trong bất kỳ ô trống nào.
Các bước: Chèn công thức sau vào bất kỳ ô trống nào (tức là, I5 ). Là công thức trong công thức mảng, Nhấn CTRL+SHIFT+ENTER để áp dụng. Công thức ngay lập tức trả về giá Sản phẩm nếu giá đó nằm trong khoảng thời gian nhất định (tức là, phạm vi Ngày ) như được mô tả bên dưới.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0)) 
🔄 Khám nghiệm tử thi công thức:
Hàm INDEX của Excel tìm giá trị của một vị trí nhất định trong một phạm vi nhất định. Trong trường hợp của chúng tôi, chúng tôi sử dụng hàm MATCH được tạo ra bởi hàm INDEX . Hàm MATCH chuyển kết quả của nó dưới dạng số hàng cho các mục nhập thỏa mãn tiêu chí đã cho. Cú pháp của hàm INDEX là
INDEX(array, row_num, [col_num]) Trong công thức, $E$5$E$16 đề cập đến đối số mảng . Bên trong hàm MATCH $B$5:$B$16=G5 , $D$5:$D$16>=H5 và $C$5:$C$16<=H5 khai báo tiêu chí. Để giúp nhận dạng tốt hơn, chúng tôi tô màu các phạm vi tương ứng trong hình chữ nhật.
Hàm MATCH xác định vị trí của một giá trị nhất định trong một hàng, cột hoặc bảng. Như chúng tôi đã nói trước đó, phần MATCH chuyển số hàng cho hàm INDEX . Cú pháp của hàm MATCH là
MATCH (lookup_value, lookup_array, [match_type]) Phần MATCH là
=MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0) Phần MATCH chỉ định 1 là lookup_value , ($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5) là lookup_array và 0 tuyên bố [match_type] là đối sánh chính xác.
Công thức MATCH đã sử dụng trả về 3 khi nó tìm thấy Kem ở số hàng 3 .
Trong trường hợp, chúng tôi có nhiều sản phẩm để trích xuất giá của chúng bộ dữ liệu. Nó giống như hình dưới đây,
Công thức kết hợp INDEX MATCH tìm nạp Giá theo nó làlập luận thỏa mãn các tiêu chí. Nếu không, sẽ dẫn đến lỗi #N/A như được mô tả trong ảnh chụp màn hình ở trên.
Đọc thêm: DẠNG CHỈ SỐ VBA Dựa trên Nhiều Tiêu chí trong Excel ( 3 Phương pháp)
Phương pháp 2: Hàm XLOOKUP để xử lý nhiều tiêu chí
Tương tự như Phương pháp 1 , chúng ta có thể sử dụng Hàm XLOOKUP (chỉ khả dụng trong Excel 365 ) cho phạm vi ngày nhiều tiêu chí INDEX MATCH . Cú pháp của hàm XLOOKUP là
XLOOKUP (lookup, lookup_array, return_array, [not_found], [match_mode], [search_mode]) Các bước: Sử dụng công thức bên dưới trong ô I5 sau đó nhấn ENTER .
=XLOOKUP(1,(H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5),$E$5:$E$16,"NotFound") Công thức XLOOKUP trả về giá phù hợp thỏa mãn các tiêu chí đã cho (tức là, Sản phẩm và Ngày ) như trong hình trên.
🔄 Tự động kiểm tra công thức:
Trình XLOOKUP chỉ định 1 làm đối số tra cứu của nó, (H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5) làm lookup_array, $E$5:$E$16 as return_array . Ngoài ra, công thức sẽ hiển thị văn bản Không tìm thấy trong trường hợp các mục nhập không nằm trong phạm vi ngày. Chúng tôi biểu thị các tiêu chí được chỉ định trong các hình chữ nhật màu như được mô tả trong hình ảnh sau.
➤ Đối với nhiều Sản phẩm, bạn có thể áp dụng công thức XLOOKUP và trích xuất giá khi đáp ứng các tiêu chí đã cho. Ngoài ra, công thức sẽ hiển thị Không tìm thấy nếu tiêu chí ngày đã cho không mở rộng trong ngày đã chophạm vi.
Bạn có thể thêm nhiều tiêu chí hơn tiêu chí được sử dụng trong công thức. Để đưa ra các kịch bản đơn giản và rõ ràng, các tiêu chí tối thiểu đã được sử dụng.
Đọc thêm: Xlookup với nhiều tiêu chí trong Excel (4 cách dễ dàng)
Phương pháp 3: Hàm CHỈ SỐ và TỔNG HỢP để trích xuất Giá dễ biến động từ Phạm vi ngày
Giá của một số Sản phẩm (ví dụ: dầu thô, tiền tệ, v.v.) rất dễ bay hơi nên chúng dao động trong nhiều tuần hoặc thậm chí nhiều ngày. Chúng tôi có giá của một sản phẩm nhất định trong khoảng thời gian một tuần. Chúng tôi muốn tìm giá cho những ngày nhất định. Để tìm giá cho một phạm vi ngày nhất định, chúng ta có thể sử dụng hàm INDEX AGGREGATE kết hợp. Cú pháp của hàm AGGREGATE là
AGGREGATE (function_num, options, ref1, ref2) Các bước: Nhập công thức sau vào bất kỳ ô trống nào (ví dụ: , E8 ).
=IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") 
Giá Ngày đầu tiên của ngày sản phẩm nhất định 02-15-22 đến 02-25-22 là $0,84 . Có thể có mức giá thứ 2 hoặc thứ 3 nhưng lúc đầu, chúng tôi chọn mức giá thứ nhất .
🔄 Khám nghiệm tử thi công thức :
Trong công thức, phần =IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") ;
AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) cung cấp số hàng cho INDEX chức năng. C$5:C$13 là đối số mảng của hàm INDEX .
Bên trong công thức AGGREGATE ,
(B$5:B$13>=F$4)*(B$5:B$13<=F$5) trả về 1 hoặc 0 tùy thuộc vào việc ngày của tập dữ liệu có rơi vàophạm vi hay không.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5)) trả về một mảng các số hàng tùy thuộc vào việc đáp ứng tiêu chí ngày. Nếu không, sẽ dẫn đến các giá trị lỗi.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1 as ref1 dẫn đến một mảng các số hàng được chuyển đổi thành số chỉ mục, nếu không sẽ dẫn đến các giá trị lỗi.
ROWS(E$8:E8) vì ref2 kết quả ở số hàng và đó là một cách dễ dàng để lấy số hàng khi bạn áp dụng công thức xuống dưới.
Số 15 = function_num (tức là, SMALL ), 6 = tùy chọn (tức là, bỏ qua các giá trị lỗi ). Bạn có thể chọn function_num từ 19 chức năng khác nhau và Tùy chọn từ 8 tùy chọn khác nhau.
Cuối cùng, AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) vượt qua số chỉ mục nhỏ nhất thứ n của một hàng thỏa mãn tiêu chí đã cho.
Trong trường hợp xảy ra bất kỳ lỗi nào, IFERROR(INDEX...),"") bỏ qua tất cả các loại lỗi và biến chúng thành khoảng trống.
➤ Kéo Fill Handle để tìm các giá phù hợp khác trong phạm vi ngày của tiêu chí. Và hàm IFERROR dẫn đến các ô trống nếu công thức gặp bất kỳ lỗi nào.
Đọc thêm: Vlookup với Nhiều tiêu chí bao gồm phạm vi ngày trong Excel (2 cách)
Kết luận
Trong bài viết này, chúng tôi trình bày nhiều cách để INDEX MATCH nhiều phạm vi ngày tiêu chí. Chúng tôi sử dụng các hàm như INDEX , MATCH . XLOOKUP và AGGREGATE để tạo công thức lập chỉ mụckhớp các mục thỏa mãn tiêu chí. Hy vọng những cách nêu trên sẽ giúp bạn đối phó với tình huống của mình. Bình luận nếu bạn có thêm thắc mắc hoặc có bất cứ điều gì để bổ sung.
