Microsoft Excel에서 여러 값이나 숫자의 순위를 매기는 것은 일상적인 작업입니다. 데이터 세트에서 항목의 순위를 지정해야 하는 다양한 경우에 직면하게 됩니다. 순위에는 단일 기준 또는 여러 기준이 포함될 수 있습니다. 어느 쪽이든 순위를 계산할 수 있습니다. 이 자습서에서는 적절한 예와 적절한 그림을 사용하여 Excel에서 Rank IF 수식을 사용하는 방법을 배웁니다. 계속 지켜봐 주시기 바랍니다.

실습 워크북 다운로드

이 실습 워크북을 다운로드하십시오.

랭크 IF.xlsx 사용 방법

엑셀 순위 함수

이제 여러 항목의 순위를 매기려면 엑셀 순위 함수 가 내장되어 있습니다. 이 함수는 기본적으로 지정한 열을 기준으로 여러 값의 순위를 매깁니다. 값을 오름차순 또는 내림차순으로 정렬할 수 있습니다. 목록을 내림차순(최대에서 최소) 또는 오름차순(최소에서 최대)으로 정렬하는 숫자 목록에서 숫자의 비교 위치를 지정하는 가장 간단한 방법입니다.

이 기능은 다음:

보시다시피 RANK 기능은 마크를 기준으로 학생의 순위를 매깁니다. 오름차순 또는 내림차순으로 정렬할 수 있습니다. 하지만 항목에 순위를 매기는 조건이 없다는 것을 분명히 알 수 있습니다.

이 기능을 사용하여 항목에 순위를 매기는 방법은 여러 가지가 있습니다. 이에 대한 자세한 내용은 Excel에서 RANK 함수를 사용하는 방법(5가지 예 포함) .

순위를 매길 수 있습니까?단일 함수에 조건이 적용되는 경우?

다음은 중요한 질문입니다. 단순히 RANK 기능을 사용하여 단일 또는 여러 기준 에 따라 숫자, 값 및 항목의 순위를 매길 수 있습니까? 아니면 존재하는 RANKIF 기능이 있습니까? 죄송합니다. Excel에는 RANKIF 기능이 없습니다. 순위를 만들기 위해 다른 함수를 사용합니다.

RANKIF 는 기본적으로 조건부 순위입니다. 기준에 따라 여러 값의 순위를 매기기 위해 Excel의 COUNTIFS 함수 및 SUMPRODUCT 함수 를 사용합니다. 이러한 함수는 이 기사에서 기대하는 것과 동일한 출력을 제공합니다.

이후 섹션에서 이에 대해 자세히 설명합니다.

5 Excel의 Rank If 수식 예

다음 섹션에서는 Excel 통합 문서에 구현할 Rank IF 수식의 5가지 실용적인 예를 제공합니다. 이러한 예는 항목 순위 지정에 대한 더 나은 아이디어를 얻는 데 도움이 됩니다. 이 주제를 더 잘 이해하려면 이러한 모든 방법을 배우고 적용하는 것이 좋습니다.

1. 그룹과 일치하는 경우 학생의 점수 순위

이 예에서는 일부 학생의 순위를 매깁니다. '는 주제 그룹을 기준으로 표시합니다. 여기에서는 COUNTIFS 함수를 사용하여 숫자의 순위를 매기고 있습니다.

우리가 사용할 일반 공식은 다음과 같습니다.

=COUNTIFS( criteria_range,criteria,values,”>”&value)+1

다음 데이터 세트:

이제 다음 단계에 따라 그룹을 기반으로 순위를 생성합니다.

📌 단계

• 먼저 셀 E5 에 다음 수식을 입력합니다.

=COUNTIFS($C$5:$C$13,C5,$D$5:$D$13,">"&D5)+1

• 그 다음 Enter 를 누르고 채우기 핸들 아이콘을 셀 범위 위로 드래그합니다 E6:E13 .

보시다시피 우리의 수식은 Excel에서 그룹을 기준으로 순위를 만드는 데 성공했습니다. 따라서 항목의 순위를 매기는 Rank IF 공식처럼 작동합니다.

🔎 공식은 어떻게 작동했습니까?

COUNTIFS 기능은 여러 기준을 사용하여 조건부 카운트를 실행합니다. 이러한 조건을 기준 범위로 입력했습니다.

=COUNTIFS(C5:C13,C5)

이 함수는 세 개의 과학 그룹이 있으므로 세 개를 반환합니다.

