Isi kandungan
Microsoft Excel telah menyediakan pelbagai cara untuk menentukan 5 nilai atau nama teratas atau kedua-duanya daripada julat data yang besar. Dalam artikel ini, anda akan dapat mempelajari semua teknik yang bermanfaat untuk mencari 5 nilai teratas serta nama dalam Excel.
Tangkapan skrin di atas ialah gambaran keseluruhan artikel yang mewakili set data & contoh bagaimana anda boleh mengekstrak 5 nilai teratas bersama-sama dengan nama daripada julat data. Anda akan dapat mengetahui lebih lanjut tentang set data bersama-sama dengan semua fungsi yang sesuai dalam kaedah berikut dalam artikel ini.
Muat Turun Buku Kerja Amalan
Anda boleh memuat turun buku kerja Excel yang telah kami gunakan untuk menyediakan artikel ini.
Cari 5 Nilai Teratas & Nama
8 Cara yang Sesuai untuk Mencari 5 Nilai dan Nama Teratas dalam Excel tanpa atau dengan Pendua
1. Mencari 5 Nilai & Nama tanpa Pendua
Dalam kriteria pertama kami, kami akan menangani nilai yang tiada pendua berbohong.
1.1 Mendapatkan 5 Nilai Teratas dengan Menggunakan LARGE & ROWS Berfungsi Bersama
Mari kita perkenalkan set data kami sekarang. Lajur B mewakili nama rawak 10 pelajar dan Lajur C menunjukkan PNGK setiap pelajar penggal akhir di universiti mereka.
Kini kita akan mengetahui 5 PNGK teratas hanya dengan menggunakan BESAR bersama-sama dengan fungsi ROWS . Fungsi LARGE akan mengetahui nilai terbesardaripada julat sel berdasarkan nombor siri yang ditakrifkan oleh fungsi ROWS . Kami akan mendapat nama juga dalam kaedah seterusnya.
📌 Langkah:
➤ Pilih Sel E7 & taip:
=LARGE($C$5:$C$14,ROWS($E$7:$E7)) ➤ Tekan Enter & anda akan mendapat CGPA pertama tertinggi dalam kalangan kesemuanya daripada Lajur C .
➤ Sekarang gunakan Pengendalian Isi untuk mengisi 4 lagi sel untuk mendapatkan 4 PNGK terbesar seterusnya .
Baca Lagi: 10 Nilai Teratas Berdasarkan Kriteria dalam Excel (Kedua-dua Kriteria Tunggal dan Berbilang)
1.2 Menarik Keluar 5 Nama Teratas dengan Menggabungkan INDEX & Fungsi MATCH
Sekarang kita akan mengetahui nama-nama yang mendapat 5 PNGK terbaik. Kita perlu memasukkan INDEX, PADANAN, BESAR & ROWS berfungsi bersama. Di sini, dalam Lajur F , 5 nilai teratas daripada Lajur C perlu ditentukan terlebih dahulu dengan mengikuti kaedah sebelumnya. Kemudian kita perlu beralih ke Lajur E untuk mengekstrak nama yang berkaitan berdasarkan PNGK mereka.
📌 Langkah:
➤ Dalam Sel E7 , formula yang diperlukan kami ialah:
=INDEX($B$5:$B$14,MATCH(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,0)) ➤ Selepas menekan Enter , anda' Akan mendapat nama pertama 'Jonas' yang mendapat CGPA tertinggi- 4.00.
➤ Sekarang gunakan Pengendalian Isi untuk mendapatkan 4 nama seterusnya dalam lajur itu & anda sudah selesai.
🔎 Bagaimana Formula Ini Berfungsi?
➤ ROWS fungsi memasukkan nombor siri untuk fungsi LARGE .
➤ LARGE fungsi mengetahui nilai terbesar daripada tatasusunan atau julat sel yang dipilih berdasarkan nombor siri.
➤ MATCH fungsi mencari nilai terbesar yang diperoleh dalam tatasusunan nilai & kembali dengan nombor baris nilai tersebut.
➤ INDEX fungsi akhirnya mengeluarkan nama dari lajur Nama berdasarkan nombor baris yang ditemui oleh fungsi MATCH .
Baca Lagi: Cara Mencari Nilai dalam Lajur dalam Excel (4 Kaedah)
1.3 Mengekstrak 5 Nama Teratas dengan Menggunakan Fungsi XLOOKUP
Jika anda ingin mengelakkan formula INDEX-MATCH maka anda boleh menggantikannya dengan carian fungsi XLOOKUP untuk julat sel atau tatasusunan & kemudian mengembalikan nilai berdasarkan keadaan yang dipilih daripada lajur atau baris yang dipilih.
📌 Langkah:
➤ Dalam Sel E7 , formula berkaitan kami dengan XLOOKUP untuk mencari nama dengan be:
=XLOOKUP(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,$B$5:$B$14) ➤ Tekan Enter & ; gunakan Fill Handle untuk mendapatkan 4 nama lain.
Dalam argumen pertama fungsi XLOOKUP , nilai terbesar mempunyai telah dimasukkan. Argumen ke-2 ialah Julat Sel C5:C14 di mana nilai terbesar yang dipilih akan dicari. Dan argumen ke-3 ialah satu lagi julat sel B5:B14 dari mana data atau nama tertentu akan diekstrak berdasarkan nombor baris yang ditemui oleh dua argumen pertama.
Baca Lagi: Nilai Cariandalam Lajur dan Nilai Pulangan Lajur Lain dalam Excel
1.4 Mencari 5 Nama Terbaik & Nilai di bawah Berbilang Kriteria
Mari kita fikirkan set data lain sekarang yang terdiri daripada berbilang kriteria. Jika anda perasan, kami kini mempunyai nama & PNGK dalam Lajur B & D masing-masing. Lajur C mewakili jabatan pelajar.
Kami akan mengetahui terlebih dahulu 5 PNGK terbaik daripada jabatan Sains Komputer & hasil output akan dicapai dalam Lajur H .
📌 Langkah:
➤ Untuk mencari 5 PNGK teratas , formula yang berkaitan dalam Sel H12 ialah:
=LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12) ➤ Tekan Enter , gunakan Isi Kendalikan untuk mendapatkan 4 nilai terbesar yang lain & anda sudah selesai.
Di sini, dengan fungsi IF , kami mencari semua PNGK pelajar dari jabatan Sains Komputer sahaja . Kemudian fungsi LARGE mengekstrak 5 PNGK teratas seperti sebelum ini.
Sekarang, kami akan menentukan nama yang mendapat 5 PNGK teratas ini dan kami akan menggunakan INDEX-MATCH berfungsi di sini.
📌 Langkah:
➤ Dalam output Sel G12 , kita perlu menaip:
=INDEX($B$5:$B$23,MATCH(LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12), IF($C$5:$C$23=$G$9,$D$5:$D$23),0)) ➤ Tekan Enter & gunakan Fill Handle untuk mengisi baki 4 sel. Anda akan mendapat semua nama sekaligus.
Baca Lagi: Cara Mencari Nilai dalam Lajur Menggunakan VBA dalam Excel (4 Cara )
2. Mencari 5 Nilai & NamaTermasuk Pendua
Kini kami akan menemui 5 nilai teratas serta nama termasuk pendua. Kami akan mempunyai sedikit set data yang diubah suai di sini.
2.1 Mendapatkan 5 Nilai Teratas Hanya dengan Menggunakan & ROWS Berfungsi Bersama
Jadi, dalam gambar di bawah, Lajur B mewakili nama 5 pelajar dan Lajur C hingga J menunjukkan PNGK setiap semester untuk pelajar tersebut. Dalam jadual bawah, kami akan mengetahui data output.
Jadi, pada mulanya, kami akan mengetahui 5 PNGK tertinggi untuk Andrew antara semua PNGK daripada 8 semester.
📌 Langkah:
➤ Pilih Sel C13 & taip:
=LARGE($C6:$N6,COLUMNS($C:C)) ➤ Tekan Enter & gunakan Pengendali Isi untuk mengisi 4 sel seterusnya di sepanjang baris untuk Andrew.
Jika anda perasan, anda mendapat nilai 4.00 dua kali sebagai output sejak CGPA Andrew ialah 4.00 dalam dua penggal. Jadi, fungsi LARGE tidak menghilangkan nilai pendua semasa mencari yang terbesar daripada julat data atau sel.
Kini, untuk mendapatkan hasil yang serupa untuk 4 pelajar yang lain, kami perlu memilih Julat Sel- C13:G13 dahulu. Kemudian di sudut kanan bawah sel yang dipilih, anda akan menemui pilihan Fill Handle . Sekarang gunakan pilihan itu untuk menyeret ke bawah ke baris yang dipilih untuk Harry & anda sudah selesai. Anda akan mendapat kesemua 5 PNGK teratas untuk semua pelajar sekali gus.
Baca Lagi: Cara Mencari TertinggiNilai dalam Lajur Excel (4 Kaedah)
2.2 Menarik Keluar 5 Nama Teratas dengan Pendua dengan Menggabungkan INDEX, MATCH & Fungsi COUNTIF
Kini, kami akan mengetahui nama 5 pelajar terbaik dengan PNGK mereka di mana pendua PNGK boleh wujud. Jika anda perhatikan dalam set data kami yang diubah suai, Sam & Mike kedua-duanya mempunyai PNGK yang sama- 3.94. Tetapi kami ingin mengetahui 5 nama teratas termasuk dua nama yang mendapat PNGK serupa dengan fungsi Excel.
📌 Langkah :
➤ Pilih Sel F7 & taip:
=INDEX($B$5:$B$14, MATCH(1, ($C$5:$C$14=LARGE($C$5:$C$14, $E7))*(COUNTIF(F$6:F6, $B$5:$B$14)=0), 0)) ➤ Tekan Enter , gunakan Fill Handle untuk mendapatkan 4 nama lain & anda sudah selesai. Anda baru sahaja mendapat kedua-dua nama- Sam & Mike yang mendapat PNGK serupa.
🔎 Bagaimana Formula Ini Berfungsi?
➤ Di sini dalam PERLAWANAN fungsi, dua fungsi logik dibentangkan yang didarab antara satu sama lain. Fungsi logik gabungan ini akan mencari 5 PNGK teratas daripada Lajur C & akan memberikan nombor 1 untuk 5 & 0 untuk nilai yang selebihnya.
➤ MATCH fungsi kemudian mencari 1 sahaja daripada hasil sebelumnya yang ditemui & kembali dengan nombor baris untuk semua padanan.
➤ INDEX fungsi akhirnya menunjukkan nama secara bersiri berdasarkan nombor baris yang ditemui melalui semua fungsi MATCH dalam Lajur F .
Baca Lagi: Cara Mencari Kejadian Pertama Nilai dalam Lajur dalamExcel (5 Cara)
2.3 Mengekstrak 5 Nama Teratas dengan Pendua dengan Menggabungkan SORT & FILTER Fungsi
Dengan menggunakan SORT & FILTER , anda boleh mencari 5 nama teratas bersama-sama dengan nilai dengan lebih mudah. Anda tidak perlu mengekstrak 5 nilai teratas di sini lagi sebelum mengetahui nama.
📌 Langkah:
➤ Dalam Sel F7 , formula berkaitan kami dengan SORT & Fungsi FILTER ialah:
=SORT(FILTER(B5:C14, C5:C14>=LARGE(C5:C14, 5)), 2,-1) ➤ Tekan Enter & anda akan mendapat 5 PNGK terbaik berserta nama pelajar sekali gus. Anda malah tidak perlu menggunakan Fill Handle di sini untuk mendapatkan nilai selebihnya kerana formula itu sendiri melakukan semua pengiraan untuk anda.
Jadi apa yang berlaku di sini ialah FILTER fungsi dengan fungsi LARGE di dalam mengekstrak semua nilai terbesar daripada Julat Sel- C5:C14. Fungsi SORT kemudian menunjukkan semua nilai atau PNGK dalam tertib menurun bersama-sama dengan nama daripada tatasusunan B5:C14.
Baca Lagi: Cara Mencari Nilai Terendah dalam Lajur Excel (6 Cara)
2.4 Cari Nama Teratas & Nilai dengan Pendua dengan Menggabungkan INDEX, SORT & SEQUENCE Berfungsi Bersama
Ini adalah satu lagi pilihan hebat & hampir serupa dengan yang sebelumnya. Kami akan menggunakan INDEX, SORT & SEQUENCE berfungsi bersama di sini.
📌 Langkah:
➤ Pilih Sel F7 &taip:
=INDEX(SORT(B5:C14,2,-1),SEQUENCE(5),{1,2}) ➤ Tekan Enter & anda sudah selesai. Anda akan mendapat 5 PNGK teratas bersama-sama dengan nama serta-merta.
Konsepnya terlalu mudah di sini. Fungsi SORT menunjukkan semua PNGK dalam tertib menurun tetapi fungsi SEQUENCE memberitahunya untuk memilih hanya 5 yang pertama. Kemudian fungsi INDEX menunjukkan hasil akhir dengan nama & PNGK dalam tatasusunan.
Baca Lagi: Cara Mencari Kejadian Terakhir bagi Nilai dalam Lajur dalam Excel (5 Kaedah)
Perkataan Penutup
Saya berharap semua kaedah ini untuk mencari 5 nilai dan nama teratas kini akan menggesa anda untuk menerapkannya dalam tugas Excel biasa anda. Jika anda mempunyai sebarang soalan atau maklum balas, sila beritahu saya melalui ulasan anda. Atau anda boleh menyemak artikel menarik kami yang lain berkaitan dengan fungsi Excel di tapak web ini.
