Táboa de contidos
Microsoft Excel proporcionou numerosas formas de determinar os 5 principais valores ou nomes ou ambos a partir dunha gran variedade de datos. Neste artigo, aprenderás todas as técnicas fructíferas para atopar os 5 principais valores e nomes en Excel.
A captura de pantalla anterior é unha visión xeral de o artigo que representa o conxunto de datos & un exemplo de como pode extraer os 5 principais valores xunto cos nomes dunha serie de datos. Poderás obter máis información sobre o conxunto de datos xunto con todas as funcións adecuadas nos seguintes métodos deste artigo.
Descargar o libro de prácticas
Podes descargar o libro de Excel. que usamos para preparar este artigo.
Atopar os 5 principais valores & Nomes
8 xeitos axeitados de atopar os 5 principais valores e nomes en Excel sen ou con duplicados
1. Atopar os 5 principais valores & Nomes sen duplicados
Nos nosos primeiros criterios, trataremos os valores nos que non hai duplicados.
1.1 Obter os 5 principais valores usando LARGE & ROWS Functions Together
Imos presentar agora o noso conxunto de datos. A Columna B representa os nomes aleatorios de 10 estudantes e a Columna C mostra o CGPA de cada estudante dun final de trimestre na súa universidade.
Agora descubriremos os 5 principais CGPA só usando LARGE xunto coas funcións ROWS . A función LARGE descubrirá o valor máis grandedun intervalo de celas baseado no número de serie definido polas funcións ROWS . Tamén obteremos os nomes no seguinte método.
📌 Pasos:
➤ Seleccione Cela E7 & tipo:
=LARGE($C$5:$C$14,ROWS($E$7:$E7)) ➤ Prema Intro & obterás o primeiro CGPA máis alto entre todos da Columna C .
➤ Agora usa Recheo de control para encher 4 celas máis e obter as seguintes 4 CGPA máis grandes .
Ler máis: Os 10 principais valores baseados en criterios en Excel (criterios únicos e múltiples)
1.2 Sacar os 5 principais nomes combinando INDEX e amp; Funcións MATCH
Agora descubriremos os nomes que obtiveron os 5 mellores CGPA. Temos que incorporar INDEX, MATCH, LARGE & ROWS funciona conxuntamente. Aquí, na Columna F , os 5 valores principais da Columna C teñen que determinarse primeiro seguindo o método anterior. Despois temos que pasar á Columna E para extraer os nomes relacionados segundo o seu CGPA.
📌 Pasos:
➤ Na Cela E7 , a nosa fórmula necesaria será:
=INDEX($B$5:$B$14,MATCH(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,0)) ➤ Despois de premer Intro , Obter o primeiro nome 'Jonas' que obtivo o CGPA-4.00 máis alto.
➤ Agora usa Fill Handle para obter os seguintes 4 nomes nesa columna & xa estás.
🔎 Como funciona esta fórmula?
➤ ROWS a función introduce a número de serie para a función LARGE .
➤ O LARGE a función descobre o valor máis grande da matriz ou intervalo de celas seleccionados en función do número de serie.
➤ MATCH busca o maior valor obtido na matriz de valores & devolve co número de fila dese valor.
➤ INDEX finalmente saca o nome da columna de Nomes en función dese número de fila atopado pola función MATCH .
Ler máis: Como atopar o valor na columna en Excel (4 métodos)
1.3 Extraer os 5 principais nomes mediante Usando a función BUSCAR XL
Se queres evitar a fórmula COINCIDENCIAR ÍNDICE , podes substituíla pola función BUSCAR XL busca un rango de celas ou matriz & a continuación, devolve os valores en función das condicións seleccionadas da columna ou fila seleccionada.
📌 Pasos:
➤ Na Cela E7 , a nosa fórmula relacionada con XLOOKUP para atopar os nomes con be:
=XLOOKUP(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,$B$5:$B$14) ➤ Preme Intro e ; use Fill Handle para obter os outros 4 nomes.
No primeiro argumento da función XLOOKUP , o valor máis grande ten introducido. O segundo argumento é o Intervalo de celas C5:C14 onde se buscará o maior valor seleccionado. E o terceiro argumento é outro rango de celas B5:B14 de onde se extraerán os datos ou o nome concretos en función do número de fila atopado polos dous primeiros argumentos.
Ler. Máis: Valor de buscaen Columna e Valor de retorno doutra columna en Excel
1.4 Atopar os 5 principais nomes & Valores baixo varios criterios
Pensemos agora noutro conxunto de datos que comprenda varios criterios. Se notas, agora temos nomes & CGPA en Columnas B e amp; D respectivamente. A columna C representa os departamentos dos estudantes.
Primeiro coñeceremos os 5 mellores CGPA do departamento de Informática & os resultados de saída conseguiranse na Columna H .
📌 Pasos:
➤ Para atopar os 5 principais CGPA , a fórmula relacionada na Cela H12 será:
=LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12) ➤ Prema Intro , use Encher Manexa para obter os outros 4 valores máis grandes & xa estás.
Aquí, coa función IF , imos descubrindo todos os CGPA dos alumnos do departamento de Informática só . A continuación, a función LARGE extrae os 5 principais CGPA como antes.
Agora, determinaremos os nomes que obtiveron estes 5 principais CGPA e usaremos INDEX-MATCH funciona aquí.
📌 Pasos:
➤ Na saída Cela G12 , temos que escribir:
=INDEX($B$5:$B$23,MATCH(LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12), IF($C$5:$C$23=$G$9,$D$5:$D$23),0)) ➤ Prema Intro & use Recheo de control para encher o resto das 4 celas. Recibirás todos os nomes á vez.
Ler máis: Como atopar valor na columna usando VBA en Excel (4 xeitos) )
2. Buscando os 5 principais valores & NomesIncluíndo duplicados
Agora atoparemos os 5 valores principais, así como os nomes incluídos os duplicados. Teremos un conxunto de datos un pouco modificado aquí.
2.1 Conseguindo os 5 principais valores só usando grandes & FILAS Funcións xuntas
Entón, na imaxe de abaixo, a Columna B representa os nomes de 5 estudantes e as Columnas C a J mostran o CGPA de cada un. semestre para eses estudantes. Na táboa inferior, atoparemos os datos de saída.
Entón, ao principio, atoparemos o 5 CGPA máis alto para Andrew entre todos os CGPA de 8 semestres.
📌 Pasos:
➤ Seleccione Cela C13 & tipo:
=LARGE($C6:$N6,COLUMNS($C:C)) ➤ Prema Intro & utiliza Recheo de control para encher as catro celas seguintes ao longo da fila de Andrew.
Se tes conta, tes o valor 4,00 o dobre que o a produción xa que o CGPA de Andrew foi de 4,00 en dous termos. Polo tanto, a función LARGE non omite os valores duplicados mentres busca os máis grandes do intervalo de datos ou celas.
Agora, para obter resultados similares para os outros 4 estudantes, primeiro ten que seleccionar Intervalo de celas- C13:G13 . A continuación, na esquina inferior dereita das celas seleccionadas, atoparás a opción Encher o controlador . Agora use esa opción para arrastrar cara abaixo ata a fila seleccionada para Harry & xa estás feito. Obterás os 5 mellores CGPA para todos os estudantes á vez.
Ler máis: Como atopar o máis altoValor na columna de Excel (4 métodos)
2.2 Extraendo os 5 principais nomes con duplicados combinando INDEX, MATCH e amp; Funcións COUNTIF
Agora, descubriremos os nomes dos 5 mellores estudantes co seu CGPA onde pode haber CGPA duplicado. Se observas no noso conxunto de datos modificado, Sam & Mike ambos teñen un CGPA-3,94 semellante. Pero queremos descubrir os 5 nomes principais, incluídos aqueles que obtiveron CGPA similares tamén coas funcións de Excel.
📌 Pasos :
➤ Seleccione Cela F7 & escriba:
=INDEX($B$5:$B$14, MATCH(1, ($C$5:$C$14=LARGE($C$5:$C$14, $E7))*(COUNTIF(F$6:F6, $B$5:$B$14)=0), 0)) ➤ Prema Intro , use Recheo de control para obter os outros 4 nomes & xa estás feito. Só tes os dous nomes: Sam & Mike que obtivo un CGPA similar.
🔎 Como funciona esta fórmula?
➤ Aquí dentro do MATCH función, preséntanse dúas funcións lóxicas que se multiplican entre si. Estas funcións lóxicas combinadas buscarán os 5 principais CGPA da Columna C & asignará o número 1 aos 5 primeiros & 0 para o resto dos valores. A función
➤ COMPARAR só busca 1 a partir dos resultados anteriores atopados & devolve cos números de fila para todas as coincidencias.
➤ A función INDEX finalmente mostra os nomes en serie en función dos números de fila atopados a través de todas as funcións COMPARAR na Columna F .
Ler máis: Como atopar a primeira aparición dun valor nunha columna enExcel (5 xeitos)
2.3 Extraer os 5 principais nomes con duplicados incorporando ORDENAR & Funcións de FILTRO
Ao usar ORDENAR & FILTER , podes atopar os 5 principais nomes xunto cos valores máis facilmente. Xa non terás que extraer aquí os 5 principais valores antes de descubrir os nomes.
📌 Pasos:
➤ En Cela F7 , a nosa fórmula relacionada con ORDENAR & As funcións de FILTRO serán:
=SORT(FILTER(B5:C14, C5:C14>=LARGE(C5:C14, 5)), 2,-1) ➤ Prema Intro & obterás os 5 mellores CGPA xunto cos nomes dos estudantes á vez. Nin sequera tes que usar Fill Handle aquí para obter o resto dos valores xa que a propia fórmula está a facer todos os cálculos por ti.
Entón, o que está a pasar aquí é o A función FILTRO coa función LARGE dentro extrae todos os valores máis grandes do Intervalo de celas: C5:C14. A función ORDENAR entón mostra todos os valores ou CGPA en orde descendente xunto cos nomes da matriz de B5:C14.
Ler máis: Como atopar o valor máis baixo nunha columna de Excel (6 xeitos)
2.4 Buscar nomes principais & Valores con duplicados mediante a fusión de INDEX, ORDEN & SEQUENCE Functions Together
Esta é outra excelente opción & case semellante ao anterior. Usaremos INDEX, ORDEN & SEQUENCE funciona conxuntamente aquí.
📌 Pasos:
➤ Seleccione Cela F7 &escriba:
=INDEX(SORT(B5:C14,2,-1),SEQUENCE(5),{1,2}) ➤ Prema Intro & xa estás feito. Recibirás os 5 primeiros CGPA xunto cos nomes de inmediato.
O concepto é demasiado sinxelo aquí. A función ORDENAR mostra todos os CGPA en orde descendente pero a función SEQUENCE dille que escolla só os 5 primeiros. Despois a función INDEX mostra os resultados finais con nomes e amp; CGPA nunha matriz.
Ler máis: Como atopar a última aparición dun valor nunha columna en Excel (5 métodos)
Palabras de conclusión
Espero que todos estes métodos para atopar os 5 principais valores e nomes che soliciten agora que os apliques nas túas tarefas habituais de Excel. Se tes algunha dúbida ou comentario, fágame saber a través dos teus comentarios. Ou pode consultar os nosos outros artigos interesantes relacionados coas funcións de Excel neste sitio web.
