Obsah
Dnes si ukážeme, ako používať vzorec VLOOKUP Jednou z najdôležitejších a najpoužívanejších funkcií programu Excel je funkcia VLOOKUP Okrem toho môžeme použiť funkcia VBA VLOOKUP na vyhľadávanie konkrétnych údajov v jednom hárku alebo v rámci rozsahu hárkov.
Dnes si tiež ukážeme, ako môžeme využiť Vzorce VLOOKUP hľadať niektoré konkrétne údaje v viacero pracovných hárkov v programe Excel.
Stiahnite si cvičebnicu
Cvičebnicu si môžete stiahnuť tu:
Vzorec VLOOKUP s viacerými listami.xlsx Testovacie známky.xlsxÚvod do funkcie VLOOKUP programu Excel
=VLOOKUP(lookup_value,table_array,col_index_num,[range_lookup])- Táto funkcia preberá rozsah buniek s názvom table_array ako argument.
- Potom vyhľadá konkrétnu hodnotu s názvom lookup_value v prvý stĺpec table_array .
- Okrem toho hľadá približnú zhodu, ak [range_lookup] argument je TRUE , inak hľadá presnú zhodu. Tu je predvolená hodnota TRUE .
- Ak nájde akúkoľvek zhodu lookup_value v prvý stĺpec table_array , presunie sa o niekoľko krokov doprava do konkrétneho stĺpca (col_index_number).
Potom vráti hodnotu z tejto bunky.
Okrem toho prikladáme príklad tohto VLOOKUP Teraz sa pozrite na nasledujúci obrázok.
Rozdelenie vzorca
Tu sa používa vzorec VLOOKUP(G8,B4:D15,3,FALSE) hľadal hodnotu G8 bunka " Angela " v prvý stĺpec tabuľky: B4:D15 .
Keď ho našla, presunula sa priamo k 3. stĺpec (Ako col_index_number je . 3 .)
Potom vrátil hodnotu odtiaľ, bol 322 .
5 spôsobov použitia vzorca VLOOKUP v programe Excel s viacerými listami
Tu máme pracovný zošit so známkami z písomných a živých skúšok niektorých kandidátov za tri týždne v rôznych pracovných listoch. Okrem toho je názov prvého z nich 1. týždeň .
Potom názov 2. pracovný list je 2. týždeň .
Nakoniec názov 3. pracovný list obsahujúci značky Marco Group je . 3. týždeň .
Teraz je naším cieľom získať ich značky z tri hárkov do nového pracovného hárku pomocou VLOOKUP funkcie programu Excel.
1. Vzorec VLOOKUP na vyhľadávanie v každom pracovnom hárku samostatne
Tu máme nový pracovný hárok s názvom "Len VLOOKUP" s menami všetkých kandidátov zoradenými podľa abecedy (od A po Z) Teraz použijeme VLOOKUP vzorec na vyhľadávanie z viacerých hárkov v programe Excel.
Najskôr budeme hľadať v tri pracovné listy samostatne.
Tu budeme hľadať lookup_value z jedného pracovného hárka do rozsahu buniek iného pracovného hárka.
Syntax vzorca bude nasledovná:
=VLOOKUP(lookup_value,'Sheet_name'!table_array, col_index_number,FALSE)- Vyhľadávanie Značky na stránke Napísal z Kandidáti 1. týždňa , zadajte tento vzorec do C5 bunky nového pracovného hárka:
=VLOOKUP(B5,'Week 1'!$B$5:$D$10,2,FALSE) 
- Následne stlačte VSTÚPIŤ .
To sa prejavuje #N/A! Chyba, pretože hodnota bunky B5 v "Len VLOOKUP" list, Alex Hales , nie je v rozsahu B5:D10 listu "Týždeň 1 " .
- Potom potiahnite Rukoväť náplne ikona.
Výsledkom je, že vidíme známky len tých kandidátov, ktorí sa zúčastnili 1. týždeň sa zobrazujú, ostatné zobrazujú chyby.
- Podobne, ak chcete zistiť známku viva, zapíšte si nasledujúci vzorec D5 bunky.
=VLOOKUP(B5,'Week 1'!$B$5:$D$10,3,FALSE) - Potom stlačte tlačidlo VSTÚPIŤ .
- Potom potiahnite Rukoväť náplne použiť vzorec v ostatných bunkách.
Takže vidíme známky len tých kandidátov, ktorí sa zúčastnili 1. týždeň sa zobrazujú, ostatné zobrazujú chyby.
Okrem toho môžeme podobnú úlohu vykonať pre 2. týždeň a 3. týždeň Aj to však neuspokojí naše potreby. Preto musíme hľadať lepší prístup.
Prečítajte si viac: Prečo VLOOKUP vráti #N/A, keď existuje zhoda? (5 príčin a riešení)
2. Vyhľadávanie vo viacerých hárkoch pomocou funkcie IFERROR v programe Excel
Tentoraz budeme najprv hľadať kandidáta v prvom pracovnom hárku ( 1. týždeň ).
Ak ho nenájdeme v prvom hárku, budeme hľadať v druhom hárku ( 2. týždeň ).
A ak ho stále nenájdeme, budeme hľadať v treťom hárku ( 3. týždeň ).
Ak ho stále nenájdeme, rozhodneme, že bol neprítomný zo skúšky.
V predchádzajúcej časti sme videli, VLOOKUP vráti NEUPLATŇUJE SA! Chyba, ak nenájde žiadnu zhodu s lookup_value v table_array .
Tentoraz sa teda zahniezdime VLOOKUP funkcie v rámci . Funkcia IFERROR na spracovanie chýb.
Preto bude syntax vzorca nasledovná:
=IFERROR(VLOOKUP(lookup_value, "Sheet1_Name"!table_array,col_index_number,FALSE),IFERROR(VLOOKUP(lookup_value, "Sheet2_Name"!table_array,col_index_number,FALSE),IFERROR(VLOOKUP(lookup_value, "Sheet3_Name"!table_array,col_index_number,FALSE), "Absent"))- Teraz zadajte nasledujúci vzorec do C5 bunka "VLOOKUP & IFERROR" list.
=IFERROR(VLOOKUP(B5,'Week 1'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'Week 2'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'Week 3'!$B$5:$D$10,2,FALSE), "Absent")) 
- Potom stlačte tlačidlo VSTÚPIŤ .
Výsledkom je, že uvidíte písomné značky Alex Hales .
Potom nájdeme viva známky Alexa Halesa.
- Zapíšte teda nasledujúci vzorec do D5 bunky.
=IFERROR(VLOOKUP(B5,'Week 1'!$B$5:$D$10,3,FALSE),IFERROR(VLOOKUP(B5,'Week 2'!$B$5:$D$10,3,FALSE),IFERROR(VLOOKUP(B5,'Week 3'!$B$5:$D$10,3,FALSE), "Absent")) - Potom stlačte tlačidlo VSTÚPIŤ .
- Potom vyberte obe bunky C5 a D5 .
- Následne presuňte Rukoväť náplne ikonu na Automatické vypĺňanie zodpovedajúce údaje v ostatných bunkách C6:D24 .
Nakoniec uvidíte známky z písomných testov aj z testov viva pre všetkých kandidátov.
Prečítajte si viac: Príklad VLOOKUP medzi dvoma listami v programe Excel
Podobné čítania
- VLOOKUP nefunguje (8 dôvodov & riešenia)
- Excel LOOKUP vs VLOOKUP: s 3 príkladmi
- Čo je pole tabuliek vo VLOOKUP? (Vysvetlené na príkladoch)
- Ako používať vnorený VLOOKUP v programe Excel (3 kritériá)
- Používanie VLOOKUP s viacerými kritériami v programe Excel (6 metód + alternatívy)
3. Použitie kombinovaného vzorca na vyhľadávanie vo viacerých hárkoch v programe Excel
V skutočnosti je vnorený IFERROR a VLOOKUP Vzorec, ktorý sme použili predtým, je užitočný, ale stále je trochu zložitý na používanie. V podstate existuje vysoká pravdepodobnosť, že dôjde k zmätku a generovaniu chýb, ak existuje veľa pracovných hárkov.
Preto vytvoríme ďalší vzorec pomocou INDIRECT , INDEX , MATCH a COUNTIF funkcie, ktoré vyzerajú ešte zložitejšie, ale je pomerne jednoduchšie ich použiť, keď existuje veľa pracovných hárkov.
- Najprv vytvorte horizontálne pole s názvami všetkých pracovných hárkov. Tu sme ho vytvorili v F5:H5 bunky.
- Potom vložte nasledujúci vzorec do C5 bunky.
=IFERROR(VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5)>0,0))&"'!$B$5:$D$10"),2,FALSE), "Absent") - Následne stlačte VSTÚPIŤ .
Rozdelenie vzorca
- Po prvé, COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5) vráti, koľkokrát sa hodnota v bunke B5 sa nachádza v rozsahu 'Týždeň 1'!B5:B10 , "Týždeň 2"!B5:B10 a "3. týždeň"!B5:B10 [Tu $F$5:$H$5 sú názvy pracovných hárkov. Takže INDIRECT vzorec dostáva 'Sheet_Name'!B5:B10 .]
- Výstup: {0,0,1} .
- Po druhé, MATCH(TRUE,{0,0,1}>0,0) vráti, v ktorom hárku je hodnota v B5 je prítomný.
- Výstup: 3 .
- Tu sa vrátil 3 ako hodnota v B5 ( Alex Hales ) je v pracovnom hárku č. 3 ( 3. týždeň ).
- Po tretie, INDEX($F$5:$H$5,1,3) vráti názov pracovného hárka, v ktorom je hodnota v bunke B5 je.
- Výstup: "3. týždeň" .
- Po štvrté, INDIRECT("'"& "3. týždeň"&"'!$B$4:$D$9") vráti celkový rozsah buniek pracovného hárka, v ktorom je hodnota v B5 je prítomný.
- Výstup: {"Nathan Mills",72,59; "Ruth Williamson",53,55; "Alex Hales",67,70; "Matthew Shepherd",76,45; "Christina Paul",69,75; "Ricardo Moyes",57,61}.
- Nakoniec, VLOOKUP(B5,{"Nathan Mills",72,59; "Ruth Williamson",53,55; "Alex Hales",67,70; "Matthew Shepherd",76,45; "Christina Paul",69,75; "Ricardo Moyes",57,61},2,FALSE) vracia 2. stĺpec riadku z tohto rozsahu, kde je hodnota v bunke B5 zápasy.
- Výstup: 67 .
- Toto je teda známka z písomnej skúšky, ktorú sme hľadali.
- A v prípade, že sa názov nenachádza v žiadnom pracovnom hárku, vráti sa "neprítomný" pretože sme ho vnorili do IFERROR funkcie.
Tu môžete použiť podobný vzorec na zistenie Viva známky uchádzačov.
- Zmeňte teda col_index_number z adresy 2 na 3 a napíšte vzorec.
=IFERROR(VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5)>0,0))&"'!$B$5:$D$10"),3,FALSE), "Absent") - Potom stlačte tlačidlo VSTÚPIŤ na získanie výsledku.
- Potom potiahnite Rukoväť náplne ikona.
Nakoniec sme získali písomné aj živé známky všetkých kandidátov. Okrem toho, ktorých mená sme nenašli, boli označení ako neprítomní.
Prečítajte si viac: Funkcia INDEX MATCH vs. VLOOKUP (9 príkladov)
4. Vzorec VLOOKUP s dynamickým číslom indexu stĺpca
Doteraz sme na získanie známok z písomnej skúšky používali col_index_num ako 2 . A pre známky viva, 3 .
Vzorce vkladáme do oboch stĺpcov samostatne.
Ak máme nakoniec viacero stĺpcov, bude dosť problematické vkladať vzorce do všetkých stĺpcov samostatne.
Tentoraz teda vygenerujeme vzorec, aby sme ho mohli vložiť do prvý a pretiahnite ho do všetkých stĺpcov cez Rukoväť náplne ikona.
Jednoduché. Namiesto vloženia čistého čísla ako col_index_num , vložiť STĹPCE($C$1:D1) ak je vzorec v stĺpec C ( Pre písomné známky ).
Potom sa vráti 2 .
Ak ho potom pretiahneme na stĺpec E , stane sa STĹPCE($C$1:E1) a vrátiť 3 A tak ďalej.
- Takže teraz zmeníme vzorec z predchádzajúcej časti na tento:
=IFERROR(VLOOKUP($B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),$B5)>0,0))&"'!$B$5:$D$10"),COLUMNS($C$1:D1),FALSE), "Absent") - Potom stlačte tlačidlo VSTÚPIŤ .
- Potom potiahnite Rukoväť náplne ikonu na pravej strane pre získanie Viva značky.
- Potom potiahnite Rukoväť náplne ikona dole.
Nakoniec uvidíte známky z písomných testov aj z testov viva pre všetkých kandidátov.
Prečítajte si viac: Dynamický VLOOKUP programu Excel (s 3 vzorcami)
5. Vzorec VLOOKUP s kombinovanými funkciami v programe Excel
Tu použijeme iný VLOOKUP vzorec v programe Excel s viacerými hárkami ignoruje IFERROR Pozrime sa na nižšie uvedené kroky.
Kroky:
- Najprv musíte vybrať novú bunku C5 kde chcete uchovávať písomné značky.
- Po druhé, mali by ste použiť vzorec uvedený nižšie v C5 bunky.
=VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,MATCH(1,--(COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!$B$5:$D$10"),B5)>0),0))&"'!$B$5:$D$10"),2,FALSE) - Po tretie, stlačte VSTÚPIŤ .
- Podobne použite nasledujúci vzorec v D5 bunka na získanie známok Viva.
=VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,MATCH(1,--(COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!$B$5:$D$10"),B5)>0),0))&"'!$B$5:$D$10"),3,FALSE) - Následne stlačte VSTÚPIŤ .
- Potom potiahnite Rukoväť náplne ikona.
Nakoniec sa vám zobrazia písomné známky aj známky z testov viva všetkých kandidátov. Okrem toho sa vám zobrazia aj #N/A chyba, keď v uvedených hárkoch chýbali mená.
Obmedzenia funkcie VLOOKUP a niektoré alternatívy v programe Excel
- Tu nemôžete použiť VLOOKUP funkciu, keď lookup_value nie je v prvý v tabuľke. Napríklad v predchádzajúcom príklade nemôžete použiť VLOOKUP funkcia na zistenie mena kandidáta, ktorý získal 90 na písomnej skúške.
- Môžete však použiť IF , IFS , INDEX MATCH , XLOOKUP , alebo FILTER funkcie programu Excel na vyriešenie tohto problému (Tu môžete navštíviť tento článok ).
- Okrem toho, VLOOKUP vráti iba prvý ak viac ako jedna hodnota zodpovedá lookup_value V týchto prípadoch môžete použiť FILTER funkcie na získanie všetkých hodnôt (Tu môžete navštíviť tento článok ).
Ako použiť vzorec VLOOKUP v programe Excel s viacerými zošitmi
V tejto časti sa budeme zaoberať tým, ako aplikovať VLOOKUP vzorec v programe Excel s viacerými zošitmi. Teraz majme nasledujúci zošit s názvom Známky zo skúšobného testu Okrem toho sú v tomto zošite tri aj pracovné listy. Sú to 1. týždeň, 2. týždeň a 3. týždeň .
Tentoraz chceme porovnať predbežné a konečné písomné známky, ktoré získali uchádzači. Najskôr sme zistili konečné písomné známky. Tie tu môžete zistiť podľa niektorej z predchádzajúcich metód. Teraz získame predbežné písomné známky z iného zošita.
- Zapíšte teda nasledujúci vzorec do D5 bunky.
=IFERROR(VLOOKUP(B5,'[Mock Test Marks.xlsx]Week 1'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'[Mock Test Marks.xlsx]Week 2'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'[Mock Test Marks.xlsx]Week 3'!$B$5:$D$10,2,FALSE), "Absent")) V tomto prípade musíte pri použití tohto vzorca otvoriť oba zošity. V opačnom prípade musíte použiť cesta/umiestnenie výplne namiesto použitia iba názvu súboru.
- Potom stlačte tlačidlo VSTÚPIŤ .
- Potom potiahnite Rukoväť náplne ikona dole.
Nakoniec sa zobrazí konečné aj predbežné písomné hodnotenie všetkých kandidátov.
Praktická časť
Vysvetlenú metódu si teraz môžete vyskúšať sami.
Záver
Pomocou týchto metód môžete použiť VLOOKUP funkcie programu Excel ako vzorca na extrahovanie údajov z viacerých listov v zošite. Máte teda ďalšie otázky? Neváhajte sa nás opýtať.
