Sisukord
Excel 365 annab meile võimsa funktsiooni meie andmekogumite automaatseks filtreerimiseks, mille nimi on FILTER funktsioon. See teeb meie ülesande lihtsamaks, kasutades seda funktsiooni Exceli valemites. See artikkel jagab täielikku ideed, kuidas FILTER funktsioon töötab Excelis iseseisvalt ja seejärel koos teiste Exceli funktsioonidega. Kui olete ka ise uudishimulik, laadige alla meie harjutustööraamat ja jälgige meid.
Lae alla praktiline töövihik
Lae alla see harjutusvihik, et seda artiklit lugedes harjutada.
Funktsiooni FILTER kasutamine.xlsx
FILTER-funktsiooni tutvustus Excelis
Funktsiooni eesmärk:
Filtreerida mõned konkreetsed lahtrid või väärtused vastavalt meie nõuetele.
Süntaks:
=FILTER (array, include, [if_empty])
Argumendid Selgitus:
| Argument | Kohustuslik või vabatahtlik | Väärtus |
|---|---|---|
| massiivi | Nõutav | Massiiv, massiivi valem või viide rakkude vahemikule, mille jaoks vajame ridade arvu. |
| lisada | Nõutav | See toimib nagu booluse massiivi; see kannab tingimust või filtreerimiskriteeriumi. |
| [if_empty] | Valikuline | Edasta väärtus, mis tagastatakse, kui tulemusi ei tagastata. |
Tagasi parameeter:
Funktsioon tagastab dünaamilise tulemuse. Kui lähteandmete väärtused muutuvad või kui lähteandmete massiivi suurus muutub, uuendatakse FILTERi tulemusi automaatselt.
10 sobivat näidet funktsiooni FILTER kasutamise kohta Excelis
Näidete demonstreerimiseks käsitleme andmekogumit, milleks on 10 asutuse üliõpilased. Nende ID, nimi, osakond, sissekirjutatud semester ja CGPA summa on lahtrite vahemikus. B5:F14 .
📚 Märkus:
Kõik käesoleva artikli toimingud on teostatud, kasutades selleks Microsoft Office 365 rakendus.
1. AND-operatsiooni teostamine mitme kriteeriumi jaoks FILTER-funktsiooniga
Esimeses näites teostame JA operatsiooni poolt FILTER Meie soovitud tingimused on vahemikus rakud C5:C6 .
Selle näite täitmiseks vajalikud sammud on esitatud allpool:
📌 Sammud:
- Kõigepealt valige lahter B10 .
- Nüüd kirjutage lahtrisse järgmine valem.
=FILTER(Dataset!B5:F14,(Dataset!D5:D14=C5)*(Dataset!F5:F14>=C6), "no results")
- Seejärel vajutage Sisesta .
- Saate filtreeritud tulemuse lahtrite vahemikus B10:F11 .
Seega võime öelda, et me oleme võimelised kohaldama FILTER funktsioon JA operatsioon.
2. Mitme kriteeriumi puhul OR-operatsiooni rakendamine koos FILTER-funktsiooniga
Teises näites kasutame me funktsiooni FILTER funktsiooni jaoks VÕI operatsioon. Siin me mainisime tingimused vahemikus rakkude C5:C6 .
Selle näite lõpetamiseks vajalikud sammud on esitatud järgmiselt:
📌 Sammud:
- Kõigepealt valige lahter B10 .
- Pärast seda kirjutage lahtrisse järgmine valem.
=FILTER(Dataset!B5:F14,(Dataset!D5:D14=OR!C5)+(Dataset!F5:F14>=OR!C6), "no results")
- Press Sisesta .
- Saate aru, et filtreeritud tulemus on soovitud lahtrites.
Seega on meil võimalik kasutada FILTER funktsioon ideaalselt VÕI operatsioon.
3. AND- ja OR-loogika kombinatsioon FILTER-funktsiooniga
Nüüd kasutame me FILTER funktsioon kombineeritud JA ja VÕI toiming. Tingimused on vahemikus lahtrid C5:C7 .
Allpool on esitatud selle näite täitmise sammud:
📌 Sammud:
- Kõigepealt valige lahter B11 .
- Seejärel kirjutage lahtrisse järgmine valem.
=FILTER(Dataset!B5:F14,(Dataset!F5:F14>=Combine!C7)*((Dataset!D5:D14=Combine!C5)+(Dataset!D5:D14=Combine!C6)), "No results")
- Vajutage Sisesta .
- Märkate, et filtreeritud tulemus on saadaval lahtrites.
Seetõttu töötab meie valem tõhusalt ja me suudame teostada JA ja VÕI toimingud samaaegselt FILTER funktsioon.
4. Duplikaatide filtreerimine funktsiooni FILTER abil
Selles näites kavatseme filtreerida meie andmekogumist välja dubleerivad üksused. Meie andmekogum sisaldab 2 dubleerivad üksused.
Selle näite sammud on esitatud allpool:
📌 Sammud:
- Alguses valige lahter H5 .
- Seejärel kirjutage lahtrisse järgmine valem.
=FILTER(B5:F16,COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16,F5:F16)>1,"No result")
- Seega vajutage Sisesta .
- Näete, et kõik dubleeritud väärtused on eraldi loetletud.
Lõpuks võime öelda, et meie valem töötab täpselt ja me suudame duplikaadid välja arvutada, kasutades selleks FILTER funktsioon Excelis.
🔎 Valemi selgitus
👉 COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16,F5:F16) : The COUNTIFS funktsioon kontrollib dubleerivate väärtuste olemasolu.
👉 FILTER(B5:F16,COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16, F5:F16)>1,”No result”) : Lõpuks on FILTER funktsioon filtreerib dubleerivad väärtused ja loetleb need eraldi.
5. Tühjade lahtrite väljaselgitamine funktsiooni FILTER abil
Meil on andmekogum, milles on mõned tühjad lahtrid. Nüüd filtreerime välja lahtrid, mis ei sisalda ühtegi tühja funktsiooni, abiga FILTER funktsioon.
Täielike ridade välja filtreerimise protseduur on esitatud allpool::
📌 Sammud:
- Esiteks, valige lahter H5 .
- Seejärel kirjutage lahtrisse järgmine valem.
=FILTER(B5:F14,(B5:B14"")*(C5:C14"")*(D5:D14"")*(E5:E14"")*(F5:F14""),"No results")
- Pärast seda vajutage Sisesta .
- Saate need üksused, millel ei ole ühtegi tühja lahtrit.
Seega võime öelda, et meie valem töötab viljakalt ja me saame Exceli abil väärtuse ilma tühjade lahtriteta. FILTER funktsioon.
Sarnased lugemised
- Kuidas kasutada Exceli HYPERLINK-funktsiooni (8 näidet)
- VLOOKUP ja HLOOKUP kombineeritud Exceli valem (koos näitega)
- Exceli kasutamine teksti osalise vaste otsimiseks [2 lihtsat viisi]
- Kuidas leida dubleerivaid väärtusi Excelis, kasutades VLOOKUP-i
6. Filtreeri lahtrid, mis sisaldavad konkreetset teksti
Kasutades FILTER funktsiooniga saame hõlpsasti otsida mis tahes konkreetset väärtust ja filtreerida vastavad üksused meie algsest andmestikust välja. Lisaks FILTER funktsioon, et ISNUMBER ja OTSIMINE funktsioonid aitavad meil ka valemit täiendada. Meie soovitud tekst 'Ellie' kuvatakse lahtris J4 .
Konkreetse teksti andmete välja filtreerimise meetodit kirjeldatakse allpool::
📌 Sammud:
- Valige alguses lahter H7 .
- Seejärel kirjutage lahtrisse järgmine valem.
=FILTER(B5:F14,ISNUMBER(SEARCH(J4,C5:C14)), "No results")
- Seejärel vajutage Sisesta võti.
- Saate tulemuse selle konkreetse tekstiga.
Seega saame valemit edukalt rakendada ja saada meie konkreetse tekstiväärtuse väärtuse.
🔎 Valemi selgitus
👉 SEARCH(J4,C5:C14) : The OTSIMINE funktsioon tagastab lahtrid, mis sobitatakse sisendväärtusega.
👉 ISNUMBER(SEARCH(J4,C5:C14)) : The ISNUMBER funktsioon tagastab true, kui otsingu väärtus on muu kui false.
👉 FILTER(B5:F14,ISNUMBER(SEARCH(J4,C5:C14)), "No results") : Lõpuks on FILTER funktsioon eraldab sobivad read ja näitab neid.
7. Summa, maksimumi, miinimumi ja keskmise arvutamine
Nüüd teeme mõned matemaatilised arvutused abiga FILTER Andmed, mida me filtreerime, on lahtris J5 Siinkohal hakkame määrama kõiki väärtusi, mida CSE osakond.
Lisaks FILTER funktsioon, et SUM , AVERAGE , MIN ja MAX hindamisprotsessi lõpuleviimiseks kasutatakse funktsioone. Hinnanguline väärtus jääb vahemikku lahtrite J7:J10 Allpool selgitatakse arvutusprotseduuri samm-sammult:
📌 Sammud:
- Kõigepealt valige lahter J7 .
- Nüüd kirjutage lahtrisse järgmine valem summeerimise jaoks.
=SUM(FILTER(F5:F14,D5:D14=J5,0))
🔎 Valemi selgitus
👉 FILTER(F5:F14,D5:D14=J5,0) : The FILTER funktsioon filtreerib CGPA meie soovitud osakonna väärtus.
👉 SUM(FILTER(F5:F14,D5:D14=J5,0)) : Lõpuks on SUM funktsioon lisab kõik need.
- Press Sisesta .
- Pärast seda valige lahter J8 ja kirjutage üles järgmine valem keskmine väärtus.
= AVERAGE(FILTER(F5:F14,D5:D14=J5,0))
🔎 Valemi selgitus
👉 FILTER(F5:F14,D5:D14=J5,0) : The FILTER funktsioon filtreerib meie soovitud osakonna CGPA väärtuse.
👉 AVERAGE(FILTER(F5:F14,D5:D14=J5,0)) : The AVERAGE funktsioon arvutab keskmine nende väärtuste väärtus.
- Jällegi, vajutage Sisesta .
- Seejärel valige lahter J9 ja kirjutage lahtrisse järgmine valem, et saada lahtrisse minimaalne väärtus.
=MIN(FILTER(F5:F14,D5:D14=J5,0))
🔎 Valemi selgitus
👉 FILTER(F5:F14,D5:D14=J5,0) : The FILTER funktsioon filtreerib meie soovitud osakonna CGPA väärtuse.
👉 MIN(FILTER(F5:F14,D5:D14=J5,0)) : The MIN funktsioon arvutab välja minimaalne väärtuse seas 4 väärtused.
- Samamoodi vajutage Sisesta .
- Lõpuks valige lahter J10 ja kirjutage lahtrisse järgmine valem, mis käsitleb maksimaalne väärtus.
=MAX(FILTER(F5:F14,D5:D14=J5,0))
🔎 Valemi selgitus
👉 FILTER(F5:F14,D5:D14=J5,0) : The FILTER funktsioon filtreerib meie soovitud osakonna CGPA väärtuse.
👉 MAX(FILTER(F5:F14,D5:D14=J5,0)) : The MAX funktsioon leiab välja maksimaalne väärtuse seas 4 CGPA väärtused.
- Press Sisesta viimast korda.
- Te märkate, et kõik väärtused CSE osakond on saadaval.
Seega võime öelda, et kõik meie valemid toimivad suurepäraselt ja me saame kõik soovitud väärtused Exceli abil. FILTER funktsioon.
8. Andmete filtreerimine ja ainult konkreetsete veergude tagastamine
Siinkohal kasutame me FILTER funktsiooni kaks korda sisseehitatud tingimuses, et saada konkreetsed veerud, mis põhinevad meie soovitud väärtusel. Meie soovitud üksus on lahtris J5 Me näitame ainult ID ja Nimi veerus.
Selle protsessi etapid on esitatud allpool:
📌 Sammud:
- Kõigepealt valige lahter H8 .
- Seejärel kirjutage lahtrisse järgmine valem.
=FILTER(FILTER(B5:F14,D5:D14=J5),{1,1,0,0,0})
- Pärast seda vajutage Sisesta .
- Saate ainult ID ja Nimi veerus meie soovitud osakond.
Seega võime öelda, et meie valem töötab korralikult ja me saame Exceli abil mõned konkreetsed veerud. FILTER funktsioon.
🔎 Valemi selgitus
👉 FILTER(B5:F14,D5:D14=J5) : The FILTER funktsioon tagastab sobivad read antud andmestikust koos kõigi veergudega.
👉 FILTER(FILTER(B5:F14,D5:D14=J5),{1,1,0,0,0}) : Väline FILTER funktsioon valib ainult esimese kaks valitud andmete veerud. Me võime kas kasutada 0 , 1 või TÕELINE , VALE .
9. Kohalda piirangut tagastatavate ridade arvule
Sellisel juhul lisame mõned piirangud, et FILTER funktsioon piiratud arvu ridade saamiseks. Meie soovitud osakond on lahtris J5 Piirangu kohaldamiseks peame kasutama piirangut. IFERROR ja INDEX toimida ka.
Selle matemaatilise meetodi etapid on kirjeldatud järgmiselt:
📌 Sammud:
- Kõigepealt valige lahter H8 .
- Seejärel kirjutage lahtrisse järgmine valem.
=IFERROR(INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}),"No result")
- Seejärel vajutage Sisesta .
- Saate tulemuse.
Seega võime öelda, et me oleme võimelised edukalt rakendama Exceli FILTER , INDEX ja IFERROR toimib edukalt.
🔎 Valemi selgitus
👉 FILTER(B5:F14,D5:D14=J5) : The FILTER funktsioon tagastab filtreeritud andmed, sobitades need sisendväärtusega.
👉 INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}) : See valem tagastab sobitatud andmete kaks esimest rida. {1;2} see on kahe esimese rea jaoks. Ja {1,2,3,4,5} see on viie veeru valimiseks.
👉 IFERROR(INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}), "No result") : Lõpuks, see on IFERROR funktsiooni kasutatakse vea vältimiseks, kui on probleem teiste funktsioonide tagastusväärtustega.
10. Wildcard'i kasutamine koos FILTER-funktsiooniga
Viimases näites hakkame andmete filtreerimiseks rakendama filtri jokkerit. Rakendame valemit valemiga ISNUMBER , OTSIMINE ja FILTER Meie soovitud väärtus on lahtris J5 .
Protsessi selgitatakse allpool samm-sammult:
📌 Sammud:
- Esiteks, valige lahter H8 ja kirjutage lahtrisse järgmine valem.
=FILTER($B$5:$F$14,ISNUMBER(SEARCH(J5,D5:D14)), "No Results!")
- Nüüd vajutage Sisesta .
- Saate kõik tulemused koos lahtri väärtusega C .
Lõpuks võime öelda, et meie valem töötab täpselt ja me suudame Exceli abil luua jokkerkaardi. FILTER funktsioon.
🔎 Valemi selgitus
👉 SEARCH(J5,D5:D14) : The OTSIMINE funktsioon otsib andmeid, sobitades need sisendväärtusega.
👉 ISNUMBER(SEARCH(J5,D5:D14)) : See valem kontrollib, millise tulemuse OTSIMINE funktsioon on ture,
👉 FILTER($B$5:$F$14,ISNUMBER(SEARCH(J5,D5:D14)), "No Results!") : Lõpuks, see on FILTER funktsioon näitab neid meie soovitud lahtrisse.
Exceli FILTER-funktsiooni alternatiivid
Meie eelmisest rakendusest võite märgata, et Excel FILTER funktsioon on pisut mugav funktsioon meie soovitud väärtuste saamiseks lühikese aja jooksul. Selle funktsiooni jaoks ei ole konkreetset alternatiivi. Kuid mõne üldise Exceli funktsiooni kombinatsioon võib meile tagastada tulemused FILTER funktsioon. Nende hulgas on IFERROR , INDEX , AGGREGATE , ROW , ISNA , MATCH funktsioonid on mainimisväärsed. Kuid me soovitame teile, et kui teil on FILTER funktsiooniga, siis minge. Nende funktsioonide kombinatsioon muudab valemi teistele arusaadavamaks. Peale selle võib see teie Exceli rakendust aeglustada.
Võimalikud põhjused, kui funktsioon FILTER ei tööta
Mõnikord on FILTER Exceli funktsioon ei tööta korralikult. Enamasti tekib see vea olemasolu tõttu. Peamiselt on #SPILL! , #CALC! , #VALUE! vead ei võimalda tavaliselt FILTER funktsioon tööle ja tagastab soovitud andmed. Selle vea kõrvaldamiseks minge tagasi oma esialgse andmestiku juurde ja parandage need, ja te leiate, et FILTER funktsioon töötab tõrgeteta.
Allpool selgitatakse lühidalt Exceli sageli esinevaid vigu:
| Tavalised vead | Kui nad näitavad |
|---|---|
| #VALUE | See ilmub, kui massiivi ja include argumendi mõõtmed ei ühildu. |
| #CALC! | See ilmub, kui valikuline argument if_empty on välja jäetud ja kriteeriumidele vastavaid tulemusi ei leita. |
| #NAME | See ilmub, kui proovite kasutada FILTERit Exceli vanemas versioonis. |
| #SPILL | See viga ilmneb, kui üks või mitu lahtrit väljavoolupiirkonnas ei ole täielikult tühjad. |
| #REF! | See viga juhtub, kui FILTER-valemit kasutatakse erinevate töövihikute vahel ja suletakse lähtetööraamat. |
| #N/A või #VALUE | Seda tüüpi viga võib tekkida, kui mõni lisatud argumendi väärtus on viga või seda ei saa muuta booleseks väärtuseks (0,1 või TRUE, FALSE). |
Kokkuvõte
Sellega on see artikkel lõppenud. Loodan, et see artikkel on teile kasulik ja te suudate Excelis FILTER funktsiooni rakendada. Palun jagage meiega kommentaare, kui teil on täiendavaid küsimusi või soovitusi, kui teil on täiendavaid küsimusi või soovitusi.
Ärge unustage vaadata meie veebisaiti, ExcelWIKI , mitmete Exceliga seotud probleemide ja lahenduste jaoks. Jätkake uute meetodite õppimist ja kasvamist!
