Comment faire un SUMIF entre deux dates et avec un autre critère (7 façons)

Hugh West

18-10-2023 Formules Excel
  • Partage Ça
Hugh West

Si vous cherchez les moyens les plus simples pour SUMIF Additionner des valeurs dans une limite de périodes de temps et sur la base de critères est parfois nécessaire et pour effectuer cette tâche rapidement, vous pouvez suivre cet article.

Télécharger le cahier d'exercices

SUMIF entre dates.xlsm

7 façons de faire un SUMIF entre deux dates et avec un autre critère

Nous disposons du jeu de données suivant, qui contient les enregistrements des ventes de certains produits avec leurs dates de livraison estimées et les régions de vente d'une entreprise. À l'aide de ce jeu de données, nous allons démontrer comment additionner les valeurs des ventes en fonction d'une région et d'une plage de dates spécifiées.

Nous avons utilisé Microsoft Excel 365 ici, vous pouvez utiliser toute autre version selon votre convenance.

Méthode-1 : Utiliser la fonction SUMIFS pour faire la somme de deux dates avec un autre critère.

Nous voulons faire la somme des valeurs de vente pour les produits suivants Est Région et pour les dates comprises entre 1/10/2022 et 3/20/2022 (m-jj-aaaa) en utilisant le bouton Fonction SUMIFS ici.

Étapes :

➤ Tapez la formule suivante dans la cellule E14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&C14,D4:D11,"East")

Ici, E4:E11 est l'intervalle de vente dont on veut additionner les valeurs, C4:C11 est la plage de dates pour le premier critère, ">="&B14 est le premier critère, ce qui signifie supérieur ou égal à la date de début 1/10/2022 La deuxième plage de critères est similaire à la première et les critères de cette plage sont les suivants "<="&C14 ce qui signifie inférieur ou égal à la date de fin 3/20/2022 et la dernière plage de critères est D4:D11 contenant les régions, les critères pour cette gamme seraient les suivants Est .

➤ Press ENTER .

Maintenant, vous obtiendrez la somme des ventes de $13,806.00 pour notre plage de dates définie avec un autre critère : Est Région .

Lire la suite : Comment faire la SOMME d'une plage de dates en mois dans Excel (9 façons)

Méthode-2 : Utilisation de SUMIFS et EOMONTH pour faire la somme de deux dates avec un autre critère.

Dans cette section, nous allons essayer de trouver la somme des valeurs des ventes pour les dates de Janvier mois et le Sud Région Nous allons donc utiliser le Fonction EOMONTH avec le Fonction SUMIFS ici.

Étapes :

➤ Tapez la formule suivante dans la cellule D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&EOMONTH(B14,0),D4:D11,C14)

Ici, E4:E11 est l'intervalle de vente dont on veut additionner les valeurs, C4:C11 est la plage de dates pour le premier critère, ">="&B14 est le premier critère, ce qui signifie supérieur ou égal à la date de début 1/1/2022 La deuxième plage de critères est similaire à la première et les critères de cette plage sont les suivants "<="&EOMONTH(B14,0) ce qui signifie inférieur ou égal à la date de fin de Janvier mois, 1/31/2022 , et la dernière plage de critères est D4:D11 contenant les régions, les critères pour cette gamme seraient les suivants Est .

➤ Press ENTER .

Après cela, vous obtiendrez la somme des ventes, $6,835.00 pour les dates de Janvier mois avec un autre critère : Sud Région .

Lire la suite : Comment utiliser SUMIFS pour additionner les valeurs d'une plage de dates dans Excel ?

Méthode-3 : Fonctions SUMIFS et DATE pour faire la somme entre deux dates

Ici, nous allons utiliser le Fonction SUMIFS et le Fonction DATE Pour résumer, les valeurs de vente de l'entreprise sont les suivantes Nord Région et pour les dates comprises dans 1/10/2022 et 3/20/2022 .

Étapes :

➤ Tapez la formule suivante dans la cellule E14 .

=SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)

Ici, E4:E11 est l'intervalle de vente dont on veut additionner les valeurs, C4:C11 est la plage de dates pour les premier et deuxième critères, et la plage du dernier critère est la suivante D4:D11 contenant les régions.

  • DATE(2022,1,10) → renvoie le numéro d'une valeur de date

    Sortie → 44571

  • ">="&DATE(2022,1,10) devient

    ">= 44571"

  • DATE(2022,3,20) → renvoie le numéro d'une valeur de date

    Sortie → 44640

  • "<="&DATE(2022,3,20) devient

    "<= 44640"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) devient

    SUMIFS(E4:E11,C4:C11,">= 44571",C4:C11,"<= 44640",D4:D11, "North") → vérifie si les valeurs de date de la plage C4:C11 sont supérieurs ou égaux à 44571 et inférieur ou égal à 44640 et la région Nord dans le D4:D11 gamme

    Sortie → $9,496.00

➤ Press ENTER .

