Kako izračunati SUMIF između dva datuma i s drugim kriterijima (7 načina)

Hugh West

18-10-2023 Excel formule
  • Podijeli Ovo
Hugh West

Ako tražite neke od najlakših načina za SUMIF između dva datuma i drugog kriterija, ovaj će vam članak biti koristan. Ponekad je potrebno zbrajanje vrijednosti u određenim vremenskim razdobljima i na temelju kriterija, a kako biste brzo obavili ovaj zadatak, slijedite ovaj članak.

Preuzmi radnu bilježnicu

SUMIF između Dates.xlsm

7 načina za SUMIF između dva datuma i s drugim kriterijima

Ovdje imamo sljedeći skup podataka koji sadrži evidenciju prodaje nekih proizvoda s njihovim procijenjenim datumima isporuke i prodajne regije tvrtke. Pomoću ovog skupa podataka demonstrirat ćemo načine zbrajanja prodajnih vrijednosti na temelju određene regije i datumskog raspona.

Koristili smo verziju Microsoft Excel 365 ovdje, možete koristiti bilo koje druge verzije prema vašoj želji.

Metoda-1: Korištenje funkcije SUMIFS za SUMIF između dva datuma s drugim kriterijima

Želimo sumirati prodajne vrijednosti za Istočna regija i za datume između 1/10/2022 i 3/20/2022 (m-dd-gggg) pomoću funkcije SUMIFS ovdje.

Koraci :

➤ Upišite sljedeću formulu u ćeliju E14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&C14,D4:D11,"East")

Ovdje, E4:E11 je raspon prodaje čije vrijednosti želimo zbrojiti, C4:C11 je raspon datuma za prvi kriterij, “>=”&B14 je prvi kriterijšto znači više ili jednako datumu početka 1/10/2022 . Drugi raspon kriterija sličan je prvom, a kriterij za ovaj raspon je “<=”&C14 što znači manje ili jednako datumu završetka 3/20/2022 i posljednji raspon kriterija je D4:D11 koji sadrži regije, kriteriji za ovaj raspon bi bili Istok .

➤ Pritisnite ENTER .

Sada ćete dobiti zbroj prodaje od 13.806,00$ za naš definirani datumski raspon s drugim kriterijem: Istok Regija .

Pročitajte više: Kako napraviti SUMIF datumski raspon mjesec u Excelu (9 načina)

Metoda-2: Korištenje SUMIFS i EOMONTH za SUMIF između dva datuma s drugim kriterijem

U ovom odjeljku pokušat ćemo pronaći zbroj prodajnih vrijednosti za datume siječanj mjesec i južnu regiju . Dakle, ovdje ćemo koristiti EOMONTH funkciju s SUMIFS funkcijom .

Koraci :

➤ Upišite sljedeću formulu u ćeliju D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&EOMONTH(B14,0),D4:D11,C14)

Ovdje, E4:E11 je raspon prodaje čije vrijednosti želimo zbrojiti, C4:C11 je raspon datuma za prvi kriterij, “>=”&B14 je prvi kriterij koji znači veći ili jednak datumu početka 1/1/2022 . Drugi raspon kriterija sličan je prvom ikriterij za ovaj raspon je “<=”&EOMONTH(B14,0) što znači manje ili jednako krajnjem datumu siječnja mjesec, 31.1.2022. , i posljednji raspon kriterija je D4:D11 koji sadrži regije, kriteriji za ovaj raspon bili bi Istok .

➤ Pritisnite ENTER .

Nakon toga, dobit ćete zbroj prodaje, $6,835.00 za datume siječanj mjesec s drugim kriterijem: Južna Regija .

Pročitajte više: Kako koristiti SUMIFS za SUM vrijednosti u datumskom rasponu u Excel

Metoda-3: Funkcije SUMIFS i DATE za SUMIF između dva datuma

Ovdje ćemo koristiti funkciju SUMIFS i DATE funkcija , da sažmemo, prodajne vrijednosti za sjevernu regiju i za datume unutar 1/10/2022 i 20.3.2022 .

Koraci :

➤ Upišite sljedeća formula u ćeliji E14 .

=SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)

