Kumaha SUMIF antara Dua Tanggal sareng Kriteria Lain (7 Cara)

Hugh West

18-10-2023 Rumus Excel
  • Bagikeun Ieu
Hugh West

Upami anjeun milarian sababaraha cara anu paling gampang pikeun SUMIF antara dua tanggal sareng kriteria anu sanés, maka anjeun bakal mendakan tulisan ieu mangpaat. Nambahkeun niléy dina wates waktu sareng dumasar kana kritéria anu kedah dilakukeun sakapeung sareng pikeun ngalaksanakeun tugas ieu gancang anjeun tiasa nuturkeun tulisan ieu.

Unduh Buku Tugas

SUMIF antara Tanggal.xlsm

7 Cara pikeun SUMIF antara Dua Tanggal sareng Kriteria Lain

Di dieu, kami gaduh set data di handap ieu anu ngandung catetan penjualan sababaraha produk sareng perkiraan tanggal pangirimanna jeung ngajual wewengkon hiji pausahaan. Nganggo set data ieu kami bakal nunjukkeun cara nyimpulkeun nilai penjualan dumasar kana daérah sareng rentang tanggal anu ditangtukeun.

Kami parantos nganggo versi Microsoft Excel 365 Ieuh, anjeun tiasa nganggo vérsi anu sanés numutkeun karesep anjeun.

Métode-1: Ngagunakeun Fungsi SUMIFS pikeun SUMIF antara Dua Tanggal sareng Kriteria Lain

Kami hoyong nyimpulkeun nilai penjualan pikeun Wétan Wilayah jeung pikeun kaping antara 1/10/2022 jeung 3/20/2022 (m-dd-yyyy) ku ngagunakeun fungsi SUMIFS di dieu.

Lengkah :

➤ Ketik rumus ieu dina sél E14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&C14,D4:D11,"East")

Di dieu, E4:E11 nyaeta rentang jualan nu nilai nu urang hoyong jumlah, C4:C11 mangrupa rentang tanggal pikeun kriteria kahiji, “>=”&B14 mangrupakeun kriteria kahiji.nu hartina leuwih gede atawa sarua jeung tanggal mimiti 1/10/2022 . Rentang kritéria kadua sarua jeung nu kahiji jeung kritéria pikeun rentang ieu “<=”&C14 nu hartina kurang atawa sarua jeung tanggal ahir 3/20/2022 sarta rentang kriteria panungtungan nyaéta D4:D11 ngandung wewengkon, kriteria keur rentang ieu bakal Wétan .

➤ Pencét ENTER .

Ayeuna, anjeun bakal meunang jumlah penjualan $13,806.00 pikeun rentang tanggal anu didefinisikeun ku kriteria sejen: Wetan Wilayah .

Maca deui: Kumaha Ngalakukeun SUMIF Tanggal Rentang Bulan dina Excel (9 Cara)

Métode-2: Ngagunakeun SUMIFS sareng EOMONTH pikeun SUMIF antara Dua Tanggal sareng Kriteria Lain

Dina bagian ieu, urang bakal nyobaan pikeun manggihan jumlah nilai jualan keur tanggal Januari bulan jeung Kidul Wilayah . Janten, urang bakal nganggo fungsi EOMONTH sareng fungsi SUMIFS di dieu.

Lengkah :

➤ Ketik rumus ieu dina sél D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&EOMONTH(B14,0),D4:D11,C14)

Di dieu, E4:E11 nyaeta rentang jualan nu nilai urang hayang jumlah, C4:C11 mangrupa rentang tanggal pikeun kriteria kahiji, “>=”&B14 mangrupakeun kriteria kahiji nu hartina leuwih gede atawa sarua jeung tanggal mimiti 1/1/2022 . Rentang kriteria kadua sami sareng anu kahiji sareng anukriteria keur rentang ieu “<=”&EOMONTH(B14,0) nu hartina kurang atawa sarua jeung tanggal ahir Januari bulan, 1/31/2022 , jeung rentang kriteria panungtungan nyaéta D4:D11 ngandung wewengkon, nu kriteria pikeun rentang ieu bakal jadi Wétan .