Ensuite, vous obtiendrez la somme des ventes, $9,496.00 pour notre plage de dates définie avec les autres critères : Nord Région .

Contenu connexe : Comment utiliser la formule IF pour une plage de dates dans Excel (6 méthodes)

Lectures similaires :

  • Comment définir un rappel de date d'échéance dans Excel (3 méthodes rapides)
  • Utiliser le tableau croisé dynamique pour filtrer une plage de dates dans Excel (5 façons)
  • VLOOKUP Plage de dates et valeur de retour dans Excel (4 méthodes adaptées)
  • Comment calculer la moyenne si dans une plage de dates dans Excel (3 façons)

Méthode-4 : Utilisation de la fonction SUMIFS avec TODAY

Supposons que vous vouliez obtenir les valeurs totales des ventes pour les dates entre 1/1/2022 et la date du jour ( 3/23/2022 ) et pour le Est Région Et, pour ce faire, vous pouvez utiliser la fonction Fonction TODAY ainsi que le Fonction SUMIFS .

Étapes :

➤ Tapez la formule suivante dans la cellule D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY(),D4:D11,C14)

Ici, E4:E11 est l'intervalle de vente dont on veut additionner les valeurs, C4:C11 est la plage de dates pour les premier et deuxième critères, et la plage du dernier critère est la suivante D4:D11 contenant les régions.

  • ">="&B14 devient

    ">= 44562"

  • AUJOURD'HUI() → renvoie la date du jour

    Sortie → 44643 (3/23/2022)

  • "<="&AUJOURD'HUI() devient

    "<= 44643"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) devient

    SUMIFS(E4:E11,C4:C11,">= 44562",C4:C11,"<= 44643",D4:D11, "East") → vérifie si les valeurs de date de la plage C4:C11 sont supérieurs ou égaux à 44562 et inférieur ou égal à 44643 et la région Est dans le D4:D11 gamme

    Sortie → $15,208.00

➤ Press ENTER .

Enfin, vous obtiendrez la somme des ventes, soit $15,208.00 pour les dates comprises entre le premier jour de Janvier 2022 et la date d'aujourd'hui avec des critères : Est Région .

Si vous voulez changer la dernière date de la plage de dates de la date du jour à 10 jours avant la date du jour, utilisez la formule suivante

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()-10,D4:D11,C14)

Pour la dernière date comme une date 10 jours après la date d'aujourd'hui

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()+10,D4:D11,C14)

Lire la suite : Excel VBA : filtrez les dates antérieures à aujourd'hui (avec des étapes rapides)

Méthode-5 : Combinaison des fonctions SUM et IF pour effectuer un SUMIF entre deux dates et avec un autre critère

Vous pouvez utiliser la combinaison de la Fonction SUM et le Fonction IF pour calculer le total des ventes pour les dates comprises entre 1/10/2022 à 3/20/2022 et pour le Est Région .

Étapes :

➤ Tapez la formule suivante dans la cellule E14 .

=SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))

Ici, E4:E11 est l'intervalle de vente dont on veut additionner les valeurs, C4:C11 est la plage de dates pour le premier et le deuxième critère, et la dernière plage de critères est D4:D11 contenant les régions.

  • IF((C4:C11)>=B14 → vérifie si les valeurs de date de la plage C4:C11 sont supérieures ou égales à la valeur de B14 .

    Sortie → {FALSE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE}

  • IF((C4:C11)<=C14 → vérifie si les valeurs de date de la plage C4:C11 sont inférieures ou égales à la valeur de C14 .

    Sortie → {VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; FAUX ; VRAI ; FAUX}

  • IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))) devient

    → {FALSE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE} , {VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; FAUX ; VRAI ; FAUX} , {1402 ; 5935 ; FAUX ; 7871 ; FAUX ; FAUX ; FAUX ; FAUX}

    → {FALSE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE ; TRUE}, {1402 ; 5935 ; FALSE ; 7871 ; FALSE ; FALSE ; FALSE ; FALSE ; FALSE ; FALSE}.

    Sortie → {FALSE ; 5935 ; FALSE ; 7871 ; FALSE ; FALSE ; FALSE ; FALSE ; FALSE}

  • SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))) devient

    SUM({FALSE ; 5935 ; FALSE ; 7871 ; FALSE ; FALSE ; FALSE ; FALSE ; FALSE})

    Sortie → $13,806.00

➤ Press ENTER .

Au final, vous obtiendrez la somme des ventes, $13,806.00 pour notre plage de dates définie avec d'autres critères : Est Région .

Contenu connexe : Excel SUMIF avec une plage de dates en mois et année (4 exemples)

Méthode 6 : Utilisation des fonctions SUMPRODUCT, MONTH et YEAR

Ici, nous allons utiliser le Fonction SUMPRODUCT le Fonction MOIS et le Fonction ANNÉE de faire la somme des valeurs de vente pour les dates de la Janvier mois et le Est Région.

Étapes :

➤ Tapez la formule suivante dans la cellule E14 .

=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)