두 번째 기준은 다음과 같습니다.

=COUNTIFS($C$5:$C$13,C5,$D$5:$D$13,”>”&D5)

현재 마크가 다른 마크보다 큰지 검색하는 기능입니다.

=COUNTIFS($C$5:$C$13,C5,$D$5:$ D$13,”>”&D5)+1

여기서 이 방정식에 1을 더합니다. 해당 그룹에서 점수가 가장 높으면 0을 반환하기 때문입니다. 하지만 0부터 순위를 매길 수는 없습니다. 그래서 우리는 1부터 순위를 시작하기 위해 플러스 1을 추가했습니다.

중복 제거

여기에 문제가 있습니다. 동일한 학생 두 명에 대해 동일한 점수를 받은 경우 둘 다 1로 평가됩니다.다음 항목의 순위는 3입니다. 따라서 순위는 1,1,3이 됩니다. 이 혼동을 없애려면 다음 수식을 입력하십시오.

=(COUNTIFS($C$5:$C$13,C5)+1-(COUNTIFS($C$5:$C$13,C5,$D$5:$D$13,">"&D5)+1)-(COUNTIFS($C$5:$C$13,C5,$D$5:$D$13,"<"&D5)+1))/2

데이터 세트에 중복 항목이 없으면 0을 반환합니다.

자세히 보기: 엑셀에서 그룹 내 순위를 매기는 방법(3가지 방법)

2. 엑셀에서 순위 IF 수식을 뒤집기

이제 앞에서 보여드린 예는 내림차순이었습니다. 즉, 가장 큰 것부터 가장 작은 것까지 순위를 계산합니다. 이 공식을 쉽게 뒤집을 수 있습니다. 수식에서 간단한 조정을 수행하십시오. 보다 큼( > ) 연산자를 보다 작은( < ) 연산자로 변경합니다.

일반 공식:

=COUNTIFS(criteria_range,criteria,values,”<“&value)+1

다음 단계에 따라 변경 사항을 확인하세요.

📌 단계

• 먼저 셀 E5 에 다음 수식을 입력합니다.

=COUNTIFS($C$5:$C$13,C5,$D$5:$D$13,"<"&D5)+1

• 그 다음 Enter 를 누르고 채우기 핸들 아이콘을 셀 범위 위로 드래그합니다 E6:E13 .

보시다시피 엑셀에서 내림차순 기준으로 순위를 만드는 데 성공했습니다.

제품 기반 판매 수식

이 예에서는 COUNTIFS 함수를 사용하여 여러 기준에 따라 순위 항목을 계산합니다. 이전 예제를 읽었다면 쉬운 작업이 될 것입니다. 이전 예제를 읽으십시오.더 잘 이해할 수 있습니다.

데이터세트를 살펴보세요.

몇몇 판매원의 판매 제품과 총 판매액이 있습니다. 이 데이터 세트는 이전 데이터 세트와 약간 다릅니다. 여기에서는 제품을 기준으로 순위를 계산합니다. 그러나 제품은 데이터 세트에 흩어져 있습니다. 이전 그룹과 같은 그룹에 있지 않습니다.

📌 단계

• 처음에는 셀 E5 에 다음 수식을 입력합니다.

=COUNTIFS($C$5:$C$18,C5,$D$5:$D$18,">"&D5)+1

• 이제 Enter 를 누르고 채우기 핸들 셀 범위의 아이콘 E6:E13 .

마지막으로 Rank IF<생성에 성공했습니다. COUNTIFS 함수를 사용하여 Excel에서 7> 수식.

유사 읽기

• Excel에서 순위 그래프를 만드는 방법 (5가지 방법)
• Excel에서 직원 스택 순위 지정(3가지 방법)
• Excel에서 평균 순위 지정 방법(4가지 일반적인 시나리오)
• Excel에서 순위 백분위수를 계산하는 방법(적절한 7가지 예)

4. 분기를 기준으로 매출 순위를 매기는 IF 공식 순위

여기서는 이전과 동일한 공식을 사용하고 있습니다. 그러나 여기서는 테이블에서 수행할 것입니다. 이제 Excel 표를 사용하여 데이터세트에 대한 다양한 작업을 계산할 수 있습니다.

데이터세트 살펴보기:

여기에 판매 데이터가 있습니다. 1년의 분기. 기준에 따라 순위를 생성합니다.“ 분기 ”.

📌 단계

• 먼저 전체 데이터 세트를 선택합니다.

