Kiel SUMIF inter Du Datoj kaj kun Alia Kriterio (7 Manieroj)

Hugh West

18-10-2023 Excel Formuloj
  • Kundividu Ĉi Tion
Hugh West

Se vi serĉas kelkajn el la plej facilaj manieroj SUMIF inter du datoj kaj aliaj kriterioj, tiam vi trovos ĉi tiun artikolon utila. Aldonado de valoroj en limo de tempoperiodoj kaj surbaze de kriterioj necesas foje esti farita kaj por fari ĉi tiun taskon rapide vi povas sekvi ĉi tiun artikolon.

Elŝutu Laborlibron

SUMIF inter Datoj.xlsm

7 Manieroj por SUMIF inter Du Datoj kaj kun Alia Kriterio

Ĉi tie, ni havas la jenan datumaron enhavantan vendajn registrojn de iuj produktoj kun iliaj taksitaj liverdatoj kaj vendado de regionoj de firmao. Uzante ĉi tiun datuman aron ni montros la manierojn resumi vendajn valorojn bazitajn sur specifa regiono kaj datintervalo.

Ni uzis Microsoft Excel 365 version. ĉi tie, vi povas uzi ajnajn aliajn versiojn laŭ via oportuno.

Metodo-1: Uzado de SUMIFS-Funkcio por SUMIF inter Du Datoj kun Alia Kriterio

Ni volas sumigi la vendajn valorojn por la Orienta Regiono kaj por la datoj inter 1/10/2022 kaj 20/3/2022 (m-dd-yyyy) uzante la SUMIFS-funkcion ĉi tie.

Paŝoj :

➤ Tajpu la jenan formulon en ĉelo E14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&C14,D4:D11,"East")

Ĉi tie, E4:E11 estas la vendintervalo, kiujn valorojn ni volas sumi, C4:C11 estas la datintervalo por la unuaj kriterioj, “>="&B14 estas la unua kriteriokio signifas pli granda aŭ egala al la komenca dato 1/10/2022 . La dua kriteriointervalo estas simila al la unua kaj la kriterioj por ĉi tiu gamo estas “<="&C14 kio signifas malpli ol aŭ egala al la findato 3/20/2022 kaj la lasta kriteriogamo estas D4:D11 enhavanta la regionojn, la kriterioj por ĉi tiu intervalo estus Orienta .

➤ Premu ENTER .

Nun, vi ricevos la sumon de vendoj de $13,806.00 por nia difinita datintervalo kun alia kriterio: Orienta Regio .

Legu Pli: Kiel fari SUMIF Datintervalan Monaton en Excel (9 Manieroj)

Metodo-2: Uzante SUMIFS kaj EOMONTH por SUMIF inter Du Datoj kun Alia Kriterio

En ĉi tiu sekcio, ni provos trovi la sumon de la vendaj valoroj por la datoj de januaro monato kaj la Suda Regiono . Do, ni uzos la EOMONATO-funkcion kun la SUMIFS-funkcio ĉi tie.

Paŝoj :

➤ Tajpu la jenan formulon en ĉelo D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&EOMONTH(B14,0),D4:D11,C14)

Jen, E4:E11 estas la venda gamo, kiujn ni volas sumi valorojn, C4:C11 estas la datintervalo por la unuaj kriterioj, “>="&B14 estas la unua kriterio kiu signifas pli granda aŭ egala al la komenca dato 1/1/2022 . La dua kriteriogamo estas simila al la unua kaj lakriterioj por ĉi tiu gamo estas “<=”&EOMONATO(B14,0) kio signifas malpli aŭ egala al la findato de januaro monato, 1/31/2022 , kaj la lasta kriteriogamo estas D4:D11 enhavanta la regionojn, la kriterioj por ĉi tiu gamo estus Orienta .

➤ Premu ENTER .

Post tio, vi ricevos la sumon de vendoj, $6,835.00 por la datoj de januaro monato kun alia kriterio: Suda Regiono .

Legu Pli: Kiel Uzi SUMIFS por SUMI valorojn en Datintervalo en Excel

Metodo-3: SUMIFS kaj DATO-Funkcioj al SUMIF inter Du Datoj

Ĉi tie, ni uzos la SUMIFS-funkcion kaj la DATO funkcio , por resumi, la vendaj valoroj por la Norda Regiono kaj por la datoj ene de 1/10/2022 kaj 3/20/2022 .

Paŝoj :

➤ Tajpo la jena formulo en ĉelo E14 .

=SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)