Ici, E4:E11 est l'intervalle de vente dont on veut additionner les valeurs, C4:C11 est la plage de dates pour le premier et le deuxième critère, et la dernière plage de critères est D4:D11 contenant les régions.

  • MOIS(C4:C11) → MOIS renvoie le numéro du mois des dates

    Sortie → {1;1;1;2;2;3;3;3}

  • MOIS(C4:C11)=1 devient

    {1;1;1;2;2;3;3;3}=1

    Sortie → {VRAI ; VRAI ; VRAI ; FAUX ; FAUX ; FAUX ; FAUX ; FAUX ; FAUX}

  • ANNÉE(C4:C11) → renvoie les valeurs de l'année des dates

    Sortie → {2022;2022;2022;2022;2022;2022;2022;2022}

  • ANNÉE(C4:C11)=2022 devient

    {2022;2022;2022;2022;2022;2022;2022;2022}=2022

    Sortie → {VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI}

  • D4:D11=D14 → vérifie si les régions de l'intervalle D4:D11 sont égales à la région Est de C14

    Sortie → {VRAI ; VRAI ; FAUX ; VRAI ; FAUX ; FAUX ; FAUX ; FAUX ; FAUX}
  • SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11) devient

    → SUMPRODUCT({VRAI ; VRAI ; VRAI ; VRAI ; FAUX ; FAUX ; FAUX ; FAUX ; FAUX}*{VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI ; VRAI}*{VRAI ; VRAI ; FAUX ; VRAI ; FAUX ; FAUX ; FAUX ; FAUX}*E4:E11)

    → SUMPRODUCT({1;1;1;0;0;0;0;0}*{VRAI ; VRAI ; FAUX ; VRAI ; FAUX ; FAUX ; FAUX ; FAUX ; FAUX}*E4:E11)

    → SUMPRODUCT({1;1;0;0;0;0;0;0}*E4:E11)  SUMPRODUCT({1402;5935;0;0;0;0;0;0})

    Sortie → $7,337.00

➤ Press ENTER .

Ensuite, vous obtiendrez la somme des ventes, $7,337.00 pour Janvier mois avec un autre critère : Est Région .

Lire la suite : Excel SUMIF avec une plage de dates en mois et année (4 exemples)

Méthode 7 : Code VBA pour faire la somme de deux dates avec des critères différents.

Nous utiliserons un VBA code ici pour effectuer le calcul du total des valeurs des ventes entre les deux dates 1/10/2022 et 3/20/2022 avec un critère Est Région .

Étapes :

➤ Allez à la Développeur Tab>> ; Visual Basic Option.

Ensuite, le Éditeur Visual Basic s'ouvrira.

➤ Allez à la Insérer Tab>> ; Module Option.

Après cela, un Module sera créé.

➤ Écrivez le code suivant 

 Sub sumdatewithcriteria() Cells(14, 5).Value = Application.WorksheetFunction.SumIfs(Range("E4:E11"), _ Range("C4:C11"), ">=" & ; DateValue("1/10/2022"), Range("C4:C11"), "<=" & ; _ DateValue("3/20/2022"), Range("D4:D11"), "East") End Sub

Nous allons obtenir notre valeur dans la cellule E14 et DATEVALUE convertira la chaîne de date en une valeur de date et ensuite, après avoir rempli les critères. SUMIFS retournera la valeur ajoutée des ventes dans la cellule E14 .

➤ Press F5 .

Enfin, vous obtiendrez la somme des ventes de $13,806.00 pour notre plage de dates définie avec un autre critère : Est Région .

Lire la suite : Comment utiliser SUMIFS avec une plage de dates et des critères multiples (7 façons rapides)

Section pratique

Pour vous entraîner vous-même, nous avons fourni un Pratique comme ci-dessous dans une feuille nommée Pratique S'il vous plaît, faites-le vous-même.

Conclusion

Dans cet article, nous avons essayé de couvrir les moyens de SUMIF entre deux dates et un autre critère facilement. J'espère que vous trouverez cet article utile. Si vous avez des suggestions ou des questions, n'hésitez pas à les partager dans la section des commentaires.

Post précédent Comment diviser une feuille de calcul Excel en plusieurs feuilles de calcul (3 méthodes) -
Prochain article Comment calculer la moyenne pondérée avec des pourcentages dans Excel ?

Hugh West est un formateur et analyste Excel très expérimenté avec plus de 10 ans d'expérience dans l'industrie. Il est titulaire d'un baccalauréat en comptabilité et finance et d'une maîtrise en administration des affaires. Hugh a une passion pour l'enseignement et a développé une approche pédagogique unique qui est facile à suivre et à comprendre. Sa connaissance approfondie d'Excel a aidé des milliers d'étudiants et de professionnels du monde entier à améliorer leurs compétences et à exceller dans leur carrière. Grâce à son blog, Hugh partage ses connaissances avec le monde, offrant des tutoriels Excel gratuits et une formation en ligne pour aider les particuliers et les entreprises à atteindre leur plein potentiel.