Slik summerer du mellom to datoer og med andre kriterier (7 måter)

Hugh West

18-10-2023 Excel-formler
  • Dele Denne
Hugh West

Hvis du leter etter noen av de enkleste måtene SUMIF mellom to datoer og andre kriterier, vil du finne denne artikkelen nyttig. Å legge sammen verdier innenfor en grense av tidsperioder og basert på kriterier må gjøres noen ganger, og for å gjøre denne oppgaven raskt kan du følge denne artikkelen.

Last ned arbeidsbok

SUMIF mellom Dates.xlsm

7 måter å SUMMER mellom to datoer og med et annet kriterium

Her har vi følgende datasett som inneholder salgsoppføringer for noen produkter med estimerte leveringsdatoer og selge regioner i et selskap. Ved å bruke dette datasettet vil vi demonstrere måtene å summere opp salgsverdier basert på en spesifisert region og datoperiode.

Vi har brukt Microsoft Excel 365 versjon her kan du bruke alle andre versjoner etter eget ønske.

Metode-1: Bruk SUMIFS-funksjonen for å SUMMER mellom to datoer med et annet kriterium

Vi ønsker å summere salgsverdiene for Øst Region og for datoene mellom 1/10/2022 og 20/3/2022 (m-dd-åååå) ved å bruke SUMIFS-funksjonen her.

Trinn :

➤ Skriv inn følgende formel i celle E14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&C14,D4:D11,"East")

Her, E4:E11 er salgsområdet som verdiene vi ønsker å summere, C4:C11 er datointervallet for det første kriteriet, “>=”&B14 er det første kriterietsom betyr større enn eller lik startdatoen 1/10/2022 . Det andre kriterieområdet er likt det første, og kriteriet for dette området er “<=”&C14 som betyr mindre enn eller lik sluttdatoen 20.3.2022 og det siste kriterieområdet er D4:D11 som inneholder regionene, vil kriteriene for dette området være Øst .

➤ Trykk ENTER .

Nå vil du få summen av salg på $13 806,00 for vår definerte datoperiode med et annet kriterium: Øst Region .

Les mer: Hvordan gjøre SUMIF Date Range Month i Excel (9 måter)

Metode-2: Bruke SUMIFS og EOMONTH til SUMIF mellom to datoer med et annet kriterium

I denne delen vil vi prøve å finne summen av salgsverdiene for datoene januar måned og Sør regionen . Så vi vil bruke EOMONTH-funksjonen med SUMIFS-funksjonen her.

Trinn :

➤ Skriv inn følgende formel i celle D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&EOMONTH(B14,0),D4:D11,C14)

Her, E4:E11 er salgsintervallet som verdiene vi vil summere, C4:C11 er datointervallet for det første kriteriet, “>=”&B14 er det første kriteriet som betyr større enn eller lik startdatoen 1/1/2022 . Det andre kriterieområdet er likt det første ogkriteriene for dette området er “<=”&EOMONTH(B14,0) som betyr mindre enn eller lik sluttdatoen januar måned, 1/31/2022 , og det siste kriterieområdet er D4:D11 som inneholder regionene, Kriteriene for dette området vil være Øst .

➤ Trykk ENTER .

Etter det vil du få summen av salg, $6 835,00 for datoene januar måned med et annet kriterium: Sør Region .

Les mer: Hvordan bruke SUMIFS til å summere verdier i datoperiode i Excel

Metode-3: SUMIFS- og DATO-funksjoner til SUMIF mellom to datoer

Her vil vi bruke SUMIFS-funksjonen og DATE funksjon , for å oppsummere salgsverdiene for Nord regionen og for datoene innenfor 1/10/2022 og 20.3.2022 .

Trinn :

➤ Type følgende formel i celle E14 .

=SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)

