Inhaltsverzeichnis
Microsoft Excel bietet zahlreiche Möglichkeiten, die Top-5-Werte oder Namen oder beides aus einer Vielzahl von Daten zu ermitteln. In diesem Artikel lernen Sie alle fruchtbaren Techniken kennen, um die Top-5-Werte sowie die Namen in Excel zu finden.
Der obige Screenshot ist ein Überblick über den Artikel, der den Datensatz & darstellt; ein Beispiel dafür, wie Sie die Top-5-Werte zusammen mit Namen aus einer Reihe von Daten extrahieren können. Sie werden mehr über den Datensatz zusammen mit allen geeigneten Funktionen in den folgenden Methoden in diesem Artikel erfahren.
Download Arbeitsbuch Praxis
Sie können die Excel-Arbeitsmappe herunterladen, die wir zur Vorbereitung dieses Artikels verwendet haben.
Top 5 Werte & Namen finden8 geeignete Methoden, um die 5 wichtigsten Werte und Namen in Excel ohne oder mit Duplikaten zu finden
1. die Top 5 Werte & Namen ohne Duplikate zu finden
Bei unserem ersten Kriterium geht es um die Werte, bei denen es keine Duplikate gibt.
1.1 Ermittlung der Top-5-Werte durch gemeinsame Verwendung der Funktionen LARGE & ROWS
Machen wir uns nun mit unserem Datensatz vertraut. Säule B steht für zufällige Namen von 10 Schülern und Säule C zeigt den Notendurchschnitt (CGPA) jedes Studenten eines Semesters, das er an seiner Universität abgeschlossen hat.
Jetzt werden wir die Top 5 CGPA nur mit Hilfe von LARGE zusammen mit REIHEN Funktionen: Die LARGE Funktion ermittelt den größten Wert aus einem Bereich von Zellen auf der Grundlage der durch den Parameter REIHEN In der nächsten Methode werden wir auch die Namen erhalten.
📌 Schritte:
➤ Auswählen Zelle E7 & Typ:
=LARGE($C$5:$C$14,ROWS($E$7:$E7)) ➤ Presse Eingabe & Sie erhalten den 1. höchsten CGPA unter allen von Säule C .
➤ Verwenden Sie nun Füllen Griff 4 weitere Felder auszufüllen, um den nächsthöheren CGPA zu erhalten.
Lesen Sie mehr: Top-10-Werte auf der Grundlage von Kriterien in Excel (sowohl einzelne als auch mehrere Kriterien)
1.2 Herausfiltern der Top 5 Namen durch Kombination von INDEX & MATCH Funktionen
Jetzt werden wir die Namen derjenigen herausfinden, die die besten 5 CGPAs erreicht haben. Wir müssen folgende Punkte berücksichtigen INDEX, MATCH, LARGE & ROWS Funktionen zusammen, hier in Säule F die 5 besten Werte aus Säule C müssen zunächst nach der vorhergehenden Methode bestimmt werden. Dann müssen wir zu Säule E zur Extraktion der verwandten Namen auf der Grundlage ihrer CGPA.
📌 Schritte:
➤ In Zelle E7 lautet unsere notwendige Formel:
=INDEX($B$5:$B$14,MATCH(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,0)) ➤ Nach dem Drücken von Eingabe erhalten Sie den 1. Namen 'Jonas', der den höchsten Notendurchschnitt - 4,00 - erreicht hat.
➤ Verwenden Sie nun Füllen Griff um die nächsten 4 Namen in dieser Spalte zu erhalten & Sie sind fertig.
🔎 Wie funktioniert diese Formel?
➤ REIHEN gibt die Seriennummer für die LARGE Funktion.
➤ Die LARGE ermittelt den größten Wert aus der Reihe oder dem Bereich von Zellen, die anhand der Seriennummer ausgewählt wurden.
➤ MATCH Funktion sucht den größten Wert im Wertefeld & und gibt die Zeilennummer dieses Wertes zurück.
➤ INDEX Funktion zieht schließlich den Namen aus der Spalte "Namen" auf der Grundlage der Zeilennummer, die durch die MATCH Funktion.
Lesen Sie mehr: Wie man den Wert einer Spalte in Excel findet (4 Methoden)
1.3 Extrahieren der 5 wichtigsten Namen mit der XLOOKUP-Funktion
Wenn Sie vermeiden möchten, dass die INDEX-MATCH Formel, dann können Sie sie durch die XLOOKUP sucht nach einem Bereich von Zellen oder einem Array & gibt dann Werte auf der Grundlage der ausgewählten Bedingungen aus der ausgewählten Spalte oder Zeile zurück.
📌 Schritte:
➤ In Zelle E7 , unsere verwandte Formel mit XLOOKUP um die Namen mit be zu finden:
=XLOOKUP(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,$B$5:$B$14) ➤ Presse Eingabe & verwenden Füllen Griff um die anderen 4 Namen zu erhalten.
Im 1. Argument der XLOOKUP Funktion wurde der größte Wert eingegeben. Das zweite Argument ist die Bereich der Zellen C5:C14 wo der größte Wert gesucht wird. 3. Argument ist ein weiterer Bereich von Zellen B5:B14 aus dem die bestimmten Daten oder Namen auf der Grundlage der Zeilennummer, die durch die ersten beiden Argumente gefunden wurde, extrahiert werden.
Lesen Sie mehr: Wert in Spalte nachschlagen und Wert einer anderen Spalte in Excel zurückgeben
1.4 Suche nach den Top 5 Namen & Werten unter mehreren Kriterien
Betrachten wir nun einen weiteren Datensatz, der mehrere Kriterien umfasst. Wie Sie sehen, haben wir jetzt Namen & CGPA in Spalten B & D beziehungsweise. Säule C repräsentiert die Abteilungen der Studenten.
Wir werden zuerst die 5 besten CGPA des Fachbereichs Informatik ermitteln & die Ergebnisse werden in Säule H .
📌 Schritte:
➤ Um die 5 besten CGPAs zu ermitteln, wird die entsprechende Formel in Zelle H12 sein wird:
=LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12) ➤ Presse Eingabe verwenden Füllen Griff um die anderen 4 größten Werte zu erhalten & Sie sind fertig.
Hier, mit dem IF Funktion finden wir alle CGPAs der Studenten aus dem Fachbereich Informatik. Dann wird die LARGE Funktion extrahiert wie zuvor die Top 5 CGPA.
Nun werden wir die Namen ermitteln, die diese 5 besten CGPAs erreicht haben, und wir werden die INDEX-MATCH funktioniert hier.
📌 Schritte:
➤ In der Ausgabe Zelle G12 müssen wir tippen:
=INDEX($B$5:$B$23,MATCH(LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12), IF($C$5:$C$23=$G$9,$D$5:$D$23),0)) ➤ Presse Eingabe & verwenden Füllen Griff um die restlichen 4 Zellen auszufüllen. Sie erhalten dann alle Namen auf einmal.
Lesen Sie mehr: Wert in Spalte mit VBA in Excel finden (4 Wege)
2. die 5 wichtigsten Werte & Namen einschließlich Duplikate finden
Jetzt finden wir die Top-5-Werte sowie die Namen einschließlich der Duplikate. Wir haben hier einen etwas veränderten Datensatz.
2.1 Ermittlung der Top-5-Werte nur durch gemeinsame Verwendung der Funktionen Large & ROWS
Auf dem Bild unten ist dies der Fall, Säule B steht für die Namen von 5 Schülern und Spalten C bis J zeigen den CGPA jedes Semesters für diese Studenten. In der unteren Tabelle finden wir die Ausgabedaten.
Wir werden also zunächst die höchsten 5 CGPA für Andrew unter allen CGPA aus 8 Semestern herausfinden.
📌 Schritte:
➤ Auswählen Zelle C13 & Typ:
=LARGE($C6:$N6,COLUMNS($C:C)) ➤ Presse Eingabe & verwenden Füllen Griff um die nächsten 4 Zellen der Zeile für Andrew zu füllen.
Wie Sie sehen, haben Sie den Wert 4,00 zweimal als Ausgabe, da Andrews Notendurchschnitt in zwei Semestern 4,00 war. LARGE Funktion lässt bei der Suche nach den größten Werten aus dem Datenbereich oder den Zellen keine doppelten Werte aus.
Um nun ähnliche Ergebnisse für die anderen 4 Schüler zu erhalten, müssen wir die Bereich der Zellen - C13:G13 In der rechten unteren Ecke der ausgewählten Zellen finden Sie dann das Symbol Füllen Griff Ziehen Sie nun mit dieser Option nach unten in die ausgewählte Zeile für Harry & das war's. Sie erhalten nun alle Top 5 CGPA für alle Schüler auf einmal.
Lesen Sie mehr: Wie man den höchsten Wert in einer Excel-Spalte findet (4 Methoden)
2.2 Herausfiltern der Top 5 Namen mit Duplikaten durch Kombination von INDEX, MATCH & COUNTIF Funktionen
Nun werden wir die Namen der 5 besten Schüler mit ihrem CGPA herausfinden, wobei es doppelte CGPAs geben kann. Wie Sie in unserem geänderten Datensatz sehen, haben Sam und Mike beide einen ähnlichen CGPA - 3,94. Aber wir wollen die 5 besten Namen herausfinden, einschließlich dieser beiden Namen, die auch ähnliche CGPAs haben, mit Excel-Funktionen.
📌 Schritte:
➤ Auswählen Zelle F7 & Typ:
=INDEX($B$5:$B$14, MATCH(1, ($C$5:$C$14=LARGE($C$5:$C$14, $E7))*(COUNTIF(F$6:F6, $B$5:$B$14)=0), 0)) ➤ Presse Eingabe verwenden Füllen Griff um die anderen 4 Namen zu erhalten & Sie sind fertig. Sie haben gerade beide Namen - Sam & Mike, die einen ähnlichen CGPA haben.
🔎 Wie funktioniert diese Formel?
➤ Hier im Inneren der MATCH Funktion werden zwei logische Funktionen dargestellt, die miteinander multipliziert werden. Diese kombinierten logischen Funktionen suchen nach den 5 besten CGPA aus Säule C & wird die Zahl 1 für die ersten 5 & 0 für die restlichen Werte zugewiesen.
➤ MATCH Funktion sucht dann nur nach 1 aus den zuvor gefundenen Ergebnissen & gibt mit den Zeilennummern für alle Treffer zurück.
➤ INDEX Funktion schließlich zeigt die Namen seriell an, basierend auf den Zeilennummern, die durch alle MATCH Funktionen in Säule F .
Lesen Sie mehr: So finden Sie das erste Vorkommen eines Wertes in einer Spalte in Excel (5 Wege)
2.3 Extrahieren der Top-5-Namen mit Duplikaten durch Einbindung der Funktionen SORT & FILTER
Durch die Verwendung von SORT & FILTER Funktionen können Sie die Top 5 Namen zusammen mit den Werten leichter finden. Sie müssen hier nicht mehr die Top 5 Werte extrahieren, bevor Sie die Namen herausfinden.
📌 Schritte:
➤ In Zelle F7 , unsere verwandte Formel mit SORT & FILTER Funktionen sein wird:
=SORT(FILTER(B5:C14, C5:C14>=LARGE(C5:C14, 5)), 2,-1) ➤ Presse Eingabe & Sie erhalten die besten 5 CGPAs zusammen mit den Namen der Schüler auf einmal. Sie müssen hier nicht einmal Fill Handle verwenden, um die restlichen Werte zu erhalten, da die Formel selbst alle Berechnungen für Sie durchführt.
Was hier also passiert, ist die FILTER Funktion mit der LARGE Funktion innerhalb extrahiert alle größten Werte aus der Bereich der Zellen - C5:C14. Die SORT Funktion zeigt dann alle Werte oder CGPA in absteigender Reihenfolge zusammen mit den Namen aus dem Array von B5:C14.
Lesen Sie mehr: Wie man den niedrigsten Wert in einer Excel-Spalte findet (6 Wege)
2.4 Suche nach Top-Namen und -Werten mit Duplikaten durch Kombination von INDEX-, SORT- und SEQUENCE-Funktionen
Dies ist eine weitere großartige Option & fast ähnlich wie die vorherige. Wir verwenden INDEX, SORT & SEQUENCE funktioniert hier zusammen.
📌 Schritte:
➤ Auswählen Zelle F7 & Typ:
=INDEX(SORT(B5:C14,2,-1),SEQUENCE(5),{1,2}) ➤ Presse Eingabe & Sie sind fertig. Sie erhalten die Top 5 CGPA zusammen mit den Namen sofort.
Das Konzept ist hier zu einfach: Die SORT Funktion zeigt alle CGPAs in absteigender Reihenfolge an, aber die SEQUENCE Funktion nur die ersten 5 auswählen. Dann wird die INDEX Funktion zeigt die Endergebnisse mit Namen & CGPA in einem Array an.
Lesen Sie mehr: Wie man das letzte Auftreten eines Wertes in einer Spalte in Excel findet (5 Methoden)
Abschließende Worte
Ich hoffe, dass all diese Methoden, um die Top 5 Werte und Namen zu finden, Sie nun dazu veranlassen werden, sie in Ihren regulären Excel-Aufgaben anzuwenden. Wenn Sie Fragen oder Feedback haben, lassen Sie es mich bitte in den Kommentaren wissen. Oder Sie können sich unsere anderen interessanten Artikel zu Excel-Funktionen auf dieser Website ansehen.