➤ Pencét ENTER .

Sanggeus éta, anjeun bakal meunang jumlah jualan, $6,835.00 pikeun tanggal Januari bulan jeung kriteria séjén: Kidul Wewengkon .

Baca Selengkapnya: Kumaha Ngagunakeun SUMIFS kana Nilai SUM dina Rentang Tanggal dina Excel

Métode-3: Fungsi SUMIFS sareng DATE pikeun SUMIF antara Dua Tanggal

Di dieu, urang bakal nganggo fungsi SUMIFS sareng DATE fungsi , mun nyimpulkeun, nilai jualan keur Kaler Wilayah jeung pikeun kaping dina 1/10/2022 jeung 3/20/2022 .

Lengkah :

➤ Jenis rumus ieu dina sél E14 .

=SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)

Di dieu, E4: E11 nyaéta rentang penjualan anu nilai anu urang hoyong jumlah, C4:C11 nyaéta rentang tanggal pikeun kriteria kahiji jeung kadua, sarta rentang kriteria panungtungan nyaéta D4:D11 ngandung wewengkon.

  • DATE(2022,1,10) → ngabalikeun sajumlah nilai tanggal

    Kaluaran → 44571

  • ">="&DATE(2022,1,10) janten

    ">= 44571"

  • DATE(2022,3,20) → ngabalikeun sajumlah nilai tanggal

    Kaluaran → 44640

  • "<="&DATE(2022,3,20) janten

    "<= 44640"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) janten

    SUMIFS(E4:E11,C4:C11,">= 44571",C4:C11,"<= 44640",D4:D11, “North”) → mariksa upami nilai tanggal rentang C4:C11 leuwih gede atawa sarua jeung 44571 jeung kurang atawa sarua jeung 44640 jeung wewengkon Kaler dina D4:D11 rentang

    Kaluaran → $9,496.00

➤ Pencét ENTER .

Teras, anjeun bakal meunang jumlah jualan, $9,496.00 pikeun rentang tanggal anu ditetepkeun ku kriteria séjén: Kalér Wilayah .

Eusi Patali: Kumaha Ngagunakeun Rumus IF pikeun Rentang Tanggal dina Excel (6 Métode)

Bacaan Sarupa:

  • Kumaha Nyetél Panginget Tanggal Due dina Excel (3 Métode Gancang)
  • Paké Pivot Table pikeun Nyaring Rentang Tanggal dina Excel (5 Cara)
  • VLOOKUP Rentang Tanggal sareng Nilai Balik dina Excel (4 Métode anu Cocog)
  • Kumaha Ngitung Rata-rata Upami dina Rentang Tanggal dina Excel (3 Cara)

Métode-4: Ngagunakeun Fungsi SUMIFS sareng TODAY

S Upami anjeun hoyong kéngingkeun total nilai penjualan kanggo kaping antara 1/1/2022 sareng tanggal ayeuna ( 3/23/2022 ) sareng kanggo Wétan Wilayah . Sareng, pikeun ngalakukeun ieu anjeun tiasa nganggo fungsi TODAY sareng fungsi SUMIFS .

Lengkah :

➤ Ketik rumus ieu dina sél D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY(),D4:D11,C14)

Di dieu, E4:E11 nyaeta rentang jualan nunilai anu urang hoyong jumlah, C4:C11 nyaéta rentang tanggal pikeun kriteria kahiji jeung kadua, sarta rentang kriteria panungtungan nyaéta D4:D11 ngandung wewengkon.

  • ">="&B14 janten

    ">= 44562"

  • TODAY() → ngabalikeun tanggal ayeuna

    Kaluaran → 44643 (3/23/2022)

  • "<="&TODAY() janten

    "<= 44643"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) janten

    SUMIFS(E4:E11,C4:C11,">= 44562",C4:C11,"<= 44643",D4:D11, “East”) → mariksa upami nilai tanggal tina rentang C4:C11 leuwih gede atawa sarua jeung 44562 jeung kurang atawa sarua jeung 44643 jeung wewengkon Wétan dina D4: D11 rentang

    Kaluaran → $15,208.00