Jen, E4: E11 estas la vendintervalo, kiujn valorojn ni volas sumi, C4:C11 estas la datintervalo por la unua kaj dua kriterioj, kaj la lasta kriteriointervalo estas D4:D11 enhavanta la regionojn.

  • DATE(2022,1,10) → redonas nombron de datovaloro

    Eligo → 44571

  • ">="&DATE(2022,1,10) iĝas

    ">= 44571"

  • DATE(2022,3,20) → resendas nombron de datovaloro

    Eligo → 44640

  • "<="&DATE(2022,3,20) iĝas

    "<= 44640"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) iĝas

    SUMIFS(E4:E11,C4:C11,">= 44571",C4:C11,"<= 44640",D4:D11, “North”) → kontrolas ĉu la datvaloroj de la intervalo C4:C11 estas pli grandaj ol aŭ egalaj al 44571 kaj malpli ol aŭ egala al 44640 kaj la regiono Norda en la D4:D11 intervalo

    Eligo → $9,496.00

➤ Premu ENTER .

Tiam, vi ricevos la sumon de vendoj, $9,496.00 por nia difinita datintervalo kun la aliaj kriterioj: Norda Regio .

Rilata Enhavo: Kiel Uzi IF-Formulon por Datintervalo en Excel (6 Metodoj)

Similaj Legadoj:

  • Kiel Agordi Dat-Rememorigilon en Excel (3 Rapidaj Metodoj)
  • Uzu Pivota Tabelo por Filtri Datintervalon en Excel (5 Manieroj)
  • VLOOKUP Datintervalo kaj Revena Valoro en Excel (4 Taŭgaj Metodoj)
  • Kiel Kalkuli Mezumon Se en Datintervalo en Excel (3 Manieroj)

Metodo-4: Uzado de SUMIFS-Funkcio kun HODIAŬ

S supozu, vi volas ricevi la totalajn vendovalorojn por la datoj inter 1/1/2022 kaj la hodiaŭa dato ( 3/23/2022 ) kaj por la Orienta Regiono . Kaj, por fari tion, vi povas uzi la HODIAŬ-funkcion kune kun la SUMIFS-funkcio .

Paŝoj :

➤ Tajpu la jenan formulon en ĉelo D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY(),D4:D11,C14)

Jen, E4:E11 estas la venda gamo kiuvalorojn, kiujn ni volas sumi, C4:C11 estas la datintervalo por la unua kaj dua kriterioj, kaj la lasta kriteriointervalo estas D4:D11 enhavanta la regionojn.

  • ">="&B14 iĝas

    ">= 44562"

  • TODAY() → resendas la hodiaŭan daton

    Eligo → 44643 (23/3/2022)

  • "<="&TODAY() iĝas

    "<= 44643"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) iĝas

    SUMIFS(E4:E11,C4:C11,">= 44562",C4:C11,"<= 44643",D4:D11, “East”) → kontrolas ĉu la datvaloroj de la intervalo C4:C11 estas pli grandaj ol aŭ egalaj al 44562 kaj malpli ol aŭ egalaj al 44643 kaj la regiono Orienta en la D4: D11 gamo

    Eligo → $15,208.00

➤ Premu ENTER .

Fine, vi ricevos la sumon de vendoj, kiu estas $15,208.00 por la datoj inter la unua tago de januaro 2022 kaj la hodiaŭa dato kun kriterioj: Orienta Regiono .

Se vi volas ŝanĝi la lastan daton de la dato intervalo de la hodiaŭa dato ĝis 10 tagoj antaŭ la hodiaŭa dato tiam uzu la sekvan formulon

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()-10,D4:D11,C14)

Por la lasta dato kiel dato 10 tagojn post la hodiaŭa dato

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()+10,D4:D11,C14)

Legu Pli: Excel VBA: Filtrila Dato antaŭ Hodiaŭ (Kun Rapidaj Paŝoj)

Metodo-5: Kombinaĵo de SUM kaj SE-Funkcioj al SUMIF inter Du Datoj kaj kun Alia Kriterio

Vi povas uzi la kombinaĵon de la SUM-funkcio kaj la IF-funkcio alkalkulu la totalajn vendojn por la datoj inter 1/10/2022 ĝis 3/20/2022 kaj por la Orienta Regiono .

Paŝoj :

➤ Tajpu la jenan formulon en ĉelo E14 .

=SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))

Jen, E4:E11 estas la venda gamo, kiujn valorojn ni volas sumi, C4 :C11 estas la datintervalo por la unua kaj dua kriterioj, kaj la lasta kriteriointervalo estas D4:D11 enhavanta la regionojn.

  • IF((C4:C11)>=B14 → kontrolas ĉu la datvaloroj de la intervalo C4:C11 estas pli grandaj ol aŭ egalaj al la valoro de B14 .

    Eligo → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • IF((C4:C11)<=C14 → kontrolas ĉu la datvaloroj de la intervalo C4:C11 estas malpli ol aŭ egalaj al la valoro de C14 .

    Eligo → {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE}

  • IF(D4:D11=D14,E4:E11) → kontrolas ĉu la regionoj de la intervalo D4:D11 estas egalaj al la regiono Orienta de C14 kaj redonas

    ({TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}, E4:E11)

    Eligo → {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))) iĝas

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE} , {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE} , {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}, {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    Eligo → {FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))) iĝas

    SUM({FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE})

    Eligo → $13,806.00

