Mục lục
Microsoft Excel đã cung cấp nhiều cách để xác định 5 giá trị hoặc tên hàng đầu hoặc cả hai từ một dải dữ liệu khổng lồ. Trong bài viết này, bạn sẽ tìm hiểu tất cả các kỹ thuật hiệu quả để tìm 5 giá trị hàng đầu cũng như tên trong Excel.
Ảnh chụp màn hình ở trên là tổng quan về bài viết đại diện cho tập dữ liệu & một ví dụ về cách bạn có thể trích xuất 5 giá trị hàng đầu cùng với tên từ một dải dữ liệu. Bạn sẽ tìm hiểu thêm về tập dữ liệu cùng với tất cả các hàm phù hợp theo các phương pháp sau trong bài viết này.
Tải xuống Sổ làm việc thực hành
Bạn có thể tải xuống sổ làm việc Excel mà chúng tôi đã sử dụng để chuẩn bị cho bài viết này.
Tìm 5 giá trị & Tên
8 cách phù hợp để tìm 5 giá trị và tên hàng đầu trong Excel mà không có hoặc có trùng lặp
1. Tìm 5 Giá trị & Tên không trùng lặp
Trong tiêu chí đầu tiên, chúng tôi sẽ xử lý các giá trị không trùng lặp.
1.1 Lấy 5 giá trị hàng đầu bằng cách sử dụng LARGE & Chức năng ROWS cùng nhau
Bây giờ chúng ta hãy làm quen với tập dữ liệu của chúng ta. Cột B đại diện cho tên ngẫu nhiên của 10 sinh viên và Cột C hiển thị CGPA của mỗi sinh viên trong kỳ cuối cùng tại trường đại học của họ.
Bây giờ chúng ta sẽ tìm ra 5 CGPA hàng đầu chỉ bằng cách sử dụng LARGE cùng với các hàm ROWS . Hàm LARGE sẽ tìm ra giá trị lớn nhấttừ một dải ô dựa trên số sê-ri được xác định bởi các hàm ROWS . Chúng ta cũng sẽ lấy tên trong phương pháp tiếp theo.
📌 Các bước:
➤ Chọn Ô E7 & gõ:
=LARGE($C$5:$C$14,ROWS($E$7:$E7)) ➤ Nhấn Enter & bạn sẽ nhận được CGPA cao thứ nhất trong số tất cả từ Cột C .
➤ Bây giờ, hãy sử dụng Fill Handle để điền thêm 4 ô để nhận được 4 CGPA lớn nhất tiếp theo .
Đọc thêm: 10 giá trị hàng đầu dựa trên tiêu chí trong Excel (Cả tiêu chí đơn và nhiều tiêu chí)
1.2 Tìm ra 5 cái tên hàng đầu bằng cách kết hợp INDEX & Chức năng MATCH
Bây giờ chúng ta sẽ tìm ra những cái tên đạt top 5 CGPAs. Chúng ta phải kết hợp INDEX, MATCH, LARGE & ROWS hoạt động cùng nhau. Ở đây, trong Cột F , 5 giá trị hàng đầu từ Cột C phải được xác định trước bằng cách làm theo phương pháp trước đó. Sau đó, chúng ta phải di chuyển đến Cột E để trích xuất các tên liên quan dựa trên CGPA của chúng.
📌 Các bước:
➤ Trong Ô E7 , công thức cần thiết của chúng ta sẽ là:
=INDEX($B$5:$B$14,MATCH(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,0)) ➤ Sau khi nhấn Enter , bạn ' sẽ lấy tên đầu tiên là 'Jonas', người có CGPA cao nhất- 4,00.
➤ Bây giờ, hãy sử dụng Fill Handle để lấy 4 tên tiếp theo trong cột đó & bạn đã hoàn tất.
🔎 Công thức này hoạt động như thế nào?
➤ Hàm ROWS nhập hàm số sê-ri cho chức năng LARGE .
➤ LARGE hàm tìm giá trị lớn nhất từ mảng hoặc dải ô được chọn dựa trên số sê-ri.
➤ Hàm MATCH tìm giá trị lớn nhất thu được trong mảng giá trị & trả về với số hàng của giá trị đó.
➤ Hàm INDEX cuối cùng lấy tên từ cột Tên dựa trên số hàng mà hàm MATCH tìm thấy .
Đọc thêm: Cách tìm giá trị trong cột trong Excel (4 phương pháp)
1.3 Trích xuất 5 tên hàng đầu theo Sử dụng Hàm XLOOKUP
Nếu bạn muốn tránh công thức INDEX-MATCH thì bạn có thể thay thế nó bằng hàm XLOOKUP tìm kiếm một dải ô hoặc mảng & sau đó trả về các giá trị dựa trên các điều kiện đã chọn từ cột hoặc hàng đã chọn.
📌 Các bước:
➤ Trong Ô E7 , công thức liên quan của chúng tôi với XLOOKUP để tìm các tên có:
=XLOOKUP(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,$B$5:$B$14) ➤ Nhấn Enter & ; sử dụng Fill Handle để lấy 4 tên còn lại.
Trong đối số đầu tiên của hàm XLOOKUP , giá trị lớn nhất có được nhập vào. Đối số thứ 2 là Phạm vi ô C5:C14 nơi giá trị lớn nhất đã chọn sẽ được tìm kiếm. Và đối số thứ 3 là một dải ô khác B5:B14 mà từ đó dữ liệu hoặc tên cụ thể sẽ được trích xuất dựa trên số hàng mà hai đối số đầu tiên tìm thấy.
Đọc Thêm: Giá trị tra cứutrong cột và giá trị trả về của một cột khác trong Excel
1.4 Tìm 5 tên & Các giá trị trong Nhiều tiêu chí
Bây giờ, hãy nghĩ về một tập dữ liệu khác bao gồm nhiều tiêu chí. Nếu bạn để ý, chúng ta hiện có tên & CGPA trong Cột B & D tương ứng. Cột C đại diện cho các khoa của sinh viên.
Trước tiên, chúng ta sẽ tìm hiểu 5 CGPA hàng đầu từ khoa Khoa học Máy tính & kết quả đầu ra sẽ đạt được trong Cột H .
📌 Các bước:
➤ Tìm 5 CGPAs hàng đầu , công thức liên quan trong Ô H12 sẽ là:
=LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12) ➤ Nhấn Enter , sử dụng Fill Xử lý để nhận 4 giá trị lớn nhất khác & bạn đã hoàn tất.
Ở đây, với chức năng IF , chúng tôi chỉ tìm ra tất cả CGPA của sinh viên khoa Khoa học máy tính . Sau đó, hàm LARGE trích xuất 5 CGPA hàng đầu như trước đây.
Bây giờ, chúng ta sẽ xác định những cái tên đã nhận được 5 CGPA hàng đầu này và chúng ta sẽ sử dụng INDEX-MATCH tại đây.
📌 Các bước:
➤ Trong đầu ra Ô G12 , chúng ta phải nhập:
=INDEX($B$5:$B$23,MATCH(LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12), IF($C$5:$C$23=$G$9,$D$5:$D$23),0)) ➤ Nhấn Enter & sử dụng Fill Handle để điền vào phần còn lại của 4 ô. Bạn sẽ nhận được tất cả các tên cùng một lúc.
Đọc thêm: Cách tìm giá trị trong cột bằng VBA trong Excel (4 cách )
2. Tìm 5 Giá trị & tênBao gồm các giá trị trùng lặp
Bây giờ chúng ta sẽ tìm thấy 5 giá trị hàng đầu cũng như tên bao gồm các giá trị trùng lặp. Chúng ta sẽ có một chút tập dữ liệu được sửa đổi ở đây.
2.1 Nhận 5 giá trị hàng đầu chỉ bằng cách sử dụng Lớn & ROWS Chức năng cùng nhau
Vì vậy, trong hình bên dưới, Cột B đại diện cho tên của 5 sinh viên và Cột C đến J đang hiển thị CGPA của mỗi người học kỳ cho những sinh viên đó. Trong bảng dưới cùng, chúng tôi sẽ tìm ra dữ liệu đầu ra.
Vì vậy, đầu tiên, chúng tôi sẽ tìm ra 5 CGPA cao nhất cho Andrew trong số tất cả các CGPA từ 8 học kỳ.
📌 Các bước:
➤ Chọn Ô C13 & gõ:
=LARGE($C6:$N6,COLUMNS($C:C)) ➤ Nhấn Enter & sử dụng Fill Handle để điền vào 4 ô tiếp theo dọc theo hàng cho Andrew.
Nếu để ý, bạn đã nhận được giá trị 4,00 gấp đôi giá trị đầu ra vì CGPA của Andrew là 4,00 trong hai nhiệm kỳ. Vì vậy, hàm LARGE không bỏ qua các giá trị trùng lặp trong khi tìm kiếm giá trị lớn nhất từ phạm vi dữ liệu hoặc ô.
Bây giờ, để có kết quả tương tự cho 4 sinh viên khác, chúng tôi phải chọn Phạm vi ô- C13:G13 trước. Sau đó, ở góc dưới bên phải của các ô đã chọn, bạn sẽ tìm thấy tùy chọn Fill Handle . Bây giờ, hãy sử dụng tùy chọn đó để kéo xuống hàng đã chọn cho Harry & bạn đã hoàn tất. Bạn sẽ nhận được tất cả 5 điểm CGPA hàng đầu cho tất cả học sinh cùng một lúc.
Đọc thêm: Cách đạt điểm cao nhấtGiá trị trong cột Excel (4 phương pháp)
2.2 Lấy ra 5 tên hàng đầu có tên trùng lặp bằng cách kết hợp INDEX, MATCH & Hàm COUNTIF
Bây giờ, chúng ta sẽ tìm ra tên của 5 sinh viên hàng đầu có CGPA của họ, nơi có thể tồn tại CGPA trùng lặp. Nếu bạn nhận thấy trong tập dữ liệu đã sửa đổi của chúng tôi, Sam & Cả Mike đều có CGPA- 3,94 tương tự nhau. Nhưng chúng tôi muốn tìm ra 5 cái tên hàng đầu bao gồm cả hai cái tên có CGPA tương tự cũng như các hàm Excel.
📌 Các bước :
➤ Chọn Ô F7 & gõ:
=INDEX($B$5:$B$14, MATCH(1, ($C$5:$C$14=LARGE($C$5:$C$14, $E7))*(COUNTIF(F$6:F6, $B$5:$B$14)=0), 0)) ➤ Nhấn Enter , sử dụng Fill Handle để lấy 4 tên còn lại & bạn đã hoàn tất. Bạn vừa có cả hai tên- Sam & Mike, người có CGPA tương tự.
🔎 Công thức này hoạt động như thế nào?
➤ Ở đây bên trong MATCH chức năng, hai chức năng logic được trình bày được nhân với nhau. Các hàm logic kết hợp này sẽ tìm kiếm 5 CGPA hàng đầu từ Cột C & sẽ chỉ định số 1 cho top 5 & 0 cho các giá trị còn lại.
➤ Hàm MATCH sau đó chỉ tìm kiếm 1 từ các kết quả tìm thấy trước đó & trả về với các số hàng cho tất cả các kết quả phù hợp.
➤ Hàm INDEX cuối cùng cũng hiển thị các tên theo thứ tự dựa trên các số hàng đó được tìm thấy thông qua tất cả các hàm MATCH trong Column F .
Đọc thêm: Cách tìm sự xuất hiện đầu tiên của một giá trị trong một cột trongExcel (5 cách)
2.3 Trích xuất 5 tên hàng đầu có tên trùng lặp bằng cách kết hợp SORT & Chức năng LỌC
Bằng cách sử dụng SORT & FILTER , bạn có thể tìm thấy 5 tên hàng đầu cùng với các giá trị dễ dàng hơn. Bạn sẽ không phải trích xuất 5 giá trị hàng đầu ở đây nữa trước khi tìm ra tên.
📌 Các bước:
➤ Trong Ô F7 , công thức liên quan của chúng tôi với SORT & FILTER chức năng sẽ là:
=SORT(FILTER(B5:C14, C5:C14>=LARGE(C5:C14, 5)), 2,-1) ➤ Nhấn Enter & bạn sẽ nhận được 5 CGPA hàng đầu cùng với tên của các sinh viên cùng một lúc. Bạn thậm chí không cần phải sử dụng Fill Handle ở đây để lấy các giá trị còn lại vì chính công thức đang thực hiện tất cả các phép tính cho bạn.
Vậy điều đang xảy ra ở đây là Hàm FILTER với hàm LARGE bên trong trích xuất tất cả các giá trị lớn nhất từ Dải ô- C5:C14. Sau đó, hàm SORT hiển thị tất cả các giá trị hoặc CGPA theo thứ tự giảm dần cùng với tên từ mảng B5:C14.
Đọc thêm: Cách tìm giá trị thấp nhất trong một cột Excel (6 cách)
2.4 Tìm tên hàng đầu & Các giá trị có Bản sao bằng cách Hợp nhất INDEX, SORT & SEQUENCE Chức năng cùng nhau
Đây là một tùy chọn tuyệt vời khác & gần giống với cái trước. Chúng tôi sẽ sử dụng INDEX, SORT & SEQUENCE hoạt động cùng nhau tại đây.
📌 Các bước:
➤ Chọn Ô F7 &gõ:
=INDEX(SORT(B5:C14,2,-1),SEQUENCE(5),{1,2}) ➤ Nhấn Enter & bạn đã hoàn tất. Bạn sẽ nhận được 5 CGPA hàng đầu cùng với tên ngay lập tức.
Khái niệm này quá đơn giản ở đây. Hàm SORT hiển thị tất cả CGPA theo thứ tự giảm dần nhưng hàm SEQUENCE yêu cầu nó chỉ chọn 5 đầu tiên. Sau đó, hàm INDEX hiển thị kết quả cuối cùng với tên & CGPA trong một mảng.
Đọc thêm: Cách tìm lần xuất hiện cuối cùng của một giá trị trong một cột trong Excel (5 phương pháp)
Từ kết luận
Tôi hy vọng tất cả các phương pháp tìm 5 giá trị và tên hàng đầu này giờ đây sẽ nhắc bạn áp dụng chúng trong các công việc Excel thông thường của mình. Nếu bạn có bất kỳ câu hỏi hoặc phản hồi nào, vui lòng cho tôi biết thông qua nhận xét của bạn. Hoặc bạn có thể xem các bài viết thú vị khác của chúng tôi liên quan đến các hàm Excel trên trang web này.