➤ Pencét ENTER .

Ahirna, anjeun bakal nampi jumlah penjualan anu $15,208.00 kanggo tanggal antara dinten kahiji Januari 2022 sareng titimangsa dinten ieu kalayan kritéria: Wetan Wilayah .

Upami anjeun badé ngarobih tanggal ahir tanggal éta rentang ti tanggal kiwari nepi ka 10 poé saméméh tanggal dinten ieu lajeng nganggo rumus handap

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()-10,D4:D11,C14)

Pikeun titimangsa panungtungan salaku tanggal 10 poé sanggeus tanggal poé ieu

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()+10,D4:D11,C14)

Baca Selengkapnya: Excel VBA: Tanggal Filter sateuacan Dinten (Kalayan Léngkah Gancang)

Métode-5: Kombinasi Fungsi SUM sareng IF ka SUMIF antara Dua Tanggal sareng Kriteria Lain

Anjeun tiasa nganggo kombinasi fungsi SUM sareng fungsi IF kaitung total penjualan pikeun kaping antara 1/10/2022 nepi ka 3/20/2022 jeung pikeun Wétan Wilayah .

Lengkah :

➤ Ketik rumus ieu dina sél E14 .

=SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))

Di dieu, E4:E11 nyaéta rentang jualan nu urang hoyong jumlah, C4 :C11 nyaéta rentang tanggal pikeun kriteria kahiji jeung kadua, sarta rentang kriteria panungtungan nyaéta D4:D11 ngandung wewengkon.

  • IF((C4:C11)>=B14 → mariksa lamun nilai tanggal rentang C4:C11 leuwih gede atawa sarua jeung nilai B14 .

    Kaluaran → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • IF((C4:C11)<=C14 → mariksa lamun nilai tanggal rentang C4:C11 kurang atawa sarua jeung nilai C14 .

    Kaluaran → {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE}

  • IF(D4:D11=D14,E4:E11) → mariksa lamun wewengkon tina rentang D4:D11 sarua jeung wewengkon Wétan tina C14 jeung mulang

    ({TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}, E4:E11)

    Kaluaran → {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))) janten

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE} , {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE} , {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}, {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    Kaluaran → {FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))) janten

    SUM({FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE})

    Kaluaran → $13.806.00

➤ Pencét ENTER .

Antukna, anjeun bakal nampi jumlah penjualan, $13,806.00 kanggo rentang tanggal anu didefinisikeun ku kriteria séjén: Wétan Wewengkon .

Eusi Patali: Excel SUMIF kalawan Rentang Tanggal dina Bulan &Taun (4 Conto)

Métode-6: Ngagunakeun Fungsi SUMPRODUCT, MONTH, jeung YEAR

Di dieu, urang bakal ngagunakeun fungsi SUMPRODUCT , nu Fungsi BULAN , jeung fungsi TAHUN pikeun nyimpulkeun nilai jualan pikeun tanggal Januari bulan jeung Timur Wilayah.

Lengkah :

➤ Ketik rumus ieu dina sél E14 .

=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)