➤ Premu ENTER .

Evente, vi ricevos la sumon de vendoj, $13,806.00 por nia difinita datintervalo kun aliaj kriterioj: Orienta Regiono .

Rilata Enhavo: Excel SUMIF kun Datintervalo en Monato &Jaro (4 Ekzemploj)

Metodo-6: Uzante funkciojn SUMPRODUCT, MONTH, kaj YEAR

Ĉi tie, ni uzos la SUMPRODUCT-funkcion , la MONATO-funkcio , kaj la JARO-funkcio por sumigi la vendajn valorojn por la datoj de la januaro monato kaj la Orienta Regiono.

Paŝoj :

➤ Tajpu la jenan formulon en ĉelo E14 .

=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)

Jen, E4:E11 estas la venda gamo, kiujn valorojn ni volas sumi, C4:C11 estas la datintervalo por la unua kaj dua kriterioj, kaj la lasta kriteriointervalo estas D4:D11 enhavanta la regionojn.

  • MONTH(C4:C11) → MONATO redonas la monatan nombron de la datoj

    Eligo → {1;1;1;2;2;3;3;3}

  • MONTH(C4:C11)=1 iĝas

    {1;1;1;2;2;3;3;3}=1

    Eligo → {TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}

  • YEAR(C4:C11) → resendas la jarvalorojn de la datoj

    Eligo → {2022;2022;2022;2022;2022;2022;2022;2022}

  • YEAR(C4:C11)=2022 iĝas

    {2022;2022;2022;2022;2022;2022;2022;2022}=2022

    Eligo → {TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11) iĝas

    → SUMPRODUCT({TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}*{TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;1;0;0;0;0;0}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;0;0;0;0;0;0}*E4:E11)  SUMPRODUCT({1402;5935;0;0;0;0;0;0})

    Eligo → $7,337.00

➤ Premu ENTER .

Poste, vi ricevos la sumon de vendoj, $7,337.00 por januaro monato kun alia kriterio: Orienta Regiono .

Legu Pli: Excel SUMIF kun Datintervalo en Monato & Jaro (4 Ekzemploj)

Metodo-7: VBA-Kodo al SUMIF inter Du Datoj kun Malsamaj Kriterioj

Ni uzos VBA kodon ĉi tie por plenumi la kalkulo de la sumo de la vendaj valoroj inter la du datoj 1/10/2022 kaj 3/20/2022 kun kriterio. Orienta Regiono .

Paŝoj :

➤ Iru al la >Programisto Tab >> Visual Basic Opcio.

Tiam, la Visual Basic Redaktoro malfermiĝos .

➤ Iru al la Enmeti Lageto >> Modulo Opcio.

Post tio, Modulo estos kreita.

➤ Skribu la jenan kodon

9194

Ni ricevos nian valoron en ĉelo E14 kaj DATVALO konvertos la datĉenon en datvaloron kaj tiam post plenumi la kriteriojn SUMIFS redonos la aldonitan vendan valoron en ĉelo E14 .

➤ Premu F5 .

Fine, vi ricevos la sumon de vendoj de $13,806.00 por nia difinita datintervalo kun alia kriterio: Orienta Regiono .

Legu pli: Kiel uzi SUMIFS kun Datintervalo kaj Multoblaj Kriterioj (7 Rapidaj Manieroj)

Praktika Sekcio

Por fari ekzercadon per vi mem ni disponigis Praktikan sekcion kiel sube en folio nomita Praktiku . Bonvolu fari ĝinper vi mem.

Konkludo

En ĉi tiu artikolo, ni provis facile kovri la manierojn SUMIF inter du datoj kaj aliaj kriterioj. . Espereble vi trovos ĝin utila. Se vi havas sugestojn aŭ demandojn, bonvolu dividi ilin en la komenta sekcio.

Antaŭa afiŝo Kiel Dividi Excel-Folion en Multoblaj Laborfolioj (3 Metodoj) -
Sekva afiŝo Kiel Kalkuli Pezitan Mezon kun Procentoj en Excel

Hugh West estas tre sperta Excel-trejnisto kaj analizisto kun pli ol 10 jaroj da sperto en la industrio. Li tenas bakalaŭron en Kontado kaj Financo kaj magistron en Komercadministracio. Hugh havas entuziasmon por instruado kaj evoluigis unikan instruan aliron kiu estas facile sekvi kaj kompreni. Lia sperta scio pri Excel helpis milojn da studentoj kaj profesiuloj tutmonde plibonigi siajn kapablojn kaj elstari en siaj karieroj. Per sia blogo, Hugh dividas sian scion kun la mondo, proponante senpagajn Excel-lernilojn kaj interretan trejnadon por helpi individuojn kaj entreprenojn atingi sian plenan potencialon.