Ako sčítať SUMIF medzi dvoma dátumami a s iným kritériom (7 spôsobov)

Hugh West

18-10-2023 Vzorce programu Excel
  • Zdieľajte To
Hugh West

Ak hľadáte najjednoduchšie spôsoby, ako SUMIF medzi dvoma dátumami a iným kritériom, potom vám bude tento článok užitočný. Sčítanie hodnôt v rámci časového limitu a na základe kritérií je niekedy potrebné vykonať a na rýchle vykonanie tejto úlohy môžete postupovať podľa tohto článku.

Stiahnite si pracovný zošit

SUMIF medzi dátumami.xlsm

7 spôsobov SUMIF medzi dvoma dátumami a s iným kritériom

Máme tu nasledujúci súbor údajov obsahujúci záznamy o predaji niektorých výrobkov s ich predpokladanými dátumami dodania a regiónmi predaja spoločnosti. Pomocou tohto súboru údajov si ukážeme spôsoby sčítania hodnôt predaja na základe zadaného regiónu a rozsahu dátumov.

Použili sme Microsoft Excel 365 verziu, môžete použiť aj iné verzie podľa vlastného uváženia.

Metóda 1: Použitie funkcie SUMIFS na SUMIF medzi dvoma dátumami s iným kritériom

Chceme zhrnúť hodnoty predaja pre Východ Región a pre dátumy medzi 1/10/2022 a 3/20/2022 (m-dd-rrrr) pomocou Funkcia SUMIFS tu.

Kroky :

➤ Do bunky zadajte nasledujúci vzorec E14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&C14,D4:D11,"East")

Tu, E4:E11 je rozsah predaja, ktorého hodnoty chceme sčítať, C4:C11 je rozsah dátumu pre prvé kritérium, ">="&B14 je prvým kritériom, čo znamená, že väčšia alebo rovná dátum začiatku 1/10/2022 Druhý rozsah kritérií je podobný prvému a kritériá pre tento rozsah sú "<="&C14 čo znamená. menšia alebo rovná dátum ukončenia 3/20/2022 a posledný rozsah kritérií je D4:D11 obsahujúce regióny, kritériá pre tento rozsah by boli Východ .

➤ Tlač VSTÚPIŤ .

Teraz získate súčet predajov $13,806.00 pre náš definovaný rozsah dátumov s iným kritériom: Východ Región .

Prečítajte si viac: Ako urobiť SUMIF Rozsah dátumu mesiac v programe Excel (9 spôsobov)

Metóda 2: Použitie SUMIFS a EOMONTH na SUMIF medzi dvoma dátumami s iným kritériom

V tejto časti sa pokúsime zistiť súčet hodnôt predaja pre dátumy Január mesiac a Južná Región . Takže použijeme Funkcia EOMONTH s Funkcia SUMIFS tu.

Kroky :

➤ Do bunky zadajte nasledujúci vzorec D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&EOMONTH(B14,0),D4:D11,C14)

Tu, E4:E11 je rozsah predaja, ktorého hodnoty chceme sčítať, C4:C11 je rozsah dátumu pre prvé kritérium, ">="&B14 je prvým kritériom, čo znamená, že väčšia alebo rovná dátum začiatku 1/1/2022 Druhý rozsah kritérií je podobný prvému a kritériá pre tento rozsah sú "<="&EOMONTH(B14,0) čo znamená. menšia alebo rovná dátum ukončenia Január mesiac, 1/31/2022 , a posledný rozsah kritérií je D4:D11 obsahujúce regióny, kritériá pre tento rozsah by boli Východ .

➤ Tlač VSTÚPIŤ .

Potom získate súčet predajov, $6,835.00 pre dátumy Január mesiac s iným kritériom: Južná Región .

Prečítajte si viac: Ako používať SUMIFS na sčítanie hodnôt v rozsahu dátumov v programe Excel

Metóda 3: Funkcie SUMIFS a DATE na SUMIF medzi dvoma dátumami

Tu budeme používať Funkcia SUMIFS a Funkcia DATE , keď to zhrnieme, hodnoty predaja pre Sever Región a pre dátumy v rámci 1/10/2022 a 3/20/2022 .

Kroky :

➤ Do bunky zadajte nasledujúci vzorec E14 .

=SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)

Tu, E4:E11 je rozsah predaja, ktorého hodnoty chceme sčítať, C4:C11 je rozsah dátumov pre prvé a druhé kritérium a rozsah posledného kritéria je D4:D11 obsahujúce regióny.

  • DATE(2022,1,10) → vráti číslo hodnoty dátumu

    Výstup → 44571

  • ">="&DATE(2022,1,10) sa stáva

    ">= 44571"

  • DATE(2022,3,20) → vráti číslo hodnoty dátumu

    Výstup → 44640

  • "<="&DATE(2022,3,20) sa stáva

    "<= 44640"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) sa stáva

    SUMIFS(E4:E11,C4:C11,">= 44571",C4:C11,"<= 44640",D4:D11, "Sever") → kontroluje, či hodnoty dátumu v rozsahu C4:C11 sú väčšie alebo rovné 44571 a menšia alebo rovná 44640 a región Sever v D4:D11 rozsah

    Výstup → $9,496.00