Her, E4: E11 er salgsområdet som verdiene vi ønsker å summere, C4:C11 er datointervallet for det første og andre kriteriet, og det siste kriterieområdet er D4:D11 som inneholder regionene.

  • DATE(2022,1,10) → returnerer et tall for en datoverdi

    Utdata → 44571

  • ">="&DATE(2022,1,10) blir

    ">= 44571"

  • DATE(2022,3,20) → returnerer et tall for en datoverdi

    Utdata → 44640

  • "<="&DATE(2022,3,20) blir

    "<= 44640"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) blir

    SUMIFS(E4:E11,C4:C11,">= 44571",C4:C11,"<= 44640",D4:D11, “North”) → sjekker om datoverdiene for området C4:C11 er større enn eller lik 44571 og mindre enn eller lik 44640 og regionen Nord i D4:D11 området

    Utgang → $9 496,00

➤ Trykk ENTER .

Deretter får du summen av salg, $9 496,00 for vår definerte datoperiode med de andre kriteriene: Nord Region .

Relatert innhold: Hvordan bruke IF-formel for datoperiode i Excel (6 metoder)

Lignende avlesninger:

  • Hvordan angi forfallsdatopåminnelse i Excel (3 raske metoder)
  • Bruk pivottabell for å filtrere datoperiode i Excel (5 måter)
  • VLOOKUP datoperiode og returverdi i Excel (4 egnede metoder)
  • Hvordan beregne gjennomsnitt hvis innenfor datoperiode i Excel (3 måter)

Metode-4: Bruke SUMIFS-funksjonen med TODAY

S du ønsker å få de totale salgsverdiene for datoene mellom 1/1/2022 og dagens dato ( 23/3/2022 ) og for Øst Region . Og for å gjøre dette kan du bruke IDAG-funksjonen sammen med SUMIFS-funksjonen .

Trinn :

➤ Skriv inn følgende formel i celle D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY(),D4:D11,C14)

Her, E4:E11 er salgsområdet somverdier vi ønsker å summere, C4:C11 er datointervallet for det første og andre kriteriet, og det siste kriterieområdet er D4:D11 som inneholder regionene.

  • ">="&B14 blir

    ">= 44562"

  • TODAY() → returnerer dagens dato

    Utgang → 44643 (23.3.2022)

  • "<="&TODAY() blir

    "<= 44643"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) blir

    SUMIFS(E4:E11,C4:C11,">= 44562",C4:C11,"<= 44643",D4:D11, “East”) → sjekker om datoverdiene for området C4:C11 er større enn eller lik 44562 og mindre enn eller lik 44643 og regionen Øst i D4: D11 område

    Utgang → $15 208,00

➤ Trykk ENTER .

Til slutt vil du få summen av salg som er $15 208,00 for datoene mellom den første dagen i januar 2022 og dagens dato med kriterier: Øst Region .

Hvis du vil endre siste dato for datoen varierer fra dagens dato til 10 dager før dagens dato, bruk deretter følgende formel

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()-10,D4:D11,C14)

For siste dato som en dato 10 dager etter dagens dato

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()+10,D4:D11,C14)

Les mer: Excel VBA: Filtreringsdato før i dag (med raske trinn)

Metode-5: Kombinasjon av SUM- og HVIS-funksjoner til SUM.HVIS mellom to datoer og med et annet kriterium

Du kan bruke kombinasjonen av SUM-funksjonen og HVIS-funksjonen tilberegne det totale salget for datoene mellom 1/10/2022 til 20/3/2022 og for Øst Region .

Trinn :

➤ Skriv inn følgende formel i celle E14 .

=SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))

Her er E4:E11 salgsområdet hvilke verdier vi ønsker å summere, C4 :C11 er datointervallet for det første og andre kriteriet, og det siste kriterieområdet er D4:D11 som inneholder regionene.

  • IF((C4:C11)>=B14 → sjekker om datoverdiene for området C4:C11 er større enn eller lik verdien til B14 .

    Utdata → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • IF((C4:C11)<=C14 → sjekker om datoverdiene for området C4:C11 er mindre enn eller lik verdien av C14 .

    Output → {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE}

  • IF(D4:D11=D14,E4:E11) → sjekker om regionene av området D4:D11 er lik regionen Øst av C14 og returnerer

    ({TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}, E4:E11)

    Utgang → {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))) blir

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE} , {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE} , {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}, {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    Utgang → {FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))) blir

    SUM({FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE})

    Utgang → $13 806,00

➤ Trykk ENTER .