• 그런 다음 키보드의 Ctrl+T 를 눌러 표로 변환합니다.
• 다음 Cell에 다음 수식을 입력합니다. E5 :

=COUNTIFS($C$5:$C$16,C5,$D$5:$D$16,">"&D5)+1

• 그런 다음 Enter 키를 누르고 셀 범위에 대한 채우기 핸들 아이콘 E6:E16 .

• 이제 다음을 수행할 수 있습니다. 정렬 또는 필터링 하여 해당 분기의 최고 실적 월과 최저 실적 월을 확인합니다. 순위를 정렬하거나 필터링합니다.

따라서 Excel Rank IF 수식을 만들어 순위를 계산할 수 있습니다. 여러 기준에 대한 특정 데이터 세트.

5. Excel에서 SUMPRODUCT 함수를 사용하는 Rank IF 공식

이제 SUMPRODUCT 함수 를 사용하여 조건을 기반으로 순위를 생성할 수 있습니다. 엑셀에서. 또한 Rank IF 공식처럼 작동하여 단일 또는 여러 기준을 기반으로 순위를 생성합니다.

우리가 사용할 일반 공식:

=SUMPRODUCT((criteria_range=criteria)*(value>values))+1

다음 데이터 세트를 살펴보십시오.

여기에 직원 데이터가 있습니다. 부서 급여를 기준으로 급여 순위를 계산합니다. 과정은 비슷합니다. SUMPRODUCT 기능만 사용하겠습니다.

📌 단계

• 처음에는 셀 E5 에서 다음 공식:

=SUMPRODUCT(($C$5:$C$18=C5)*(D5>$D$5:$D$18))+1

• 다음으로 Enter 키를 누릅니다. 채우기 핸들 아이콘을 셀 범위 E6:E13 위로 드래그합니다.

컬러 그레이딩, 부서별로 순위를 차등화하려고 노력했습니다. 이 Excel 수식 은 당신이 원했던 Rank If 수식처럼 작동합니다.

🔎 수식은 어떻게 작동했습니까?

SUMPRODUCT 는 하나 이상의 배열을 인수로 취하고 모든 배열의 해당 값을 곱한 다음 곱의 합계를 반환합니다. 이러한 조건을 기준 범위로 입력했습니다.

=($C$5:$C$18=C5)

전체 열을 확인하여 일치하는 항목을 찾습니다. 배열을 반환합니다. 일치하는 항목이 있으면 TRUE 를 반환하고 일치하지 않는 값에 대해서는 FALSE 를 반환합니다.

이제 두 번째 기준은 다음과 같습니다.

=(D5>$D$5:$D$18)

급여를 확인합니다. 내림차순으로 정렬합니다. D5 보다 크거나 같은 급여에 대해 TRUE 을 반환하고 그렇지 않으면 FALSE 를 반환합니다. 오름차순으로 정렬하려면 보다 큼 기호 (D5<$D$5:$D$18)를 변경합니다.

=SUMPRODUCT(($C$5:$C$18 =C5)*(D5>$D$5:$D$18))+1

마지막으로 SUMPRODUCT 함수는 1과 0의 배열 값을 합산합니다. 각 그룹의 가장 큰 숫자에 대해 0을 반환합니다. 그리고 결과에 1을 추가하여 순위를 매기기 시작했습니다.1.

💬 기억해야 할 사항

✎ 이 기사를 내림차순(내림차순)으로 시연했습니다. 필요에 따라 순위를 변경할 수 있습니다.

✎ 공식에 1을 더하는 것을 잊지 마세요. 그렇지 않으면 0부터 순위가 생성됩니다.

✎ Excel의 모든 순위 절차는 숫자 값에만 적용됩니다. 양수 및 음수, 0, 날짜 및 시간 값이어야 합니다. 숫자가 아닌 값은 무시합니다.

결론

결론적으로 이 자습서가 Excel의 Rank IF 수식에 대한 유용한 지식을 제공했으면 합니다. . 이러한 지침을 모두 배우고 데이터 세트에 적용하는 것이 좋습니다. 실습 워크북을 다운로드하여 직접 해보십시오. 또한 의견 섹션에서 의견을 자유롭게 제공하십시오. 귀하의 소중한 피드백은 저희가 이와 같은 자습서를 만들도록 동기를 부여합니다.

다양한 Excel 관련 문제 및 해결 방법에 대해 Exceldemy.com 웹 사이트를 확인하는 것을 잊지 마십시오.

새로운 방법을 계속 배우고 계속 성장하세요!