Di dieu, E4:E11 nyaéta rentang jualan nu urang rék dijumlahkeun, C4:C11 nyaéta rentang tanggal pikeun kriteria kahiji jeung kadua, sarta rentang kriteria panungtungan nyaéta D4:D11 ngandung wewengkon.

  • MONTH(C4:C11) → BULAN ngabalikeun jumlah bulan tanggal

    Kaluaran → {1;1;1;2;2;3;3;3}

  • MONTH(C4:C11)=1 janten

    {1;1;1;2;2;3;3;3}=1

    Kaluaran → {TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}

  • YEAR(C4:C11) → ngabalikeun nilai taun ti tanggal

    Kaluaran → {2022;2022;2022;2022;2022;2022;2022;2022}

  • YEAR(C4:C11)=2022 janten

    {2022;2022;2022;2022;2022;2022;2022;2022}=2022

    Kaluaran → {TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • D4:D11=D14 → mariksa lamun wewengkon rentang D4:D11 sarua jeung wewengkon Wétan tina C14

    Kaluaran → {TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}
  • SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11) janten

    → SUMPRODUCT({TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}*{TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;1;0;0;0;0;0}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;0;0;0;0;0;0}*E4:E11)  SUMPRODUCT({1402;5935;0;0;0;0;0;0})

    Kaluaran → $7,337.00

➤ Pencét ENTER .

Sanggeusna, anjeun bakal meunang jumlah tina penjualan, $7,337.00 pikeun Januari bulan kalayan kriteria séjén: Wétan Wilayah .

Baca deui: Excel SUMIF kalawan Rentang Tanggal dina Bulan & amp; Taun (4 Conto)

Métode-7: Kode VBA ka SUMIF antara Dua Tanggal jeung Kritéria Béda

Kami baris ngagunakeun VBA kode di dieu pikeun ngalakukeun itungan total tina nilai jualan antara dua tanggal 1/10/2022 jeung 3/20/2022 jeung kriteria Wétan Wilayah .

Lengkah :

➤ Pindah ka Pamekar Tab >> Visual Basic Pilihan.

Lajeng, Visual Basic Editor bakal muka .

➤ Pindah ka Selapkeun Tab >> Modul Pilihan.

Sanggeus éta, a Modul bakal dijieun.

➤ Tulis kodeu ieu

9223

Urang bakal meunang nilai dina sél E14 jeung DATEVALUE bakal ngarobah string tanggal jadi nilai titimangsa lajeng sanggeus minuhan kriteria SUMIFS bakal mulangkeun nilai jualan ditambahkeun dina sél E14 .

➤ Pencét F5 .

Ahirna, anjeun bakal meunang jumlah penjualan $13,806.00 pikeun rentang tanggal tangtu kami kalawan kriteria sejen: Wetan Wilayah .

Baca deui: Kumaha Ngagunakeun SUMIFS kalawan Rentang Tanggal sareng Sababaraha Kriteria (7 Cara Gancang)

Bagian Praktek

Pikeun ngalaksanakeun latihan ku nyalira kami parantos nyayogikeun bagian Praktek sapertos di handap dina lambaran anu namina. Praktek . Mangga laksanakeunku sorangan.

Kacindekan

Dina artikel ieu, urang nyoba nutupan cara pikeun SUMIF antara dua tanggal jeung kriteria sejen kalawan gampang. . Miharep anjeun bakal manggihan eta mangpaat. Upami anjeun gaduh saran atanapi patarosan, mangga bagikeun dina bagian koméntar.

pos saméméhna Kumaha Ngabagi Lembar Excel kana Sababaraha Lembar Kerja (3 Métode) -
Tulisan salajengna Kumaha Ngitung Rata-rata Beurat sareng Persentase dina Excel

Hugh West mangrupikeun palatih sareng analis Excel anu ngalaman langkung ti 10 taun pangalaman di industri. Anjeunna nyepeng gelar Sarjana Akuntansi sareng Keuangan sareng gelar Master dina Administrasi Bisnis. Hugh gaduh gairah pikeun ngajar sareng parantos ngembangkeun pendekatan pangajaran anu unik anu gampang diturutan sareng kahartos. Pangaweruh ahli ngeunaan Excel parantos ngabantosan rébuan mahasiswa sareng profésional di sakumna dunya ningkatkeun kaahlian sareng unggul dina karirna. Ngaliwatan blogna, Hugh ngabagi pangaweruhna ka dunya, nawiskeun tutorial Excel gratis sareng pelatihan online pikeun ngabantosan individu sareng usaha ngahontal poténsi pinuh.