➤ Tlač VSTÚPIŤ .

Potom získate súčet predajov, $9,496.00 pre nami definovaný rozsah dátumov s ostatnými kritériami: Sever Región .

Súvisiaci obsah: Ako používať vzorec IF pre rozsah dátumov v programe Excel (6 metód)

Podobné čítanie:

  • Ako nastaviť pripomienku dátumu splatnosti v programe Excel (3 rýchle metódy)
  • Použitie otočnej tabuľky na filtrovanie rozsahu dátumov v programe Excel (5 spôsobov)
  • Rozsah dátumu a návratová hodnota VLOOKUP v programe Excel (4 vhodné metódy)
  • Ako vypočítať priemerné ak v rámci rozsahu dátumov v programe Excel (3 spôsoby)

Metóda 4: Použitie funkcie SUMIFS s TODAY

Predpokladajme, že chcete získať celkové hodnoty predaja za dátumy medzi 1/1/2022 a dnešný dátum ( 3/23/2022 ) a pre Východ Región . A na to môžete použiť Funkcia TODAY spolu s Funkcia SUMIFS .

Kroky :

➤ Do bunky zadajte nasledujúci vzorec D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY(),D4:D11,C14)

Tu, E4:E11 je rozsah predaja, ktorého hodnoty chceme sčítať, C4:C11 je rozsah dátumov pre prvé a druhé kritérium a rozsah posledného kritéria je D4:D11 obsahujúce regióny.

  • ">="&B14 sa stáva

    ">= 44562"

  • TODAY() → vráti dnešný dátum

    Výstup → 44643 (3/23/2022)

  • "<="&TODAY() sa stáva

    "<= 44643"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) sa stáva

    SUMIFS(E4:E11,C4:C11,">= 44562",C4:C11,"<= 44643",D4:D11, "East") → kontroluje, či hodnoty dátumu v rozsahu C4:C11 sú väčšie alebo rovné 44562 a menšia alebo rovná 44643 a región Východ v D4:D11 rozsah

    Výstup → $15,208.00

➤ Tlač VSTÚPIŤ .

Nakoniec získate súčet tržieb, ktorý je $15,208.00 pre dátumy medzi prvým dňom január 2022 a dnešný dátum s kritériami: Východ Región .

Ak chcete zmeniť posledný dátum rozsahu dátumov z dnešného dátumu na 10 dní pred dnešným dátumom, použite nasledujúci vzorec

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()-10,D4:D11,C14)

Pre posledný dátum ako dátum 10 dní po dnešnom dátume

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()+10,D4:D11,C14)

Prečítajte si viac: Excel VBA: Filtrovanie dátumu pred dnešným dňom (s rýchlymi krokmi)

Metóda 5: Kombinácia funkcií SUM a IF na SUMIF medzi dvoma dátumami a s iným kritériom

Môžete použiť kombináciu Funkcia SUM a Funkcia IF na výpočet celkového predaja za dátumy medzi 1/10/2022 na 3/20/2022 a pre Východ Región .

Kroky :

➤ Do bunky zadajte nasledujúci vzorec E14 .

=SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))

Tu, E4:E11 je rozsah predaja, ktorého hodnoty chceme sčítať, C4:C11 je rozsah dátumov pre prvé a druhé kritérium a rozsah posledného kritéria je D4:D11 obsahujúce regióny.

  • IF((C4:C11)>=B14 → kontroluje, či hodnoty dátumu v rozsahu C4:C11 sú väčšie alebo rovné hodnote B14 .

    Výstup → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • IF((C4:C11)<=C14 → kontroluje, či hodnoty dátumu v rozsahu C4:C11 sú menšie alebo rovné hodnote C14 .

    Výstup → {TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE}

  • IF(D4:D11=D14,E4:E11) → kontroluje, či sú oblasti rozsahu D4:D11 sa rovnajú oblasti Východ z C14 a vráti

    ({PRAVDA; PRAVDA; NEPRAVDA; PRAVDA; NEPRAVDA; NEPRAVDA; NEPRAVDA; NEPRAVDA; NEPRAVDA}, E4:E11)

    Výstup → {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE; FALSE}

  • IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))) sa stáva

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE} , {TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE} , {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE; FALSE}

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}, {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE}

    Výstup → {FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE; FALSE}

  • SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))) sa stáva

    SUM({FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE; FALSE})

    Výstup → $13,806.00

➤ Tlač VSTÚPIŤ .

Nakoniec získate súčet predajov, $13,806.00 pre nami definovaný rozsah dátumov s ďalšími kritériami: Východ Región .

