Зміст
Сьогодні ми покажемо, як використовувати формула VLOOKUP з декількома аркушами в Excel. Власне, однією з найважливіших і найпоширеніших функцій Excel є функція VLOOKUP Крім того, ми можемо використовувати функція VBA VLOOKUP шукати конкретні дані на одному аркуші або в діапазоні аркушів.
Також сьогодні ми покажемо, як ми можемо використовувати Формули VLOOKUP шукати певні дані в кілька робочих аркушів в Excel.
Завантажити Практичний посібник
Ви можете завантажити робочий зошит практики за посиланням:
Формула для перерахунку з декількома аркушами.xlsx Імітація тестових оцінок.xlsxВступ до функції СРЗНАЧЕННЯ в Excel
=VLOOKUP(значення_пошуку,масив_таблиці,номер_індексу_колон,[діапазон_пошуку])- Ця функція отримує діапазон комірок з назвою table_array як аргумент.
- Потім відбувається пошук конкретного значення, яке називається lookup_value в перший стовпчику table_array .
- Крім того, шукає приблизний збіг, якщо [range_lookup]. аргумент полягає в тому, що ПРАВДА інакше шукає точний збіг. Тут, за замовчуванням, це ПРАВДА .
- Якщо він знайде будь-які збіги з lookup_value в перший стовпчику table_array переміщує на кілька кроків вправо до певного стовпчика (col_index_number).
Потім повертає значення з цієї комірки.
Додатково додаємо приклад цього ПЕРЕГЛЯД А тепер подивіться на наступний малюнок.
Розбивка по формулам
Тут формула VLOOKUP(G8,B4:D15,3,FALSE) шукали значення G8 клітина " Анжела. " в перший стовпчик таблиці: B4:D15 .
Після того, як він знайшов його, він попрямував прямо до 3-й стовпчик (як і в колонці col_index_number це 3 .)
Потім повертається значення звідти, яке було 322 .
5 способів використання формули VLOOKUP в Excel з декількома аркушами
Перед нами робочий зошит з оцінками письмових та очних іспитів деяких кандидатів за три тижні в різних аркушах. При цьому, прізвище першого з них Тиждень 1 .
Після цього було названо ім'я 2-й аркуш - це Тиждень 2 .
Насамкінець, назву 3-й аркуш, що містить відмітки про Marco Group це Тиждень 3 .
Тепер наше завдання - витягти їхні сліди з три на новий аркуш за допомогою кнопки ПЕРЕГЛЯД функція Excel.
1. формула VLOOKUP для пошуку на кожному аркуші окремо
Тут у нас з'явився новий робочий аркуш, який називається "Тільки для перегляду" з прізвищами всіх кандидатів, відсортованими в алфавітному порядку (від А до Я) Зараз ми будемо використовувати ПЕРЕГЛЯД формула для пошуку на декількох аркушах в Excel.
Перш за все, ми будемо шукати через три робочі аркуші окремо.
Тут ми будемо шукати lookup_value з одного аркуша в діапазон комірок іншого аркуша.
Синтаксис формули буде таким:
=VLOOKUP(значення_пошуку,'Назва_аркуша'!масив_таблиці, номер_колонці,FALSE)- Для пошуку Знаки в Письмовий про Кандидати 1-го тижня введіть цю формулу в поле C5 комірку нового аркуша:
=VLOOKUP(B5,'Тиждень 1'!$B$5:$D$10,2,FALSE)
- Після цього натисніть ENTER .
Це свідчить про те, що #НІ! Помилка, оскільки значення комірки B5 в "Тільки для перегляду" простирадло, Алекс Хейлз не знаходиться в діапазоні B5:D10 аркуша "Тиждень 1 " .
- Потім перетягніть Ручка наповнення ікону.
В результаті ми бачимо оцінки лише тих кандидатів, які з'явилися в Тиждень 1 відображаються, решта - з помилками.
- Аналогічно, щоб знайти знак viva, запишіть наступну формулу в поле D5 в камеру.
=VLOOKUP(B5,'Тиждень 1'!$B$5:$D$10,3,FALSE)
- Потім натисніть ENTER .
- Потім перетягніть Ручка наповнення щоб застосувати формулу до решти комірок.
Отже, ми бачимо відмітки лише тих кандидатів, які з'явилися в Тиждень 1 відображаються, решта - з помилками.
Крім того, ми можемо виконати аналогічне завдання для Тиждень 2 і Тиждень 3 Але це не задовольнить наші потреби, тому ми маємо шукати кращий підхід.
Читати далі: Чому VLOOKUP повертає #N/A при наявності збігу (5 причин та шляхи вирішення)
2. пошук на декількох аркушах за допомогою функції IFERROR в Excel
Цього разу ми спочатку будемо шукати кандидата на першому робочому аркуші ( Тиждень 1 ).
Потім, якщо ми не знайдемо його/її на першому аркуші, ми будемо шукати на другому аркуші ( Тиждень 2 ).
І якщо ми все одно не знайдемо його/її, то будемо шукати в третьому аркуші ( Тиждень 3 ).
Якщо ми його так і не знайдемо, то будемо вважати, що він був відсутній з іспиту.
У попередньому розділі ми бачили, ПЕРЕГЛЯД прибутки НІ! Помилка, якщо не знайдено жодного збігу з lookup_value в table_array .
Тож цього разу ми будемо гніздитися ПЕРЕГЛЯД функціонує в рамках в "Урядовому кур'єрі". Функція IFERROR працювати над помилками.
Тому синтаксис формули буде таким:
=IFERROR(VLOOKUP(значення_пошуку, "Назва_листа1"!table_array,col_index_umber,FALSE),IFERROR(значення_пошуку, "Назва_листа2"!table_array,col_index_umber,FALSE),IFERROR(значення_пошуку, "Назва_листа3"!table_array,col_index_umber,FALSE), "Відсутні")))- Тепер введіть наступну формулу в поле C5 осередку "VLOOKUP & IFERROR" простирадло.
=IFERROR(VLOOKUP(B5,'Тиждень 1'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'Тиждень 2'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'Тиждень 3'!$B$5:$D$10,2,FALSE), "Відсутні"))
- Потім натисніть ENTER .
В результаті ви побачите письмові позначки Алекс Хейлз .
Тоді ми знайдемо сліди життя Алекса Хейлза.
- Отже, запишемо наступну формулу в D5 в камеру.
=IFERROR(VLOOKUP(B5,'Тиждень 1'!$B$5:$D$10,3,FALSE),IFERROR(VLOOKUP(B5,'Тиждень 2'!$B$5:$D$10,3,FALSE),IFERROR(VLOOKUP(B5,'Тиждень 3'!$B$5:$D$10,3,FALSE), "Відсутні"))
- Після цього натисніть ENTER .
- Потім виділіть обидві комірки C5 і D5 .
- Отже, перетягніть Ручка наповнення іконку до Автозаповнення відповідні дані в інших комірках C6:D24 .
Нарешті, ви побачите як письмові, так і усні оцінки всіх кандидатів.
Читати далі: Приклад переходу між двома аркушами в Excel
Схожі читання
- VLOOKUP не працює (8 причин та шляхи вирішення)
- Excel LOOKUP vs VLOOKUP: на 3 прикладах
- Що таке табличний масив у VLOOKUP (пояснення на прикладах)
- Як використовувати вкладену таблицю в Excel (3 критерії)
- Використання СЦЕПИ з декількома критеріями в Excel (6 способів + альтернативи)
3. використання комбінованої формули для пошуку на декількох аркушах в Excel
Власне, вкладений ПОМИЛКА і ПЕРЕГЛЯД формула, яку ми використовували раніше, є корисною, але все ще дещо складною у використанні. В основному, існує висока ймовірність заплутатися і генерувати помилки, якщо є багато робочих аркушів.
Таким чином, сформуємо ще одну формулу, використовуючи НЕПРЯМИЙ , ІНДЕКС , МАТЧ і COUNTIF функції, які виглядають ще більш складними, але порівняно легше застосовуються, коли є багато робочих аркушів.
- Перш за все, створюємо горизонтальний масив з назвами всіх робочих аркушів. Тут ми створили такий масив в F5:H5 клітини.
- Потім вставте наступну формулу в поле C5 в камеру.
=IFERROR(VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5)>0,0))&"'!$B$5:$D$10"),2,FALSE), "Немає")
- Після цього натисніть ENTER .
Розбивка по формулам
- По-перше, COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5) повертає, у скільки разів значення в комірці більше B5 присутній в асортименті "Тиждень 1"! B5:B10 , "Тиждень другий"! B5:B10 і "Тиждень 3"! B5:B10 відповідно. [Тут $F$5:$H$5 це назви робочих аркушів. Так що НЕПРЯМИЙ формула отримує 'Назва_листа'!B5:B10 .]
- Вихідні дані: {0,0,1} .
- По-друге, MATCH(TRUE,{0,0,1}>0,0) повертає, на якому аркуші значення в B5 присутній.
- Виходьте: 3 .
- Тут він повернувся 3 як значення в B5 ( Алекс Хейлз ) знаходиться в робочому аркуші no 3 ( Тиждень 3 ).
- По-третє, INDEX($F$5:$H$5,1,3) повертає ім'я робочого аркуша, на якому знаходиться значення в комірці B5 є.
- Вихідні дані: "Тиждень 3" .
- По-четверте, INDIRECT("'"& "Тиждень 3″&"'!$B$4:$D$9") повертає загальний діапазон комірок робочого аркуша, в яких значення в B5 присутній.
- Вихідні дані: {"Nathan Mills",72,59; "Ruth Williamson",53,55; "Alex Hales",67,70; "Matthew Shepherd",76,45; "Christina Paul",69,75; "Ricardo Moyes",57,61}.
- Нарешті, VLOOKUP(B5,{"Натан Міллз",72,59; "Рут Вільямсон",53,55; "Алекс Хейлз",67,70; "Метью Шепард",76,45; "Крістіна Пол",69,75; "Рікардо Мойес",57,61},2,FALSE) повертає значення 2-й стовпчик рядка з того діапазону, де значення в комірці B5 збіги.
- Вихід: 67 .
- Отже, це та оцінка письмового іспиту, яку ми шукали.
- А у випадку, якщо ім'я не буде знайдено в жодному аркуші, він повернеться "Відсутній" тому що ми вклали його в гніздо ПОМИЛКА функцію.
Тут ви можете скористатися аналогічною формулою, щоб дізнатися Віва! оцінки кандидатів.
- Отже, змінити col_index_number від 2 до 3 і напишіть формулу.
=IFERROR(VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),B5)>0,0))&"'!$B$5:$D$10"),3,FALSE), "Немає")
- Потім натисніть ENTER щоб отримати результат.
- Потім перетягніть кнопку Ручка наповнення ікону.
Нарешті, ми отримали як письмові, так і усні оцінки всіх кандидатів. Крім того, ті, чиї прізвища не були знайдені, були позначені як відсутні.
Читати далі: Функція INDEX MATCH vs VLOOKUP (9 прикладів)
4. формула VLOOKUP з динамічним номером індексу стовпця
До цього часу для виведення оцінок на письмовому іспиті ми використовували col_index_num як 2 І за відмітки "віва", 3 .
Власне, ми вставляємо формули окремо в обидві колонки.
Зрештою, коли ми матимемо кілька колонок, буде досить клопітно вставляти формули в усі колонки окремо.
Отже, цього разу ми згенеруємо формулу так, щоб можна було вставити формулу в перший і перетягніть його на всі стовпці через кнопку Ручка наповнення ікону.
Все просто. Замість того, щоб вставити чисте число в якості col_index_num вставити COLUMNS($C$1:D1) якщо формула в колонка С ( Для письмових знаків ).
Потім вона повернеться 2 .
Потім, якщо ми затягнемо його в колонка E , вона стане COLUMNS($C$1:E1) і повернутися 3 І так далі.
- Отже, тепер ми змінюємо формулу в попередньому розділі на цю:
=IFERROR(VLOOKUP($B5,INDIRECT("'"&INDEX($F$5:$H$5,1,MATCH(TRUE,COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!B5:B10"),$B5)>0,0))&"'!$B$5:$D$10"),COLUMNS($C$1:D1),FALSE), "Немає")
- Потім натисніть ENTER .
- Після цього перетягніть кнопку Ручка наповнення праворуч, щоб отримати Віва! знаки.
- Потім перетягніть Ручка наповнення іконку вниз.
Нарешті, ви побачите як письмові, так і усні оцінки всіх кандидатів.
Читати далі: Динамічна таблиця Excel (з 3 формулами)
5. формула VLOOKUP з комбінованими функціями в Excel
Тут ми скористаємося ще одним ПЕРЕГЛЯД формулу в Excel з декількома аркушами, ігноруючи ПОМИЛКА Отже, давайте подивимось на кроки, наведені нижче.
Сходинки:
- По-перше, необхідно виділити нову комірку C5 де ви хочете зберігати письмові позначки.
- По-друге, слід використовувати формулу, наведену нижче в C5 в камері.
=VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,MATCH(1,--(COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!$B$5:$D$10"),B5)>0),0))&"'!$B$5:$D$10"),2,FALSE)
- По-третє, преса ENTER .
- Аналогічно, використовуйте наступну формулу в D5 для отримання знаків Viva.
=VLOOKUP(B5,INDIRECT("'"&INDEX($F$5:$H$5,MATCH(1,--(COUNTIF(INDIRECT("'"&$F$5:$H$5&"'!$B$5:$D$10"),B5)>0),0))&"'!$B$5:$D$10"),3,FALSE)
- Після цього натисніть ENTER .
- Потім перетягніть кнопку Ручка наповнення ікону.
Нарешті, ви побачите як письмові, так і усні оцінки всіх кандидатів. Крім того, ви побачите #N/A помилка, коли прізвища були відсутні у згаданих аркушах.
Обмеження функції VLOOKUP та деякі альтернативи в Excel
- Тут ви не можете використовувати ПЕРЕГЛЯД функціонувати, коли lookup_value не входить до складу перший Наприклад, у попередньому прикладі не можна використовувати стовпець ПЕРЕГЛЯД функцію, щоб дізнатися ім'я кандидата, який отримав 90 на письмовому іспиті.
- Однак, ви можете скористатися послугами ЯКЩО , IFS , ЗБІГ ІНДЕКСІВ , XLOOKUP або ФІЛЬТР функції Excel для вирішення цього завдання (тут ви можете відвідати ця стаття ).
- Більше того, ПЕРЕГЛЯД повертає тільки перший значення, якщо більше одного значення відповідає lookup_value У цих випадках ви можете скористатися послугами ФІЛЬТР для отримання всіх значень (тут ви можете відвідати ця стаття ).
Як застосувати формулу VLOOKUP в Excel з кількома книгами
У цьому розділі ми поговоримо про те, як застосовувати ПЕРЕГЛЯД формулу в Excel з декількома книгами. Нехай у нас є наступна книга з ім'ям Імітація тестових знаків Крім того, в цьому робочому зошиті є три робочі аркуші теж. Вони Тиждень 1, тиждень 2 і Тиждень 3 .
Цього разу ми хочемо порівняти попередні та остаточні письмові оцінки, які отримали кандидати. Спочатку ми знайшли остаточні письмові оцінки. Тут ви можете знайти їх, скориставшись будь-яким із попередніх способів. Тепер ми витягнемо попередні письмові оцінки з іншого зошита.
- Отже, запишемо наступну формулу в D5 в камеру.
=IFERROR(VLOOKUP(B5,'[Mock Test Marks.xlsx]Тиждень 1'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'[Mock Test Marks.xlsx]Тиждень 2'!$B$5:$D$10,2,FALSE),IFERROR(VLOOKUP(B5,'[Mock Test Marks.xlsx]Тиждень 3'!$B$5:$D$10,2,FALSE), "Відсутній"))
Тут при використанні цієї формули необхідно відкрити обидві робочі книги. В іншому випадку доведеться використовувати функцію шлях/місце заповнення замість того, щоб використовувати тільки ім'я файлу.
- Потім натисніть ENTER .
- Потім перетягніть Ручка наповнення іконку вниз.
Нарешті, ви побачите як остаточні, так і попередні письмові оцінки для всіх кандидатів.
Практична секція
Тепер ви можете практикувати пояснену методику самостійно.
Висновок
За допомогою цих методів можна використовувати ПЕРЕГЛЯД функція Excel як формула для вилучення даних з декількох аркушів робочої книги. Якщо у вас залишилися питання, задавайте їх нам.