Tabla de contenido
Hoy mostraremos cómo utilizar la fórmula VLOOKUP En realidad, una de las funciones más importantes y utilizadas de Excel es la función VLOOKUP Además, podemos utilizar la función VLOOKUP de VBA para buscar datos específicos en una sola hoja de cálculo, o dentro de un rango de hojas de cálculo.
Además, hoy mostraremos cómo podemos utilizar Fórmulas VLOOKUP para buscar algunos datos específicos en varias hojas de cálculo en Excel.
Descargar el cuaderno de prácticas
Puede descargar el cuaderno de prácticas desde aquí:
Fórmula VLOOKUP con Múltiples Hojas.xlsx Simulacro de examen Marks.xlsxIntroducción a la función VLOOKUP de Excel
=VLOOKUP(valor_buscado,matriz_tabla,número_índice_col,[rango_buscado])- Esta función toma un rango de celdas llamado tabla_array como argumento.
- A continuación, busca un valor específico denominado buscar_valor en el primero de la columna tabla_array .
- Además, busca una coincidencia aproximada si el [range_lookup] argumento es TRUE en caso contrario, busca una coincidencia exacta. En este caso, el valor predeterminado es TRUE .
- Si encuentra alguna coincidencia del buscar_valor en el primero de la columna tabla_array , se desplaza unos pasos a la derecha hasta una columna específica (número_índice_col).
A continuación, devuelve el valor de esa celda.
Además, adjuntamos un ejemplo VLOOKUP Ahora, mira la siguiente figura.
Desglose de fórmulas
En este caso, la fórmula VLOOKUP(G8,B4:D15,3,FALSE) buscó el valor de G8 célula " Angela " en el primero de la tabla: B4:D15 .
Después de encontrar uno, se trasladó directamente a la Tercero (Como la columna número_índice_col es 3 .)
Luego devolvió el valor de allí, fue 322 .
5 Maneras de Usar la Fórmula VLOOKUP en Excel con Múltiples Hojas
Aquí tenemos un cuaderno de trabajo con las notas de los exámenes escritos y de viva voz de algunos candidatos en tres semanas en diferentes hojas de trabajo. Además, el nombre de la primera es Semana 1 .
A continuación, el nombre del 2ª hoja de trabajo es Semana 2 .
Por último, el nombre del Tercero hoja de trabajo con marcas de Grupo Marco es Semana 3 .
Ahora, nuestro objetivo es extraer sus marcas del tres a la nueva hoja de cálculo mediante la función VLOOKUP de Excel.
1. Fórmula VLOOKUP para buscar en cada hoja de cálculo por separado
Aquí, tenemos una nueva hoja de cálculo llamada "Sólo VLOOKUP" con los nombres de todos los candidatos ordenados alfabéticamente (de la A a la Z) Ahora utilizaremos la función VLOOKUP para buscar en varias hojas de Excel.
En primer lugar, buscaremos en tres hojas de trabajo por separado.
Aquí buscaremos buscar_valor de una hoja de cálculo a un rango de celdas de otra hoja de cálculo.
La sintaxis de la fórmula será:
=VLOOKUP(lookup_value,'Nombre_hoja'!table_array, col_index_number,FALSE)- Para buscar el Marcas en Escrito de la Candidatos de la semana 1 introduzca esta fórmula en el campo C5 de la nueva hoja de cálculo:
=VLOOKUP(B5,'Semana 1'!$B$5:$D$10,2,FALSE) 
- A continuación, pulse INTRODUCE .
Esto muestra ¡#N/A! Error, porque el valor de la celda B5 en el "Sólo VLOOKUP" sábana, Alex Hales no está en el rango B5:D10 de la hoja "Semana 1 " .
- A continuación, arrastre el Asa de llenado icono.
Como resultado, vemos las notas de sólo aquellos candidatos que se presentaron en Semana 1 se están mostrando, el resto están mostrando errores.
- Del mismo modo, para hallar la nota viva, escriba la siguiente fórmula en la casilla D5 celda.
=VLOOKUP(B5,'Semana 1'!$B$5:$D$10,3,FALSE) - A continuación, pulse INTRODUCE .
- A continuación, arrastre el Asa de llenado para aplicar la fórmula en el resto de las celdas.
Por lo tanto, vemos las marcas de sólo los candidatos que se presentaron en Semana 1 se están mostrando, el resto están mostrando errores.
Además, podemos realizar una tarea similar para Semana 2 y Semana 3 también, pero eso no satisfará nuestras necesidades. Por lo tanto, tenemos que buscar un planteamiento mejor.
Más información: ¿Por qué VLOOKUP devuelve #N/A cuando existe una coincidencia? (5 causas y soluciones)
2. Buscar en Múltiples Hojas con la Función IFERROR en Excel
Esta vez buscaremos primero un candidato en la primera hoja de cálculo ( Semana 1 ).
Entonces, si no lo encontramos en la primera hoja de cálculo, buscaremos en la segunda hoja de cálculo ( Semana 2 ).
Y si seguimos sin encontrarlo, buscaremos en la tercera hoja de cálculo ( Semana 3 ).
Si no lo encontramos todavía, decidiremos que fue ausente del examen.
En la sección anterior vimos, VLOOKUP devuelve ¡NO! Error si no encuentra ninguna coincidencia con el campo buscar_valor en el tabla_array .
Así que esta vez anidaremos VLOOKUP funciones dentro de el Función IFERROR para gestionar los errores.
Por lo tanto, la sintaxis de la fórmula será:
=IFERROR(VLOOKUP(lookup_value, "Sheet1_Name"!table_array,col_index_number,FALSE),IFERROR(VLOOKUP(lookup_value, "Sheet2_Name"!table_array,col_index_number,FALSE),IFERROR(VLOOKUP(lookup_value, "Sheet3_Name"!table_array,col_index_number,FALSE), "Ausente"))- Ahora, introduzca la siguiente fórmula en el campo C5 célula del "VLOOKUP & IFERROR" sábana.
=IFERROR(VLOOKUP(B5,'Semana 1'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5, 'Semana 2'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'Semana 3'!$B$5:$D$10,2,FALSE), "Ausente")) 
- A continuación, pulse INTRODUCE .
Como resultado, verá las marcas escritas de Alex Hales .
Entonces, encontraremos las marcas vivas de Alex Hales.
- Por lo tanto, escriba la siguiente fórmula en el D5 celda.
=IFERROR(VLOOKUP(B5,'Semana 1'!$B$5:$D$10,3,FALSE),IFERROR(VLOOKUP(B5,'Semana 2'!$B$5:$D$10,3,FALSE),IFERROR(VLOOKUP(B5,'Semana 3'!$B$5:$D$10,3,FALSE), "Ausente")) - A continuación, pulse INTRODUCE .
- A continuación, seleccione ambas celdas C5 y D5 .
- En consecuencia, arrastre el Asa de llenado icono a Autorrelleno los datos correspondientes en el resto de las celdas C6:D24 .
Por último, podrá ver las notas de todos los candidatos, tanto en la prueba escrita como en la viva.
Más información: Ejemplo de VLOOKUP entre dos hojas en Excel
Lecturas similares
- VLOOKUP No Funciona (8 Razones & Soluciones)
- Excel LOOKUP vs VLOOKUP: Con 3 Ejemplos
- ¿Qué es una matriz de tablas en VLOOKUP? (Explicado con ejemplos)
- Cómo utilizar VLOOKUP anidados en Excel (3 Criterios)
- Usar VLOOKUP con Múltiples Criterios en Excel (6 Métodos + Alternativas)
3. Uso de Fórmulas Combinadas para Buscar en Múltiples Hojas en Excel
En realidad, el IFERROR y VLOOKUP que hemos utilizado antes es útil, pero sigue siendo un poco compleja de utilizar. Básicamente, existe una alta probabilidad de confundirse y generar errores si hay muchas hojas de cálculo.
Por lo tanto, generaremos otra fórmula utilizando el INDIRECTO , ÍNDICE , MATCH y CONSEJO funciones que parecen aún más complejas, pero es comparativamente más fácil de aplicar cuando hay muchas hojas de cálculo.
- En primer lugar, cree una matriz horizontal con los nombres de todas las hojas de cálculo. En este caso, hemos creado una en F5:H5 células.
- A continuación, inserte la siguiente fórmula en el campo C5 celda.
=IFERROR(VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5)>0,0))&"'!$B$5:$D$10"),2,FALSE), "Ausente") - A continuación, pulse INTRODUCE .
Desglose de fórmulas
- En primer lugar, COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5) devuelve cuántas veces el valor de la celda B5 está presente en el intervalo Semana 1 B5:B10 , Semana 2 B5:B10 y ¡Semana 3! B5:B10 respectivamente. [Aquí $F$5:$H$5 son los nombres de las hojas de cálculo, por lo que el campo INDIRECTO fórmula recibe Nombre_hoja B5:B10 .]
- Salida: {0,0,1} .
- En segundo lugar, MATCH(TRUE,{0,0,1}>0,0) devuelve en qué hoja de cálculo está el valor en B5 está presente.
- Salida: 3 .
- Aquí volvió 3 como el valor en B5 ( Alex Hales ) está en la hoja de cálculo no 3 ( Semana 3 ).
- Tercero, INDEX($F$5:$H$5,1,3) devuelve el nombre de la hoja de cálculo donde se encuentra el valor de la celda B5 es.
- Salida: "Semana 3" .
- En cuarto lugar, INDIRECT("'"& "Semana 3″&"'!$B$4:$D$9") devuelve el rango total de celdas de la hoja de cálculo en las que el valor en B5 está presente.
- Salida: {"Nathan Mills",72,59; "Ruth Williamson",53,55; "Alex Hales",67,70; "Matthew Shepherd",76,45; "Christina Paul",69,75; "Ricardo Moyes",57,61}.
- Por fin, VLOOKUP(B5,{"Nathan Mills",72,59; "Ruth Williamson",53,55; "Alex Hales",67,70; "Matthew Shepherd",76,45; "Christina Paul",69,75; "Ricardo Moyes",57,61},2,FALSE) devuelve el 2ª columna de la fila de ese rango en la que el valor de la celda B5 partidos.
- Salida: 67 .
- Así pues, esta es la nota del examen escrito que buscábamos.
- Y en caso de que el nombre no se encuentre en ninguna hoja de cálculo, devolverá "Ausente" porque lo anidamos dentro de un IFERROR función.
En este caso, puede utilizar una fórmula similar para averiguar el Viva de los candidatos.
- Por lo tanto, cambie el número_índice_col de 2 a 3 y escribe la fórmula.
=IFERROR(VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5)>0,0))&"'!$B$5:$D$10"),3,FALSE), "Ausente") - A continuación, pulse INTRODUCE para obtener el resultado.
- A continuación, arrastre el Asa de llenado icono.
Por último, disponemos de las notas escritas y vivas de todos los candidatos. Además, se han marcado como ausentes aquellos cuyos nombres no se han encontrado.
Más información: Función INDEX MATCH vs VLOOKUP (9 Ejemplos)
4. Fórmula VLOOKUP con número de índice de columna dinámico
Hasta ahora, para extraer las notas del examen escrito, utilizábamos col_index_num como 2 Y para las notas de viva, 3 .
En realidad, estamos insertando las fórmulas por separado en ambas columnas.
Eventualmente, cuando tengamos varias columnas, será bastante problemático insertar fórmulas en todas las columnas por separado.
Por lo tanto, esta vez generaremos una fórmula para que podamos insertarla en el archivo primero y arrástrelo a todas las columnas a través de la columna Asa de llenado icono.
Simple. En lugar de insertar un número puro como el col_index_num , insertar COLUMNAS($C$1:D1) si la fórmula está en columna C ( Para las notas escritas ).
A continuación, devolverá 2 .
Entonces, si lo arrastramos a columna E se convertirá en COLUMNAS($C$1:E1) y devolver 3 Y así sucesivamente.
- Así que ahora cambiamos la fórmula del apartado anterior por ésta:
=IFERROR(VLOOKUP($B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),$B5)>0,0))&"'!$B$5:$D$10"),COLUMNS($C$1:D1),FALSE), "Ausente") - A continuación, pulse INTRODUCE .
- A continuación, arrastre el Asa de llenado a la derecha para obtener el Viva marcas.
- A continuación, arrastre el Asa de llenado icono hacia abajo.
Por último, podrá ver las notas de todos los candidatos, tanto en la prueba escrita como en la viva.
Más información: Excel VLOOKUP Dinámico (con 3 Fórmulas)
5. Fórmula VLOOKUP con Funciones Combinadas en Excel
En este caso, utilizaremos otro VLOOKUP en Excel con varias hojas ignorando la IFERROR Veamos los pasos que se indican a continuación.
Pasos:
- En primer lugar, debe seleccionar una nueva celda C5 donde desea guardar las marcas escritas.
- En segundo lugar, debe utilizar la fórmula que figura a continuación en el C5 celda.
=VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,MATCH(1,--(COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!$B$5:$D$10"),B5)>0),0))&"'!$B$5:$D$10"),2,FALSE) - En tercer lugar, pulse INTRODUCE .
- Del mismo modo, utilice la siguiente fórmula en el D5 célula para obtener las marcas Viva.
=VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,MATCH(1,--(COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!$B$5:$D$10"),B5)>0),0))&"'!$B$5:$D$10"),3,FALSE) - A continuación, pulse INTRODUCE .
- A continuación, arrastre el Asa de llenado icono.
Por último, podrá ver las notas escritas y vivas de todos los candidatos. Además, podrá ver la #N/A error en el que faltaban los nombres en las hojas mencionadas.
Limitaciones de la función VLOOKUP y algunas alternativas en Excel
- En este caso, no se puede utilizar el VLOOKUP cuando el buscar_valor no está en el primero de la tabla. Por ejemplo, en el ejemplo anterior, no puede utilizar la columna VLOOKUP función para conocer el nombre del candidato que obtuvo un 90 en el examen escrito.
- Sin embargo, puede utilizar la función SI , IFS , INDEX MATCH , XLOOKUP o FILTRO funciones de Excel para resolver esto (Aquí, usted puede visitar este artículo ).
- Además, VLOOKUP sólo devuelve el primero si hay más de un valor que coincida con buscar_valor En estos casos, puede utilizar la función FILTRO para obtener todos los valores (Aquí, puede visitar este artículo ).
Cómo Aplicar la Fórmula VLOOKUP en Excel con Múltiples Libros de Trabajo
En esta sección, hablaremos de cómo aplicar el VLOOKUP en Excel con varios libros. Ahora, tengamos el siguiente libro llamado Notas del simulacro de examen Además, en ese libro de trabajo, hay tres hojas de trabajo también. Son Semana 1, Semana 2 y Semana 3 .
En este momento, queremos comparar las calificaciones escritas preliminares y finales obtenidas por los candidatos. En primer lugar, encontramos las calificaciones escritas finales. Aquí, usted puede encontrar que siguiendo cualquiera de los métodos anteriores. Ahora, vamos a extraer las calificaciones escritas preliminares de otro libro de trabajo.
- Por lo tanto, escriba la siguiente fórmula en el D5 celda.
=IFERROR(VLOOKUP(B5,'[Mock Test Marks.xlsx]Semana 1'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5, '[Mock Test Marks.xlsx]Semana 2'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'[Mock Test Marks.xlsx]Semana 3'!$B$5:$D$10,2,FALSE), "Ausente")) Aquí, al utilizar esta fórmula, debe abrir ambos libros de trabajo. De lo contrario, tendrá que utilizar la función ruta/ubicación de relleno en lugar de utilizar sólo el nombre del archivo.
- A continuación, pulse INTRODUCE .
- A continuación, arrastre el Asa de llenado icono hacia abajo.
Por último, verá las notas escritas finales y preliminares de todos los candidatos.
Sección práctica
Ahora, puedes practicar el método explicado por ti mismo.
Conclusión
Con estos métodos, puede utilizar el VLOOKUP de Excel como fórmula para extraer datos de varias hojas de un libro. ¿Tienes alguna otra pregunta? No dudes en planteárnosla.