Súvisiaci obsah: Excel SUMIF s rozsahom dátumu v mesiaci & rok (4 príklady)

Metóda 6: Použitie funkcií SUMPRODUCT, MONTH a YEAR

Tu budeme používať Funkcia SUMPRODUCT ,. Funkcia MESIAC a Funkcia ROK na sčítanie hodnôt predaja za dátumy Január mesiac a Východ Región.

Kroky :

➤ Do bunky zadajte nasledujúci vzorec E14 .

=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)

Tu, E4:E11 je rozsah predaja, ktorého hodnoty chceme sčítať, C4:C11 je rozsah dátumov pre prvé a druhé kritérium a rozsah posledného kritéria je D4:D11 obsahujúce regióny.

  • MONTH(C4:C11) → MESIAC vráti číslo mesiaca dátumu

    Výstup → {1;1;1;2;2;3;3;3}

  • MESIAC(C4:C11)=1 sa stáva

    {1;1;1;2;2;3;3;3}=1

    Výstup → {TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE}

  • ROK(C4:C11) → vráti hodnoty rokov dátumov

    Výstup → {2022;2022;2022;2022;2022;2022;2022;2022}

  • ROK(C4:C11)=2022 sa stáva

    {2022;2022;2022;2022;2022;2022;2022;2022}=2022

    Výstup → {TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • D4:D11=D14 → kontroluje, či sú oblasti rozsahu D4:D11 sa rovnajú oblasti Východ z C14

    Výstup → {TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE}
  • SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11) sa stáva

    → SUMPRODUCT({TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE}*{TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}*{TRUE; TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;1;0;0;0;0;0;0}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;0;0;0;0;0;0}*E4:E11)  SUMPRODUCT({1402;5935;0;0;0;0;0;0})

    Výstup → $7,337.00

➤ Tlač VSTÚPIŤ .

Potom získate súčet predajov, $7,337.00 pre Január mesiac s iným kritériom: Východ Región .

Čítajte viac: Excel SUMIF s rozsahom dátumu v mesiaci & rok (4 príklady)

Metóda 7: Kód VBA na SUMIF medzi dvoma dátumami s rôznymi kritériami

Budeme používať VBA kód na výpočet súčtu hodnôt predaja medzi dvoma dátumami 1/10/2022 a 3/20/2022 s kritériami Východ Región .

Kroky :

➤ Prejdite na Vývojár Karta>> Visual Basic Možnosť.

Potom sa Editor jazyka Visual Basic sa otvorí.

➤ Prejdite na Vložte Karta>> Modul Možnosť.

Potom sa Modul sa vytvorí.

➤ Napíšte nasledujúci kód 

 Sub sumdatewithcriteria() Cells(14, 5).Value = Application.WorksheetFunction.SumIfs(Range("E4:E11"), _ Range("C4:C11"), ">=" & DateValue("1/10/2022"), Range("C4:C11"), "<=" & _ DateValue("3/20/2022"), Range("D4:D11"), "East") End Sub

Hodnotu získame v bunke E14 a DATEVALUE prevedie reťazec dátumu na hodnotu dátumu a po splnení kritérií SUMIFS vráti pridanú hodnotu predaja v bunke E14 .

➤ Tlač F5 .

Nakoniec získate súčet predajov $13,806.00 pre náš definovaný rozsah dátumov s iným kritériom: Východ Región .

Prečítajte si viac: Ako používať SUMIFS s rozsahom dátumov a viacerými kritériami (7 rýchlych spôsobov)

Praktická časť

Na cvičenie podľa seba sme poskytli Cvičenie sekciu ako nižšie v hárku s názvom Prax . Prosím, urobte to sami.

Záver

V tomto článku sme sa pokúsili pokryť spôsoby, ako SUMIF medzi dvoma dátumami a iným kritériom ľahko. Dúfam, že vám to bude užitočné. Ak máte nejaké návrhy alebo otázky, neváhajte sa o ne podeliť v sekcii komentárov.

Predchádzajúci príspevok Ako rozdeliť hárok programu Excel na viac pracovných hárkov (3 metódy) -
Ďalší príspevok Ako vypočítať vážený priemer s percentami v programe Excel

Hugh West je veľmi skúsený tréner a analytik Excelu s viac ako 10-ročnými skúsenosťami v tomto odvetví. Má bakalársky titul v odbore účtovníctvo a financie a magisterský titul v odbore Business Administration. Hugh má vášeň pre vyučovanie a vyvinul jedinečný vyučovací prístup, ktorý sa dá ľahko sledovať a pochopiť. Jeho odborné znalosti Excelu pomohli tisíckam študentov a profesionálov na celom svete zlepšiť svoje zručnosti a vyniknúť vo svojej kariére. Hugh sa prostredníctvom svojho blogu delí o svoje znalosti so svetom a ponúka bezplatné výukové programy Excelu a online školenia, ktoré jednotlivcom a firmám pomôžu naplno využiť ich potenciál.