Оглавление
Microsoft Excel предлагает множество способов определения 5 лучших значений, имен или и того, и другого из огромного количества данных. В этой статье вы узнаете все плодотворные методы поиска 5 лучших значений, а также имен в Excel.
Приведенный выше скриншот - это обзор статьи, в которой представлен набор данных & пример того, как можно извлечь 5 лучших значений вместе с именами из ряда данных. Вы сможете узнать больше о наборе данных вместе со всеми подходящими функциями в следующих методах в этой статье.
Скачать Практическое пособие
Вы можете скачать рабочую книгу Excel, которую мы использовали для подготовки этой статьи.
Найти 5 лучших ценностей и имен8 подходящих способов найти 5 лучших значений и имен в Excel без дубликатов или с дубликатами
1. Поиск 5 лучших значений и имен без дубликатов
В нашем первом критерии мы будем иметь дело со значениями, в которых нет дубликатов.
1.1 Получение 5 лучших значений путем совместного использования функций LARGE & ROWS
Давайте теперь познакомимся с нашим набором данных. Колонка B представляет случайные имена 10 студентов и Колонка C показывает CGPA каждого студента выпускного семестра в своем университете.
Теперь мы узнаем 5 лучших CGPA только с помощью БОЛЬШОЙ вместе с РЯДЫ функции. БОЛЬШОЙ Функция найдет наибольшее значение из диапазона ячеек на основе порядкового номера, определенного в функции РЯДЫ функции. Имена мы также получим в следующем методе.
📌 Шаги:
➤ Выберите Клетка E7 & тип:
=LARGE($C$5:$C$14,ROWS($E$7:$E7)) ➤ Нажмите Войти & вы получите 1-ое место в рейтинге самых высоких показателей CGPA среди всех из Колонка C .
➤ Теперь используйте Наполнительная рукоятка заполнить еще 4 ячейки, чтобы получить следующий наибольший 4 CGPA.
Читать далее: Топ-10 значений на основе критериев в Excel (как по одному, так и по нескольким критериям)
1.2 Вытаскивание 5 лучших имен путем комбинирования функций INDEX & MATCH
Теперь мы узнаем имена тех, кто получил 5 лучших CGPA. Мы должны включить INDEX, MATCH, LARGE & ROWS функции вместе. Здесь, в Колонка F 5 лучших значений из Колонка C должны быть определены сначала, следуя предыдущему методу. Затем мы должны перейти к Колонка E для извлечения связанных имен на основе их CGPA.
📌 Шаги:
➤ В Клетка E7 , наша необходимая формула будет:
=INDEX($B$5:$B$14,MATCH(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,0)) ➤ После нажатия Войти Вы получите 1-е имя "Джонас", который получил наивысший CGPA - 4.00.
➤ Теперь используйте Наполнительная рукоятка чтобы получить следующие 4 имени в этой колонке & вы закончили.
🔎 Как работает эта формула?
➤ РЯДЫ функция вводит серийный номер для БОЛЬШОЙ функция.
➤ The БОЛЬШОЙ Функция находит наибольшее значение из массива или диапазона ячеек, выбранных на основе порядкового номера.
➤ МАТЧ функция ищет полученное наибольшее значение в массиве значений & возвращается с номером строки этого значения.
➤ ИНДЕКС Функция, наконец, извлекает имя из столбца Имена на основе номера строки, найденного функцией МАТЧ функция.
Читать далее: Как найти значение в столбце в Excel (4 метода)
1.3 Извлечение 5 лучших имен с помощью функции XLOOKUP
Если вы хотите избежать INDEX-MATCH формулу, то вы можете заменить ее на XLOOKUP Функция ищет диапазон ячеек или массив & затем возвращает значения на основе выбранных условий из выбранного столбца или строки.
📌 Шаги:
➤ В Клетка E7 , наша связанная формула с XLOOKUP чтобы найти имена с be:
=XLOOKUP(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,$B$5:$B$14) ➤ Нажмите Войти & использовать Наполнительная рукоятка чтобы получить остальные 4 имени.
В 1-м аргументе XLOOKUP функции, было введено наибольшее значение. 2-й аргумент - это Диапазон ячеек C5:C14 где будет искаться выбранное наибольшее значение. И 3-й аргумент - это другой диапазон ячеек B5:B14 откуда будут извлечены конкретные данные или имя на основе номера строки, найденного по первым двум аргументам.
Читать далее: Поиск значения в столбце и возврат значения другого столбца в Excel
1.4 Поиск 5 лучших имен и значений по нескольким критериям
Давайте теперь подумаем о другом наборе данных, который включает в себя несколько критериев. Если вы заметили, у нас есть имена & CGPA в Колонки B & D соответственно. Колонка C представляет факультеты студентов.
Сначала мы узнаем 5 лучших CGPA с факультета компьютерных наук & выходные результаты будут получены в Колонка H .
📌 Шаги:
➤ Чтобы найти 5 лучших CGPA, соответствующая формула в Ячейка H12 будет:
=LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12) ➤ Нажмите Войти , используйте Наполнительная рукоятка чтобы получить остальные 4 наибольших значения & готово.
Здесь, с ЕСЛИ функция, мы выясняем все CGPA студентов только факультета компьютерных наук. затем БОЛЬШОЙ функция, как и раньше, извлекает 5 лучших CGPA.
Теперь определим имена, которые получили эти 5 лучших CGPA, и используем INDEX-MATCH функции здесь.
📌 Шаги:
➤ На выходе Ячейка G12 мы должны напечатать:
=INDEX($B$5:$B$23,MATCH(LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12), IF($C$5:$C$23=$G$9,$D$5:$D$23),0)) ➤ Нажмите Войти & использовать Наполнительная рукоятка заполните оставшиеся 4 ячейки. Вы получите все имена сразу.
Читать далее: Как найти значение в столбце с помощью VBA в Excel (4 способа)
2. Поиск 5 лучших значений & имен, включая дубликаты
Теперь мы найдем 5 лучших значений, а также имена, включая дубликаты. У нас будет немного измененный набор данных.
2.1 Получение 5 лучших значений только при совместном использовании функций Large & ROWS
Так, на рисунке ниже, Колонка B представляет имена 5 студентов и Колонки C - J показывают CGPA каждого семестра для этих студентов. В нижней таблице мы найдем выходные данные.
Итак, сначала мы выясним 5 самых высоких CGPA для Андрея среди всех CGPA из 8 семестров.
📌 Шаги:
➤ Выберите Ячейка C13 & тип:
=LARGE($C6:$N6,COLUMNS($C:C)) ➤ Нажмите Войти & использовать Наполнительная рукоятка чтобы заполнить следующие 4 ячейки в строке для Эндрю.
Если вы заметили, вы дважды получили значение 4.00 в качестве вывода, так как за два семестра средний балл Эндрю был 4.00. Таким образом, БОЛЬШОЙ функция не опускает дублирующиеся значения при поиске наибольших значений из диапазона данных или ячеек.
Теперь, чтобы получить аналогичные результаты для остальных 4 студентов, мы должны выбрать Диапазон ячеек - C13:G13 сначала. Затем в правом нижнем углу выделенных ячеек вы найдете надпись Наполнительная рукоятка Теперь используйте эту опцию, чтобы перетащить вниз к выбранной строке для Гарри & вы закончили. Вы получите все 5 лучших CGPA для всех студентов сразу.
Читать далее: Как найти наибольшее значение в столбце Excel (4 метода)
2.2 Извлечение 5 лучших имен с дубликатами путем комбинирования функций INDEX, MATCH и COUNTIF
Теперь мы выясним имена 5 лучших студентов с их CGPA, где могут существовать дубликаты CGPA. Если вы заметили в нашем измененном наборе данных, Сэм и Майк имеют одинаковые CGPA - 3,94. Но мы хотим выяснить 5 лучших имен, включая эти два имени, которые также получили одинаковые CGPA с помощью функций Excel.
📌 Шаги:
➤ Выберите Ячейка F7 & тип:
=INDEX($B$5:$B$14, MATCH(1, ($C$5:$C$14=LARGE($C$5:$C$14, $E7))*(COUNTIF(F$6:F6, $B$5:$B$14)=0), 0)) ➤ Нажмите Войти , используйте Наполнительная рукоятка чтобы получить остальные 4 имени & вы закончили. Вы только что получили оба имени - Сэм и Майк, которые получили одинаковые CGPA.
🔎 Как работает эта формула?
➤ Здесь внутри МАТЧ функция, представлены две логические функции, которые умножаются друг на друга. Эти комбинированные логические функции будут искать 5 лучших CGPA из Колонка C & присвоит число 1 для 5 лучших & 0 для остальных значений.
➤ МАТЧ функция ищет только 1 из предыдущих найденных результатов & возвращается с номерами строк для всех совпадений.
➤ ИНДЕКС функция окончательно отображает имена последовательно, основываясь на номерах строк, найденных через все МАТЧ функции в Колонка F .
Читать далее: Как найти первое вхождение значения в столбец в Excel (5 способов)
2.3 Извлечение 5 лучших имен с дубликатами с помощью функций SORT & FILTER
С помощью сортировка и фильтрация функции, вы можете легче найти 5 лучших имен вместе со значениями. Вам больше не придется извлекать 5 лучших значений, прежде чем узнать имена.
📌 Шаги:
➤ В Ячейка F7 , наша связанная формула с сортировка и фильтрация функции будут:
=SORT(FILTER(B5:C14, C5:C14>=LARGE(C5:C14, 5)), 2,-1) ➤ Нажмите Войти & вы сразу получите 5 лучших CGPA вместе с именами студентов. Вам даже не придется использовать Fill Handle здесь, чтобы получить остальные значения, так как формула сама сделает все вычисления за вас.
Итак, что здесь происходит - ФИЛЬТР функция с БОЛЬШОЙ функция внутри извлекает все наибольшие значения из Диапазон клеток - C5:C14. Сайт СОРТ Затем функция отображает все значения или CGPA в порядке убывания вместе с именами из массива B5:C14.
Читать далее: Как найти наименьшее значение в столбце Excel (6 способов)
2.4 Поиск верхних имен & значений с дубликатами путем объединения функций INDEX, SORT & SEQUENCE вместе
Это еще один отличный вариант & почти такой же, как и предыдущий. Мы будем использовать INDEX, SORT & SEQUENCE функции вместе здесь.
📌 Шаги:
➤ Выберите Ячейка F7 & тип:
=INDEX(SORT(B5:C14,2,-1),SEQUENCE(5),{1,2}) ➤ Нажмите Войти & все готово. Вы получите 5 лучших CGPA вместе с именами сразу же.
Концепция здесь слишком проста. СОРТ функция показывает все CGPA в порядке убывания, но функция SEQUENCE функция говорит ему выбрать только первые 5. Затем функция ИНДЕКС Функция показывает окончательные результаты с именами & CGPA в массиве.
Читать далее: Как найти последнее вхождение значения в столбец в Excel (5 методов)
Заключительные слова
Я надеюсь, что все эти методы поиска 5 лучших значений и имен подскажут вам, как применять их в вашей обычной работе в Excel. Если у вас есть вопросы или отзывы, пожалуйста, дайте мне знать в комментариях. Или вы можете ознакомиться с другими интересными статьями, связанными с функциями Excel, на этом сайте.