Ovdje, E4: E11 je raspon prodaje čije vrijednosti želimo zbrojiti, C4:C11 je raspon datuma za prvi i drugi kriterij, a zadnji raspon kriterija je D4:D11 koji sadrži regije.

  • DATE(2022,1,10) → vraća broj datumske vrijednosti

    Izlaz → 44571

  • ">="&DATE(2022,1,10) postaje

    ">= 44571"

  • DATE(2022,3,20) → vraća broj datumske vrijednosti

    Izlaz → 44640

  • "<="&DATE(2022,3,20) postaje

    "<= 44640"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) postaje

    SUMIFS(E4:E11,C4:C11,">= 44571",C4:C11,"<= 44640",D4:D11, “North”) → provjerava jesu li vrijednosti datuma u rasponu C4:C11 veće ili jednake 44571 i manje od ili jednako 44640 i regija Sjever u D4:D11 rasponu

    Izlaz → 9496,00 $

➤ Pritisnite ENTER .

Tada ćete dobiti zbroj prodaje, 9.496,00$ za naš definirani datumski raspon s ostalim kriterijima: Sjever Regija .

Povezani sadržaj: Kako koristiti IF formulu za datumski raspon u Excelu (6 metoda)

Slična čitanja:

  • Kako postaviti podsjetnik za krajnji rok u Excelu (3 brze metode)
  • Upotrijebite zaokretnu tablicu za filtriranje datumskog raspona u Excelu (5 načina)
  • VLOOKUP Datumski raspon i povratna vrijednost u Excelu (4 prikladne metode)
  • Kako izračunati prosjek ako unutar datumskog raspona u Excelu (3 načina)

Metoda-4: Korištenje funkcije SUMIFS s TODAY

S recimo, želite dobiti ukupne prodajne vrijednosti za datume između 1/1/2022 i današnjeg datuma ( 3/23/2022 ) i za Istočna Regija . Da biste to učinili, možete koristiti funkciju TODAY zajedno s funkcijom SUMIFS .

Koraci :

➤ Upišite sljedeću formulu u ćeliju D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY(),D4:D11,C14)

Ovdje, E4:E11 je prodajni raspon kojivrijednosti koje želimo zbrojiti, C4:C11 je raspon datuma za prvi i drugi kriterij, a posljednji raspon kriterija je D4:D11 koji sadrži regije.

  • ">="&B14 postaje

    ">= 44562"

  • TODAY() → vraća današnji datum

    Izlaz → 44643 (3/23/2022)

  • "<="&TODAY() postaje

    "<= 44643"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) postaje

    SUMIFS(E4:E11,C4:C11,">= 44562",C4:C11,"<= 44643",D4:D11, “East”) → provjerava jesu li datumske vrijednosti raspona C4:C11 su veći ili jednaki 44562 i manji ili jednaki 44643 i regija Istok u D4: D11 raspon

    Izlaz → 15.208,00 $

➤ Pritisnite ENTER .

Konačno, dobit ćete zbroj prodaje koji iznosi 15.208,00 $ za datume između prvog dana siječnja 2022 i današnji datum s kriterijima: Istok Regija .

Ako želite promijeniti zadnji datum datuma u rasponu od današnjeg datuma do 10 dana prije današnjeg datuma, tada koristite sljedeću formulu

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()-10,D4:D11,C14)

Za zadnji datum kao datum 10 dana nakon današnjeg datuma

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()+10,D4:D11,C14)

Pročitajte više: Excel VBA: Filtrirajte datum prije današnjeg (s brzim koracima)

Metoda-5: Kombinacija funkcija SUM i IF u SUMIF između dva datuma i s drugim kriterijem

Možete koristiti kombinaciju funkcije SUM i funkcije IF doizračunajte ukupnu prodaju za datume između 1/10/2022 do 3/20/2022 i za Istočna Regija .

Koraci :

➤ Upišite sljedeću formulu u ćeliju E14 .

=SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))

Ovdje, E4:E11 je raspon prodaje čije vrijednosti želimo zbrojiti, C4 :C11 je raspon datuma za prvi i drugi kriterij, a posljednji raspon kriterija je D4:D11 koji sadrži regije.

  • IF((C4:C11)>=B14 → provjerava jesu li vrijednosti datuma raspona C4:C11 veće ili jednake vrijednosti B14 .

    Izlaz → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • IF((C4:C11)<=C14 → provjerava jesu li vrijednosti datuma u rasponu C4:C11 manje ili jednake vrijednost C14 .

    Izlaz → {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE}

  • IF(D4:D11=D14,E4:E11) → provjerava jesu li regije raspona D4:D11 jednake su regiji East od C14 i vraća

    ({TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}, E4:E11)

    Izlaz → {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))) postaje

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE} , {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE} , {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}, {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    Izlaz → {FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))) postaje

    SUM({FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE})

    Izlaz → 13.806,00$

➤ Pritisnite ENTER .