Til slutt vil du få summen av salg, $13 806,00 for vår definerte datoperiode med andre kriterier: Øst Region .

Relatert innhold: Excel SUMIF med en datoperiode i måned &År (4 eksempler)

Metode-6: Bruk av funksjonene SUMPRODUCT, MONTH og YEAR

Her vil vi bruke SUMPRODUKT-funksjonen , 1>MÅNED-funksjonen og ÅR-funksjonen for å summere salgsverdiene for datoene for januar måneden og Øst Region.

Trinn :

➤ Skriv inn følgende formel i celle E14 .

=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)

Her, E4:E11 er salgsområdet som verdiene vi ønsker å summere, C4:C11 er datoperiode for det første og andre kriteriet, og det siste kriterieområdet er D4:D11 som inneholder regionene.

  • MONTH(C4:C11) → MONTH returnerer månedsnummeret for datoene

    Utdata → {1;1;1;2;2;3;3;3}

  • YEAR(C4:C11) → returnerer årsverdiene for datoene

    Utgang → {2022;2022;2022;2022;2022;2022;2022;2022}

  • YEAR(C4:C11)=2022 blir

    {2022;2022;2022;2022;2022;2022;2022;2022}=2022

    Utgang → {TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • D4:D11=D14 → sjekker om områdene i området D4:D11 er lik regionen Øst av C14

    Utgang → {TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}
  • SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11) blir

    → SUMPRODUCT({TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}*{TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;1;0;0;0;0;0}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;0;0;0;0;0;0}*E4:E11)  SUMPRODUCT({1402;5935;0;0;0;0;0;0})

    Utgang → $7 337,00

➤ Trykk ENTER .

Etterpå vil du få summen av salg, $7 337,00 for januar måned med et annet kriterium: East Region .

Les mer: Excel SUMIF med en datoperiode i måned & År (4 eksempler)

Metode-7: VBA-kode til SUMIF mellom to datoer med forskjellige kriterier

Vi vil bruke en VBA -kode her for å utføre beregning av summen av salgsverdiene mellom de to datoene 1/10/2022 og 20/3/2022 med et kriterium Øst Region .

Trinn :

➤ Gå til Utvikler Fane >> Visual Basic Alternativ.

Deretter åpnes Visual Basic Editor .

➤ Gå til Sett inn fanen >> Modul Alternativ.

Etter det, en Modul vil bli opprettet.

➤ Skriv følgende kode

6378

Vi får verdien vår i celle E14 og DATOVERDI vil konvertere datostrengen til en datoverdi, og etter å ha oppfylt kriteriene vil SUMIFS returnere den ekstra salgsverdien i celle E14 .

➤ Trykk F5 .

Til slutt vil du få summen av salg på $13 806,00 for vår definerte datoperiode med et annet kriterium: Øst Region .

Les mer: Hvordan bruke SUMIFS med Datointervall og flere kriterier (7 raske måter)

Øvingsseksjon

For å øve selv har vi gitt en Øving -seksjon som nedenfor i et ark med navn Øv . Vennligst gjør detav deg selv.

Konklusjon

I denne artikkelen prøvde vi å dekke måtene å SUMIF mellom to datoer og et annet kriterium enkelt . Håper du finner det nyttig. Hvis du har forslag eller spørsmål, del dem gjerne i kommentarfeltet.

Forrige innlegg Hvordan dele opp Excel-ark i flere regneark (3 metoder) -
Neste innlegg Hvordan beregne vektet gjennomsnitt med prosenter i Excel

Hugh West er en svært erfaren Excel-trener og analytiker med over 10 års erfaring i bransjen. Han har en bachelorgrad i regnskap og finans og en mastergrad i bedriftsøkonomi. Hugh har en lidenskap for undervisning og har utviklet en unik undervisningstilnærming som er enkel å følge og forstå. Hans ekspertkunnskap om Excel har hjulpet tusenvis av studenter og fagfolk over hele verden med å forbedre sine ferdigheter og utmerke seg i karrieren. Gjennom bloggen sin deler Hugh sin kunnskap med verden, og tilbyr gratis Excel-opplæringer og nettbasert opplæring for å hjelpe enkeltpersoner og bedrifter å nå sitt fulle potensial.