Sadržaj
Microsoft Excel je pružio brojne načine za određivanje prvih 5 vrijednosti ili imena ili oboje iz ogromnog raspona podataka. U ovom članku ćete naučiti sve plodonosne tehnike za pronalaženje prvih 5 vrijednosti kao i imena u Excelu.
Snimak ekrana iznad je pregled članak koji predstavlja skup podataka & primjer kako možete izdvojiti prvih 5 vrijednosti zajedno s imenima iz niza podataka. Moći ćete naučiti više o skupu podataka zajedno sa svim odgovarajućim funkcijama u sljedećim metodama u ovom članku.
Preuzmite radnu svesku za vježbe
Možete preuzeti Excel radnu svesku koje smo koristili za pripremu ovog članka.
Pronađite top 5 vrijednosti & Imena
8 prikladnih načina za pronalaženje 5 najboljih vrijednosti i imena u Excelu bez ili sa duplikatima
1. Pronalaženje 5 najboljih vrijednosti & Imena bez duplikata
U našim prvim kriterijima bavit ćemo se vrijednostima u kojima nema duplikata.
1.1 Dobivanje najboljih 5 vrijednosti korištenjem LARGE & ROWS Funkcije zajedno
Hajde da se sada upoznamo s našim skupom podataka. Kolona B predstavlja nasumična imena 10 studenata, a Kolona C prikazuje CGPA svakog studenta završnog roka na njihovom univerzitetu.
Sada ćemo saznati prvih 5 CGPA samo korištenjem LARGE zajedno sa ROWS funkcijama. Funkcija LARGE će saznati najveću vrijednostiz raspona ćelija na osnovu serijskog broja definiranog funkcijama ROWS . Imena ćemo dobiti i u sljedećoj metodi.
📌 Koraci:
➤ Odaberite Ćelija E7 & tip:
=LARGE($C$5:$C$14,ROWS($E$7:$E7)) ➤ Pritisnite Enter & dobit ćete 1. najviši CGPA među svim iz kolone C .
➤ Sada koristite ručicu za popunjavanje da popunite još 4 ćelije kako biste dobili sljedeće najveće 4 CGPA .
Pročitajte više: Top 10 vrijednosti na osnovu kriterija u Excelu (pojedinačni i višestruki kriteriji)
1.2 Izvlačenje prvih 5 imena kombinacijom INDEX & Funkcije MATCH
Sada ćemo saznati imena koja su dobila 5 najboljih CGPA. Moramo uključiti INDEX, MATCH, LARGE & ROWS funkcionira zajedno. Ovdje, u koloni F , prvih 5 vrijednosti iz kolone C moraju se prvo odrediti slijedeći prethodni metod. Zatim moramo preći na Kolonu E za izdvajanje povezanih imena na osnovu njihovog CGPA.
📌 Koraci:
➤ U ćeliji E7 , naša potrebna formula će biti:
=INDEX($B$5:$B$14,MATCH(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,0)) ➤ Nakon što pritisnete Enter , vi ćete Dobit ću prvo ime 'Jonas' koji je dobio najviši CGPA- 4.00.
➤ Sada koristite Fill Handle da dobijete sljedeća 4 imena u toj koloni & gotovi ste.
🔎 Kako ova formula funkcionira?
➤ ROWS funkcija unosi serijski broj za LARGE funkciju.
➤ LARGE funkcija pronalazi najveću vrijednost iz niza ili raspona ćelija odabranih na osnovu serijskog broja.
➤ MATCH funkcija traži dobivenu najveću vrijednost u nizu vrijednosti & vraća s brojem reda te vrijednosti.
➤ INDEX funkcija konačno izvlači ime iz stupca Imena na osnovu tog broja reda pronađenog funkcijom MATCH .
Pročitajte više: Kako pronaći vrijednost u koloni u Excelu (4 metode)
1.3 Izdvajanje 5 najboljih imena prema Korištenje funkcije XLOOKUP
Ako želite izbjeći formulu INDEX-MATCH , možete je zamijeniti funkcijom XLOOKUP koja traži raspon ćelija ili niz & zatim vraća vrijednosti na osnovu odabranih uslova iz odabranog stupca ili reda.
📌 Koraci:
➤ U ćeliji E7 , naša povezana formula sa XLOOKUP za pronalaženje imena sa be:
=XLOOKUP(LARGE($C$5:$C$14,ROWS($E$7:$E7)),$C$5:$C$14,$B$5:$B$14) ➤ Pritisnite Enter & ; koristite Fill Handle da dobijete ostala 4 imena.
U 1. argumentu funkcije XLOOKUP , najveća vrijednost ima je uneto. 2. argument je Raspon ćelija C5:C14 gdje će se tražiti odabrana najveća vrijednost. A treći argument je još jedan raspon ćelija B5:B14 odakle će određeni podaci ili ime biti izvučeni na osnovu broja reda pronađenog pomoću prva dva argumenta.
Pročitajte Više: Vrijednost traženjau koloni i povratna vrijednost druge kolone u Excelu
1.4 Pronalaženje 5 najboljih imena & Vrijednosti pod više kriterija
Pomislimo sada na drugi skup podataka koji sadrži više kriterija. Ako primijetite, sada imamo imena & CGPA u kolone B & D respektivno. Kolona C predstavlja odjele studenata.
Najprije ćemo saznati 5 najboljih CGPA odsjeka za računarstvo & izlazni rezultati će se postići u Koloni H .
📌 Koraci:
➤ Da biste pronašli 5 najboljih CGPA , povezana formula u ćeliji H12 će biti:
=LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12) ➤ Pritisnite Enter , koristite Popuni Handle da dobijete ostale 4 najveće vrijednosti & gotovi ste.
Ovdje, sa IF funkcijom, saznajemo sve CGPA studente samo sa odsjeka za računarstvo . Zatim funkcija LARGE izvlači prvih 5 CGPA kao i prije.
Sada ćemo odrediti imena koja su dobila ovih 5 najboljih CGPA i koristit ćemo INDEX-MATCH ovdje funkcionira.
📌 Koraci:
➤ U izlaz Ćelija G12 , moramo upisati:
=INDEX($B$5:$B$23,MATCH(LARGE(IF($C$5:$C$23=$G$9,$D$5:$D$23),$F12), IF($C$5:$C$23=$G$9,$D$5:$D$23),0)) ➤ Pritisnite Enter & koristite Ručica za popunjavanje da popunite preostale 4 ćelije. Dobit ćete sva imena odjednom.
Pročitajte više: Kako pronaći vrijednost u koloni koristeći VBA u Excelu (4 načina )
2. Pronalaženje najboljih 5 vrijednosti & ImenaUključujući duplikate
Sada ćemo pronaći prvih 5 vrijednosti, kao i imena uključujući duplikate. Ovdje ćemo imati malo modificiranog skupa podataka.
2.1 Dobivanje 5 najboljih vrijednosti samo korištenjem Large & REDOVI funkcionišu zajedno
Dakle, na slici ispod, kolona B predstavlja imena 5 učenika, a kolone C do J prikazuju CGPA svakog semestar za te studente. U donjoj tabeli ćemo saznati izlazne podatke.
Dakle, prvo ćemo saznati najviših 5 CGPA za Andrewa među svim CGPA od 8 semestri.
📌 Koraci:
➤ Odaberite Ćelija C13 & tip:
=LARGE($C6:$N6,COLUMNS($C:C)) ➤ Pritisnite Enter & koristite Fill Handle da popunite sljedeće 4 ćelije duž reda za Andrewa.
Ako primijetite, imate vrijednost 4,00 dvostruko veću od izlaz pošto je Andrewov CGPA bio 4,00 u dva termina. Dakle, funkcija LARGE ne izostavlja duple vrijednosti dok traži najveće iz raspona podataka ili ćelija.
Sada, da bismo dobili slične rezultate za ostala 4 učenika, mi prvo morate odabrati Raspon ćelija- C13:G13 . Zatim ćete u desnom donjem uglu odabranih ćelija pronaći opciju Ručica za popunjavanje . Sada upotrijebite tu opciju da povučete prema dolje do odabranog reda za Harry & gotov si. Dobit ćete svih 5 najboljih CGPA za sve studente odjednom.
Pročitajte više: Kako pronaći najvišiVrijednost u koloni Excel (4 metode)
2.2 Izvlačenje najboljih 5 imena s duplikatima kombiniranjem INDEX, MATCH & Funkcije COUNTIF
Sada ćemo saznati imena 5 najboljih učenika sa njihovim CGPA gdje može postojati duplikat CGPA. Ako primijetite u našem izmijenjenom skupu podataka, Sam & Mike obojica imaju sličan CGPA-3.94. Ali želimo saznati prvih 5 imena, uključujući ona dva imena koja imaju slične CGPA-ove, kao i sa Excel funkcijama.
📌 Koraci :
➤ Odaberite Ćelija F7 & upišite:
=INDEX($B$5:$B$14, MATCH(1, ($C$5:$C$14=LARGE($C$5:$C$14, $E7))*(COUNTIF(F$6:F6, $B$5:$B$14)=0), 0)) ➤ Pritisnite Enter , koristite ručicu za popunjavanje da dobijete ostala 4 imena & gotov si. Upravo imate oba imena- Sam & Mike koji je dobio sličan CGPA.
🔎 Kako ova formula funkcionira?
➤ Ovdje unutar MATCH funkcija, predstavljene su dvije logičke funkcije koje se međusobno množe. Ove kombinovane logičke funkcije će tražiti prvih 5 CGPA iz Kolona C & će dodijeliti broj 1 za prvih 5 & 0 za ostale vrijednosti.
➤ MATCH funkcija zatim traži 1 samo iz prethodnih pronađenih rezultata & vraća sa brojevima redova za sva podudaranja.
➤ INDEX funkcija konačno prikazuje imena serijski na osnovu onih brojeva redova pronađenih kroz sve MATCH funkcije u koloni F .
Pročitajte više: Kako pronaći prvo pojavljivanje vrijednosti u koloni uExcel (5 načina)
2.3 Ekstrahiranje 5 najboljih imena s duplikatima pomoću SORT & FILTER Funkcije
Upotrebom SORT & FILTER , možete lakše pronaći prvih 5 imena zajedno sa vrijednostima. Ovdje više nećete morati izvlačiti prvih 5 vrijednosti prije nego što saznate imena.
📌 Koraci:
➤ Za Ćelija F7 , naša srodna formula sa SORT & FILTER funkcije će biti:
=SORT(FILTER(B5:C14, C5:C14>=LARGE(C5:C14, 5)), 2,-1) ➤ Pritisnite Enter & odmah ćete dobiti 5 najboljih CGPA-a zajedno s imenima učenika. Ovdje čak i ne morate koristiti Fill Handle da biste dobili preostale vrijednosti jer sama formula radi sve izračune umjesto vas.
Dakle, ono što se ovdje događa je Funkcija FILTER sa funkcijom LARGE izvlači sve najveće vrijednosti iz Range of Cells-C5:C14. Funkcija SORT tada prikazuje sve vrijednosti ili CGPA u opadajućem redoslijedu zajedno s imenima iz niza B5:C14.
Pročitajte više: Kako pronaći najnižu vrijednost u Excel koloni (6 načina)
2.4 Pronađi najbolja imena & Vrijednosti s duplikatima spajanjem INDEX, SORT & SEQUENCE Funkcije zajedno
Ovo je još jedna odlična opcija & skoro sličan prethodnom. Koristit ćemo INDEX, SORT & SEQUENCE ovdje funkcionira zajedno.
📌 Koraci:
➤ Odaberite Ćelija F7 &tip:
=INDEX(SORT(B5:C14,2,-1),SEQUENCE(5),{1,2}) ➤ Pritisnite Enter & gotov si. Odmah ćete dobiti prvih 5 CGPA zajedno s nazivima.
Koncept je ovdje previše jednostavan. Funkcija SORT prikazuje sve CGPA-ove u opadajućem redoslijedu, ali SEQUENCE funkcija joj govori da odabere samo prvih 5. Zatim funkcija INDEX prikazuje konačne rezultate sa imena & CGPA u nizu.
Pročitajte više: Kako pronaći posljednje pojavljivanje vrijednosti u koloni u Excel-u (5 metoda)
Završne riječi
Nadam se da će vas sve ove metode za pronalaženje prvih 5 vrijednosti i imena sada potaknuti da ih primijenite u svojim redovnim poslovima u Excelu. Ako imate bilo kakvih pitanja ili povratnih informacija, javite mi kroz svoje komentare. Ili možete pogledati naše druge zanimljive članke vezane za Excel funkcije na ovoj web stranici.