Na kraju ćete dobiti zbroj prodaje, 13.806,00$ za naš definirani datumski raspon s drugim kriterijima: Istok Regija .

Povezani sadržaj: Excel SUMIF s datumskim rasponom u mjesecu &Godina (4 primjera)

Metoda-6: Upotreba funkcija SUMPRODUCT, MONTH i YEAR

Ovdje ćemo koristiti funkciju SUMPRODUCT , funkcija MONTH i funkcija YEAR za zbrajanje prodajnih vrijednosti za datume siječanj mjesec i istok Regija.

Koraci :

➤ Upišite sljedeću formulu u ćeliju E14 .

=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)

Ovdje, E4:E11 je raspon prodaje čije vrijednosti želimo zbrojiti, C4:C11 je raspon datuma za prvi i drugi kriterij, a zadnji raspon kriterija je D4:D11 koji sadrži regije.

  • MONTH(C4:C11) → MJESEC vraća broj mjeseca za datume

    Izlaz → {1;1;1;2;2;3;3;3}

  • MONTH(C4:C11)=1 postaje

    {1;1;1;2;2;3;3;3}=1

    Izlaz → {TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}

  • YEAR(C4:C11) → vraća vrijednosti godine za datume

    Izlaz → {2022;2022;2022;2022;2022;2022;2022;2022}

  • YEAR(C4:C11)=2022 postaje

    {2022;2022;2022;2022;2022;2022;2022;2022}=2022

    Izlaz → {TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • D4:D11=D14 → provjerava jesu li regije raspona D4:D11 jednaki su regiji Istok C14

    Izlaz → {TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}
  • SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11) postaje

    → SUMPRODUCT({TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}*{TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;1;0;0;0;0;0}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;0;0;0;0;0;0}*E4:E11)  SUMPRODUCT({1402;5935;0;0;0;0;0;0})

    Izlaz → $7,337.00

➤ Pritisnite ENTER .

Nakon toga ćete dobiti zbroj prodaje, 7,337.00$ za siječanj mjesec s drugim kriterijem: Istok Regija .

Pročitajte više: Excel SUMIF s datumskim rasponom u mjesecu & Godina (4 primjera)

Metoda-7: VBA kod u SUMIF između dva datuma s različitim kriterijima

Ovdje ćemo koristiti VBA kod za izvođenje izračun ukupne vrijednosti prodaje između dva datuma 1/10/2022 i 3/20/2022 s kriterijem Istočna regija .

Koraci :

➤ Idite na Razvojna Kartica >> Visual Basic Opcija.

Tada će se otvoriti Visual Basic Editor .

➤ Idite na opciju Umetni Kartica >> Modul .

Nakon toga, kreirat će se Modul .

➤ Napišite sljedeći kod

3928

Dobit ćemo našu vrijednost u ćeliji E14 i DATEVALUE pretvorit će niz datuma u vrijednost datuma, a zatim će nakon ispunjavanja kriterija SUMIFS vratiti dodanu prodajnu vrijednost u ćeliju E14 .

➤ Pritisnite F5 .

Konačno ćete dobiti zbroj prodaje od 13.806,00$ za naš definirani datumski raspon s drugi kriterij: Istok Regija .

Pročitajte više: Kako koristiti SUMIFS s Datumski raspon i više kriterija (7 brzih načina)

Odjeljak za vježbu

Za samostalno vježbanje osigurali smo odjeljak Vježbanje kao ispod na listu pod nazivom Vježbajte . Molim te učini tosami.

Zaključak

U ovom smo članku pokušali lako pokriti načine SUMIF između dva datuma i drugog kriterija . Nadam se da će vam biti od koristi. Ako imate prijedloge ili pitanja, slobodno ih podijelite u odjeljku za komentare.

Prethodni post Kako podijeliti Excel list na više radnih listova (3 metode) -
Sljedeći post Kako izračunati ponderirani prosjek s postocima u Excelu

Hugh West vrlo je iskusan Excel trener i analitičar s više od 10 godina iskustva u industriji. Diplomirao je računovodstvo i financije te magistrirao poslovno upravljanje. Hugh ima strast za podučavanjem i razvio je jedinstveni pristup podučavanju koji je lako pratiti i razumjeti. Njegovo stručno poznavanje programa Excel pomoglo je tisućama studenata i profesionalaca diljem svijeta da poboljšaju svoje vještine i postignu uspjeh u karijeri. Putem svog bloga, Hugh dijeli svoje znanje sa svijetom, nudeći besplatne vodiče za Excel i online obuku kako bi pomogao pojedincima i tvrtkama da dostignu svoj puni potencijal.